中国DOS联盟

@echo off
setlocal enableextensions enabledelayedexpansion
rem 作者：rubble@126.com
rem 17:55 2009-4-14 版本：0.4
set dira=%~1
set dirb=%~2
if "%1" == "" (
        echo     使用说明：请在命令行参数上指明两个目录，或在这里按提示输入。
        echo     命令行参数格式：批处理名 ^<目录1^> ^<目录2^>
        echo.
        set /p dira=请输入第一个目录的名字（可拖放并输入回车）：
)
echo.
if "%2" == "" (
        echo     使用说明：请在命令行参数上指明两个目录，或在这里按提示输入。
        echo     命令行参数格式：批处理名 ^<目录1^> ^<目录2^>
        echo.
        set /p dirb=请输入第二个目录的名字（可拖放并输入回车）：
)

if "%dira%" == "" exit /b
if "%dirb%" == "" exit /b
for /F "delims=. tokens=1" %%A in ("%TIME%") do set startTime=%%A
for /F "delims=: tokens=1,2,3" %%A in ("%startTime%") do (
        set startH=%%A
        set startM=%%B
        set startS=%%C
)

set TEMPDIR=TEMPMD5\
rd /Q /S %TEMPDIR% 1>NUL 2>NUL
md %TEMPDIR%
set mdfive=md5v4.txt
rem 已处理的文件数
set count=0
rem 文件夹 %dira% 和 %dirb% 里的文件总数
set total_count=0
rem 已处理的临时文件数
set tmpf_count=0
rem 临时文件总数，已知有 5 个了。其余的是 md5 值的个数
set tmpf_total_count=5
echo 第 1/2步，正在计算，请稍候……
echo 正在比较 %dira% 和 %dirb% 中的文件的 md5 值 > %mdfive%
set list_fn_md=%TEMPDIR%list_fn_md
set list_fn_nmd=%TEMPDIR%list_fn_nmd
set list_fn_oa=%TEMPDIR%list_fn_oa
set list_fn_ob=%TEMPDIR%list_fn_ob
set list_all_md=%TEMPDIR%list_all_md

call :COUNTFILES %dira%
call :COUNTFILES %dirb%

for /f "delims=" %%a in ('dir /b /a:-d "%dira%\*"') do (
        set fn=%%~nxa
        for /f "tokens=1 delims= " %%A in ('md5sum "%dira%\%%a"') do set mda=%%A
        set /a count=!count!+1
        call :PROGRESS !count! !total_count!
        if "!mda:~0,1!" == "\" set mda=!mda:~1,1024!
        rem 以 !mda! 为文件名，记录 md5 为 !mda! 的文件
        call :ADDMDFN "%TEMPDIR%!mda!" "%dira%\!fn!"
        rem 把 md5 值记录到文件里，保证不重复
        call :ADDMDLIST !mda!
        if exist "%dirb%\!fn!" (
            for /f "tokens=1 delims= " %%A in ('md5sum "%dirb%\!fn!"') do set mdb=%%A
            set /a count=!count!+1
            call :ADDMDFN "%TEMPDIR%!mdb!" "%dirb%\!fn!"
            call :PROGRESS !count! !total_count!
            if "!mdb:~0,1!" == "\" set mdb=!mdb:~1,1024!
            if "!mda!" == "!mdb!" (
                rem 记录文件名相同并且 md5 相同的文件
                echo !mda! !mdb! !fn! >> "!list_fn_md!"
            ) else (
                rem 记录文件名相同但 md5 不相同的文件
                echo !mda! !mdb! !fn! >> "!list_fn_nmd!"
                call :ADDMDLIST !mdb!
            )
        ) else (
            rem 记录只在 %dira% 中出现的文件
            echo !mda! !fn! >> "!list_fn_oa!"
        )
)
for /f "delims=" %%a in ('dir /b /a:-d "%dirb%\*"') do (
        set fn=%%~nxa
        if not exist "%dira%\!fn!" (
            for /f "tokens=1 delims= " %%A in ('md5sum "%dirb%\%%a"') do set mdb=%%A
            if "!mdb:~0,1!" == "\" set mdb=!mdb:~1,1024!
            rem 记录只在 %dirb% 中出现的文件
            echo !mdb! !fn! >> "!list_fn_ob!"
            rem 把 md5 值记录到文件里，保证不重复
            call :ADDMDLIST !mdb!
            call :ADDMDFN "%TEMPDIR%!mdb!" "%dirb%\!fn!"
            set /a count=!count!+1
            call :PROGRESS !count! !total_count!
        )
)
echo 第 2/2步，正在统计，请稍候……
echo 统计：>>%mdfive%
echo 左：%dira% >> %mdfive%
echo 右：%dirb% >> %mdfive%
if not exist "%list_fn_md%" set /a tmpf_total_count-=1
if not exist "%list_fn_nmd%" set /a tmpf_total_count-=1
if not exist "%list_fn_oa%" set /a tmpf_total_count-=1
if not exist "%list_fn_ob%" set /a tmpf_total_count-=1
if not exist "%list_all_md%" set /a tmpf_total_count-=1
echo 两个目录中都存在且 md5 相同的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_md%"
echo ===============================================================================================>> %mdfive%
echo 左：%dira% >> %mdfive%
echo 右：%dirb% >> %mdfive%
echo 两个目录中都存在但 md5 不相同的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_nmd%"
echo ===============================================================================================>> %mdfive%
echo 只在目录 %dira% 中存在的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_oa%"
echo ===============================================================================================>> %mdfive%
echo 只在目录 %dirb% 中存在的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_ob%"
echo ===============================================================================================>> %mdfive%
echo 以 md5 汇总的文件列表：>> %mdfive%
call :OUTPUTLIST_MD "%list_all_md%"

