求A-z的随机排列..谢谢
中国DOS联盟
联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 求嗰随机数排列
查看 965 回复 8
楼 主
求嗰随机数排列
发表于 2008-04-05 01:04 · 中国 广东 肇庆 电信
第 2 楼
发表于 2008-04-05 01:25 · 中国 湖南 娄底 电信
:
@echo off&setlocal enabledelayedexpansion
set "str=abcdefghijklmnopqrstuvwxyz"
for /l %%i in (0 1 25) do (
set /a num=!random! %% 25+1
call set var=%%str:~!num!,1%%
call set str=%%str:!var!=%%!var!
)
echo !str:~10!!str:~0,10!
pause
本帖最近评分记录
（共 1 条）
点击查看详情
| 评分人 | 分数 | 时间 |
|---|---|---|
| forkfan | +2 | 2008-04-06 14:30 |
致精致简！
第 3 楼
发表于 2008-04-05 01:29 · 中国 广东 肇庆 电信
谢谢..
第 4 楼
发表于 2008-04-05 02:07 · 中国 江苏 常州 溧阳市 电信
@echo off
set "str=abcdefghijklmnopqrstuvwxyz"
set n=27
:loop
set/a n-=1
set/a s=%random%%%%n%
call set var=%%str:~%s%,1%%
set var1=%var%%var1%
call set str=%%str:%var%=%%
if defined str goto loop
echo %var1%
pause
set "str=abcdefghijklmnopqrstuvwxyz"
set n=27
:loop
set/a n-=1
set/a s=%random%%%%n%
call set var=%%str:~%s%,1%%
set var1=%var%%var1%
call set str=%%str:%var%=%%
if defined str goto loop
echo %var1%
pause
简单!简单!再简单!
第 5 楼
发表于 2008-04-05 10:21 · 中国 湖北 武汉 电信
支持
第 6 楼
我也来一个：
发表于 2008-04-06 04:01 · 中国 湖南 株洲 电信
@echo off
:begin
set code=abcdefghijklmnopqrstuvwxyz
set /a n=%random%%%26
call,set str=%%code:~%n%,1%%
for %%i in (%var%) do if "%%i"=="%str%" goto begin
set var=%var% %str%
if "%var:~51,1%"=="" goto begin
echo %var%
pause批处理之家新域名：www.bathome.net
第 7 楼
发表于 2008-04-06 05:27 · 中国 湖南 娄底 电信
:
[ Last edited by 26933062 on 2008-4-6 at 05:28 AM ]
@echo off&setlocal EnableDelayedExpansion
set "code=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
for /l %%a in (26 -1 1) do (
set /a w=!random!%%%%a
call set var=!var!%%code:~!w!,1%%
call set code=%%code:!var:~-1!=%%
)
echo !var!
pause
[ Last edited by 26933062 on 2008-4-6 at 05:28 AM ]
致精致简！
第 8 楼
发表于 2008-04-06 07:28 · 法国 wanadoo网络
我替楼兄做个注：
这个第三步 妙 我加分！
@echo off&setlocal EnableDelayedExpansion
set "code=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
for /l %%a in (26 -1 1) do (
set /a w=!random!%%%%a
1.随机取余数，余数w小于等于25
call set var=!var!%%code:~!w!,1%%
2.取变量code的第w+1位放入变量var并不断累积
call set code=%%code:!var:~-1!=%%
3.删除变量code中已截取的字母，将其继续循环
)
echo %var%
pause
这个第三步 妙 我加分！
菩提本无树,明镜亦非台,本来无一物,何处惹尘埃.
第 9 楼
发表于 2008-04-06 08:47 · 中国 湖南 娄底 电信
呵呵，再来个另类点的。
@echo off&setlocal EnableDelayedExpansion
set "code=ABCDEFGHIJKLMNOPQRSTUVWXYZ"
for /l %%a in (26 -1 1) do (
set /a w=!random!%%%%a
call call set code=%%%%code:%%code:~!w!,1%%=%%%%%%code:~!w!,1%%
)
echo %code%
pause
致精致简！
论坛跳转: