中国DOS联盟

@echo off
::   Code by JM 2006-6-11
:in
mode con lines=25
cls
color 1f
chcp 936>nul
title 请输入命令名称
echo.
echo                               ╭────────╮   
echo           ╭─────────┤   请输入命令   ├──────────╮
echo           │                  ╰────────╯                    │
echo           │         操作说明：                                       │
echo           │                                                          │
echo           │             请输入一个DOS命令名称，然后回车。            │
echo           │                                                          │
echo           │         本操作将把该DOS命令的帮助信息输出到当            │
echo           │                                                          │
echo           │         前目录下以该命令为文件名的文本文件中             │
echo           │                                                          │
echo           │         （例如：copy.txt）。完成一个操作之后，           │
echo           │                                                          │
echo           │         将返回本界面继续下一个操作。生成所有             │
echo           │                                                          │
echo           │         的DOS帮助信息请输入all。                         │  
echo           │                                                          │
echo           │╭──────────────╮          ╭──────╮│
echo           ╰┤  察看DOS命令列表请输入help ├─────┤退出请按 0  ├╯
echo             ╰──────────────╯          ╰──────╯  
echo.
echo.
set input=
set /p input=           请输入一个DOS命令名称并回车确认：
if '%input%'=='0' exit
if '%input%'=='' goto in
if '%input%'=='help' goto help
if '%input%'=='all' goto cmdinfo
%input% >nul 2>nul || (
    cls
    color 0c
    title 命令输入错误
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo                ──────────────────────────
    echo.
    echo                         "%input%" 不是DOS命令，请重新输入
    echo.
    echo                ──────────────────────────
    pause>nul && goto in
)
%input% /? >%input%.txt
goto info

:help
mode con lines=84
cls
title DOS命令列表
echo.
help
echo       ╭────────────────────────────╮            
echo ───┤ 上一步请按1，生成DOS命令列表help.txt请回车，退出请按 0 ├────
echo       ╰────────────────────────────╯  
echo.
echo.
set /p input=                  请选择(0/1/回车)
if not '%input%'=='' set input=%input%
if '%input%'=='0' exit
if '%input%'=='1' goto in
if '%input%'=='help' goto made
goto help

:cmdinfo
mode con lines=25
cls
title 生成帮助信息
(echo.
echo.
echo                                DOS命令帮助信息
echo.
echo                                    由 %username% 创建于 %date:~0,10%
echo.)>DOS命令帮助信息.txt
for /f  %%i in ('help^|findstr "^[A-Z]"') do (
    cls
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo.
    echo              ──────────────────────────
    echo.
    echo                      正在生成  %%i  的帮助信息，请稍候...
    echo.
    echo              ──────────────────────────   
    help %%i>>DOS命令帮助信息.txt
    if errorlevel 1 echo.>>DOS命令帮助信息.txt
    (if errorlevel 0 echo ————————————————————————
         echo.)>>DOS命令帮助信息.txt)
cls
title 操作成功
echo.
echo.
echo.
echo.
echo.
echo                   ──────────────────────────
echo.
echo                           操作已完成，已经在当前目录下生成
echo.
echo                              "DOS命令帮助信息.txt" 文件
echo.
echo                   ──────────────────────────
ping 127.0.0.1 -n 3 >nul
start DOS命令帮助信息.txt
goto in

:made
mode con lines=25
(echo.
    echo.
    echo                                DOS命令列表
    echo.
    echo.)>help.txt
help>>help.txt

:info
cls
chcp 936>nul
title 操作成功
echo.
echo.
echo.
echo.
echo.
echo                   ──────────────────────────
echo.
echo                           操作已完成，已经在当前目录下生成
echo.
echo                                   %input%.txt文件
echo.
echo                   ──────────────────────────
start %input%.txt
goto in