goto ALLDONE

rem 统计文件夹里的文件数目，放到全局变量 total_count 里
:COUNTFILES
if %1=="" goto :EOF
for /f %%a in ('dir /b /a:-d "%~1\*"') do (
    set /a total_count=!total_count!+1
)
goto :EOF

rem 参数 %1 必须加双引号
:OUTPUTLIST
if %1 == "" goto :EOF
if not exist %1 goto :EOF
set tcnt=0
for /f "tokens=1* delims= " %%a in (%~1) do (
    echo %%a %%b >> %mdfive%
    set /a tcnt+=1
)
echo !tcnt! >> %mdfive%
set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!
goto :EOF

rem 参数 %1 必须加双引号
:OUTPUTLIST_MD
if %1 == "" goto :EOF
if not exist %1 goto :EOF

set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!

set md_count=0
for /f "tokens=1* delims= " %%a in (%~1) do (
    echo %%a >> %mdfive%
    set tcnt=0
    for /f "tokens=1* delims= " %%A in (!TEMPDIR!%%a) do (
        echo %%A %%B >> %mdfive%
        set /a tcnt+=1
    )
    set /a tmpf_count+=1
    call :PROGRESS !tmpf_count! !tmpf_total_count!
    echo !tcnt! >> %mdfive%
    set /a md_count+=1
    echo. >> %mdfive%
)
echo %md_count% >> %mdfive%
goto :EOF

