中国DOS联盟

@echo off
mode con cols=80 lines=31&color fc
title Windows 备份还原小助手(撒手不管版)  作者:王泽芝
dir /b /a j:\20*.gho>j:\备份还原.txt
set count=0
setlocal enabledelayedexpansion
for /f %%i in (j:\备份还原.txt) do (
    set /a count+=1
    set first=!second!
    set second=!third!
    set third=%%i
)
:index
cls
echo.
echo.
echo.
echo                                 王泽芝精工出品
echo.
echo                                  (撒手不管版)
echo                       ╭───────────────╮
echo                       │                              │
echo                   ╭─┤ Windows 备 份 还 原 小 助 手 ├─╮
echo                   │  │                              │  │
echo                   │  ╰───────────────╯  │
echo                   │   注意本软件仅为你保存最多五个备份   │
echo                   │                                      │
echo                   │            ☆ 操作选项 ☆            │
echo                   │                                      │
echo                   │    1.系统备份  2.系统还原  3.退出    │
echo                   ╰───────────────────╯
echo.
set start=
set /p start=    输入(1 2 3)后按回车键:
if "%start%"=="1" goto bf
if "%start%"=="2" goto hy
if "%start%"=="3" goto :eof
goto index
:bf
if %count% equ 3 attrib -r -s -h j:\%first%&&del j:\%first%
attrib -r -s -h c:\boot.ini
copy c:\ghost\c启动.ini c:\boot.ini
echo cd\>c:\AUTOEXEC.BAT
echo cd ghost>>c:\AUTOEXEC.BAT
echo attrib.exe -a -s -h c:\boot.ini>>c:\AUTOEXEC.BAT
echo copy c:\ghost\boot.ini c:\>>c:\AUTOEXEC.BAT
echo attrib.exe +a +s +h c:\boot.ini>>c:\AUTOEXEC.BAT
echo Ghost.exe -clone,mode=pdump,src=1:2,dst=1:8\%date:~0,4%%date:~5,2%%date:~8,2%.gho -z2 -sure -rb>>c:\AUTOEXEC.BAT
msg %username% /time:20  ":)正在对系统盘进行病毒扫描，扫描完成后将进行备份:)"
for /f "delims=\" %%e in ('fsutil fsinfo drives^|find /v ""') do (
set var=%%e
set drive=!var:~-2!
fsutil fsinfo drivetype !drive:~0,2!|find "固定">nul && for /f "tokens=*" %%j in ('dir /a-d /b /s !drive!\avp.com 2^>nul') do if not "%%j"=="" "%%j" scan /memory d:\
)
echo echo.^>c:\AUTOEXEC.BAT>E:\自编程序区\善后.bat
echo attrib +r +s +h j:\%date:~0,4%%date:~5,2%%date:~8,2%.gho>>E:\自编程序区\善后.bat
echo del j:\备份还原.txt>>E:\自编程序区\善后.bat
echo del "C:\Personal\王泽芝\「开始」菜单\程序\启动\善后.bat.lnk">>E:\自编程序区\善后.bat
goto end
:hy
set num=
cls
echo.
echo.
echo.
echo                                 王泽芝精工出品
echo.
echo                                  (撒手不管版)
echo                       ╭───────────────╮
echo                       │                              │
echo                   ╭─┤ Windows 备 份 还 原 小 助 手 ├─╮
echo                   │  │                              │  │
echo                   │  ╰───────────────╯  │
echo                   │                                      │
echo                   │   注意本软件仅为你保存最多五个备份   │
echo                   │                                      │
echo                   │            ☆ 操作选项 ☆            │
echo                   │                                      │
echo                   │      1. 还  原  原  始  系  统       │
echo                   │      2. 还  原  精  简  系  统       │
if not "!third!"=="" (echo                   │      3.还原为!third:~0,4!年!third:~4,2!月!third:~6,2!日系统      │)else if "!num!"=="" set num=3
if not "!second!"=="" (echo                   │      4.还原为!second:~0,4!年!second:~4,2!月!second:~6,2!日系统      │)else if "!num!"=="" set num=4
if not "!first!"=="" (echo                   │      5.还原为!first:~0,4!年!first:~4,2!月!first:~6,2!日系统      │)else if "!num!"=="" set num=5
if "!num!"=="" set num=6
echo                   │      !num!. 退                  出       │
echo                   ╰───────────────────╯
echo.
:cl
set start=
set /p start=    输入(1 2 3 4 5 6)后按回车键:
if "%start%"=="!num!" goto :eof
if "%start%"=="1" set GHO=yuanshiWindows.GHO&&goto hyks
if "%start%"=="2" set GHO=jingjianWindows.GHO&&goto hyks
if "%start%"=="3" set GHO=!third!&&goto hyks
if "%start%"=="4" set GHO=!second!&&goto hyks
if "%start%"=="5" set GHO=!first!&&goto hyks
goto cl
:hyks
attrib -r -s -h c:\boot.ini
copy c:\ghost\c启动.ini c:\boot.ini
echo cd\>c:\AUTOEXEC.BAT
echo cd ghost>>c:\AUTOEXEC.BAT
echo attrib.exe -a -s -h c:\boot.ini>>c:\AUTOEXEC.BAT
echo copy c:\ghost\boot.ini c:\>>c:\AUTOEXEC.BAT
echo attrib.exe +a +s +h c:\boot.ini>>c:\AUTOEXEC.BAT
echo Ghost.exe -clone,mode=pload,src=1:8\%GHO%:1,dst=1:2 -sure -rb>>c:\AUTOEXEC.BAT
echo echo.^>c:\AUTOEXEC.BAT>E:\自编程序区\善后.bat
echo del j:\备份还原.txt>>E:\自编程序区\善后.bat
echo del "C:\Personal\王泽芝\「开始」菜单\程序\启动\善后.bat.lnk">>E:\自编程序区\善后.bat
goto end
:end
copy E:\自编程序区\善后.bat.lnk "C:\Personal\王泽芝\「开始」菜单\程序\启动\">nul
shutdown -r -t 1