rem 函数：把 md5 值保存到一个名为 !list_all_md! 的文件里，
rem 并保证不保存重复的 md5 值
:ADDMDLIST
if %1 == "" goto :EOF
if exist "!list_all_md!" (
        rem 这里的 delims 要么删除，要么做成像下面这行的样子，在等号后面加个空格
        rem for /f "tokens=1 delims= " %%a in (!list_all_md!) do (
        for /f "tokens=1 " %%a in (!list_all_md!) do (
            if "%%a" == "%1" goto :EOF
        )
)
echo %1 >> "!list_all_md!"
rem 记录临时文件总数
set /a tmpf_total_count+=1
goto :EOF

rem 函数：以 %1 为文件名，保存 %2
rem %1：在这个应用里是 md5 值
rem %2：md5 值为 %1 的文件
:ADDMDFN
if %1 == "" goto :EOF
if %2 == "" goto :EOF
echo %2 >> %1
goto :EOF

:PROGRESS
set tips=

set backspace=
set /a percent=%1*100/%2
set /a char=%1%%7
set /a bnum=%percent%/10
set /a snum=10-%bnum%
for /L %%a in (1, 1, %bnum%) do set /p=▌<NUL
for /L %%a in (1, 1, %snum%) do set /p=  <NUL
set /p=%1/%2 %percent%%% <NUL
set /p=!tips:~%char%,1!<NUL
if "%percent%" == "100" (
    echo.
    goto :EOF
)
set /p=%backspace%<NUL
goto :EOF

rem :PROGRESS
rem set tips=

rem set backspace=
rem set /a char=%1%%7
rem set /p=!tips:~%char%,1!<NUL
rem set /p=%backspace%<NUL
rem goto :EOF

:ALLDONE

rd /Q /S %TEMPDIR% 1>NUL 2>NUL
for /F "delims=. tokens=1" %%A in ("%TIME%") do set endTime=%%A
for /F "delims=: tokens=1,2,3" %%A in ("%endTime%") do (
        set endH=%%A
        set endM=%%B
        set endS=%%C
)
if "%endM:~0,1%" == "0" set endM=%endM:~1,1%
if "%endS:~0,1%"=="0" set endS=%endS:~1,1%
for /F "delims=: tokens=1,2,3" %%A in ("%startTime%") do (
        set startH=%%A
        set startM=%%B
        set startS=%%C
)
if "%startM:~0,1%"=="0" set startM=%startM:~1,1%
if "%startS:~0,1%"=="0" set startS=%startS:~1,1%
set /A totalTime=%endH%*3600+%endM%*60+%endS%-(%startH%*3600+%startM%*60+%startS%)
echo 共用时 %totalTime% 秒。
echo 起始时间：%startH%:%startM%:%startS%>>%mdfive%
echo 结束时间：%endH%:%endM%:%endS%>>%mdfive%
echo 共用时 %totalTime% 秒。>>%mdfive%
start %mdfive%
echo 
endlocal
@echo on

~I         - 删除任何引号(")，扩充 %I

%~I         - expands %I removing any surrounding quotes (")

@echo off
set a=""""C:\test hat\cndos""""
set b=%a:"=%
echo %b%

""""""""

@echo off
setlocal enableextensions enabledelayedexpansion
rem v5
rem 1。去掉了进度显示和计时功能，简化了一下，根据 anxd 的写法，用 fc 比较
rem    md5 值，并可以编历所有子目录。
rem 2。没有用 anxd 的映射驱动器的做法，在我的电脑上，盘符已经到了 P:。
rem 3。根据版主 HAT 的方法，增强了对用户输入合法性的检查，但仍不完美。
rem 4。现在可以快速找到两个目录中 md5 值不同的文件。

rem 注：fsutil fsinfo drives 可以查询出系统有多少个盘符

rem 检查用户输入
set dira=%1
set dirb=%2

if {%dira%}=={} (
    call :USEAGE
    set /p dira=请输入第一个目录的名字（可拖放并输入回车）：
)

if {%dirb%}=={} (
    call :USEAGE
    set /p dirb=请输入第二个目录的名字（可拖放并输入回车）：
)

if {%dira%}=={} (
    call :USEAGE
    echo 目录一非法。
    exit /b
)

if {%dirb%}=={} (
    call :USEAGE
    echo 目录二非法。
    exit /b
)
set dira=%dira:"=%
set dirb=%dirb:"=%

set dira="%dira%"
set dirb="%dirb%"

if %dira%=="" (
    call :USEAGE
    echo 目录一非法。
    exit /b
)

if %dirb%=="" (
    call :USEAGE
    echo 目录二非法。
    exit /b
)
rem 用户输入检查完毕，仍不能处理用户输入奇数个双引号的情况。

set diramd5=dira.txt
set dirbmd5=dirb.txt
set diratmp=dira.tmp
set dirbtmp=dirb.tmp

set md5=md5v5.txt

if exist %diramd5% del %diramd5%
if exist %dirbmd5% del %dirbmd5%

call :CALMD5 %dira% %diramd5%
call :CALMD5 %dirb% %dirbmd5%

sort %diramd5%>%diratmp%
sort %dirbmd5%>%dirbtmp%

fc %diramd5% %dirbmd5%>%md5%
del %diramd5% %dirbmd5% %diratmp% %dirbtmp%
start %md5%

goto :ALLDONE

:USEAGE
echo     使用说明：请在命令行参数上指明两个目录，或在这里按提示输入。
echo     命令行参数格式：批处理名 ^<目录1^> ^<目录2^>
echo.
goto :EOF

rem %1：将要计算其中文件的目录
rem %2：保存计算结果的文件
:CALMD5
set tdir=%1
set md5fn=%2
for /f "delims=" %%a in ('dir /s /b /a:-d /o:n !tdir!\*') do (
        md5sum %%a >> !md5fn!
)
goto :EOF

:ALLDONE
endlocal
@echo off

@echo off
setlocal enableextensions enabledelayedexpansion
rem v6
rem 1。去掉了进度显示和计时功能，简化了一下，根据 anxd 的写法，用 fc 比较
rem    md5 值，并可以编历所有子目录。
rem 2。没有用 anxd 的映射驱动器的做法，在我的电脑上，盘符已经到了 P:。
rem 3。根据版主 HAT 的方法，增强了对用户输入合法性的检查，但仍不完美。
rem 4。现在可以快速找到两个目录中 md5 值不同的文件。
rem 6。分析 md5sum 输出的结果，只记录 md5 值和其对应的文件名。

rem 注：fsutil fsinfo drives 可以查询出系统有多少个盘符

rem 检查用户输入
set dira=%1
set dirb=%2

if {%dira%}=={} (
    call :USEAGE
    set /p dira=请输入第一个目录的名字（可拖放并输入回车）：
)

if {%dirb%}=={} (
    call :USEAGE
    set /p dirb=请输入第二个目录的名字（可拖放并输入回车）：
)

if {%dira%}=={} (
    call :USEAGE
    echo 目录一非法。
    exit /b
)

if {%dirb%}=={} (
    call :USEAGE
    echo 目录二非法。
    exit /b
)
set dira=%dira:"=%
set dirb=%dirb:"=%

set dira="%dira%"
set dirb="%dirb%"

if %dira%=="" (
    call :USEAGE
    echo 目录一非法。
    exit /b
)

if %dirb%=="" (
    call :USEAGE
    echo 目录二非法。
    exit /b
)
rem 用户输入检查完毕，仍不能处理用户输入奇数个双引号的情况。

set diramd5=dira.txt
set dirbmd5=dirb.txt
set diratmp=dira.tmp
set dirbtmp=dirb.tmp

set md5=md5v6.txt

if exist %diramd5% del %diramd5%
if exist %dirbmd5% del %dirbmd5%

call :CALMD5 %dira% %diramd5%
call :CALMD5 %dirb% %dirbmd5%

sort %diramd5%>%diratmp%
sort %dirbmd5%>%dirbtmp%

fc %diramd5% %dirbmd5%>%md5%
del %diramd5% %dirbmd5% %diratmp% %dirbtmp% > NUL
start %md5%

goto :ALLDONE

:USEAGE
echo     使用说明：请在命令行参数上指明两个目录，或在这里按提示输入。
echo     命令行参数格式：批处理名 ^<目录1^> ^<目录2^>
echo.
goto :EOF

rem %1：将要计算其中文件的目录
rem %2：保存计算结果的文件
:CALMD5
set tdir=%1
set md5fn=%2
for /f "delims=" %%a in ('dir /s /b /a:-d /o:n !tdir!\*') do (
        set fn=%%~nxa
        for /f "tokens=1 delims= " %%b in ('md5sum "%%a"') do set md5val=%%b
        if "!md5val:~0,1!"=="\" set md5val=!md5val:~1,1024!
        echo !md5val! *!fn!>> !md5fn! & rem 只记录 md5 值和文件名
)
goto :EOF

:ALLDONE
endlocal
@echo off