中国DOS联盟

@echo off
if "%1"=="" goto :FullScreen
::还原显示模式
REG ADD HKEY_CURRENT_USER\Console /v FullScreen /t REG_DWORD /d %1 /f>nul

cls
title 智能获取72小时天气预报 --- 腾讯版  Code By Kumho Lin
color 0b
setlocal EnableDelayedExpansion
set "a=FileName: WeatherCapturer.exe"
set "b=FileVersion: 1.0.0.1"
set "c=Function: Get the weather information in 72 hours according to your location"
set "d=Author: Kumho Lin"
set "e=QQ: 240460440"
set "f=E-Mail: kumho.lin@gmail.com"
set "g=HomePage: http://kumho.lin.googlepages.com"
set "h=Are you sure you wanna run this batch program right now [Y/N]?"
for %%i in (a b c d e f g h) do (
        set/p=<nul
        for /l %%a in (0,1,100) do (
                if not "!%%i:~%%a,1!"=="" (
                        if "%%a"=="100" echo.&echo;
                        set/p=!%%i:~%%a,1!<nul
                        for /l %%p in (1,1,200) do ver>nul
                )
        )
        echo.
)
set /p choice=
if /i "%choice%"=="y" (goto Begin) else goto Out
:Out
exit
:Begin
cls
ping -n 2 127.1 >nul 2>nul
:: →→→→→→→→→→→→→ Loading The Program ←←←←←←←←←←

(set,=Loading the program, please wait a minute&for /l %%c In (0,1,42)do @call set/p=%%,:~%%c,1%%<nul)&set,=&ping -n 2 127.1>nul&set/p="."<nul&ping -n 2 127.1>nul&set/p="."<nul&ping -n 2 127.1>nul&set/P="."<nul&ping -n 3 127.1>nul
cls
set num=20
set a==
set n=1
for /l %%i in (1,1,80) do (
cls
set /a num+=1
echo                                       !num!%%
echo !a!
set a=!a!=
set /a n+=1
for /l %%j in (1,1,150) do ver>nul
)
ping -n 1 127.1 >nul 2>nul
echo                                 Loading Complete
ping -n 2 127.1 >nul 2>nul
endlocal
cls
:: →→→→→→→→→→→→→ Loading The Program ←←←←←←←←←←


:: ************************** 判断是否联网 *****************************

setlocal EnableDelayedExpansion
set a=The program is detecting your system, please wait a minute...
for %%i in (a) do (
        set/p=<nul
        for /l %%a in (0,1,100) do (
                if not "!%%i:~%%a,1!"=="" (
                        if %%a==100 echo.&echo;
                        set/p=!%%i:~%%a,1!<nul
                        for /l %%i in (1,1,100) do ver>nul
                )
        )
        echo.
)
endlocal
ping -n 2 127.1>nul 2>nul
cls
ping -n 2 www.ip138.com >nul 2>nul
if %errorlevel% equ 0 (goto ready) else goto problem
:problem
setlocal DisableDelayedExpansion
set "A=            Your computer is not connecting to the Internet !!!"
set "B="
for /l %%j in (1,1,10) do (
set/p=%A%<nul
set/p=%B%<nul
for /l %%i in (1,1,500) do ver>nul
set/p=                                                                   <nul
for /l %%i in (1,1,500) do ver>nul
set/p=%B%<nul
ping -n 1 127.1 >nul 2>nul
)
endlocal
MSG * /time:3 ***** 您必须连接到互联网才能使用该功能 *****
goto quit
:ready
echo The batch program is connecting to the Internet, please wait a few seconds...
ping -n 4 127.1>nul 2>nul
cls

:: ==================== 获取IP、地理位置及ISP脚本开始 ===================

echo Set oDOM = WScript.GetObject(WScript.Arguments(0))>%TEMP%\Text.vbs
echo Do Until oDOM.readyState = "complete">>%TEMP%\Text.vbs
echo WScript.sleep 200>>%TEMP%\Text.vbs
echo Loop>>%TEMP%\Text.vbs
echo WScript.echo oDOM.documentElement.outerText>>%TEMP%\Text.vbs
echo Set oDOM=nothing>>%TEMP%\Text.vbs
cscript //NoLogo /E:vbscript %TEMP%\Text.vbs http://www.ip138.com | find /i "您的IP地址是" 2>nul>%TEMP%\location.txt
for /f "tokens=2 delims=[]" %%i in (%TEMP%\location.txt) do set true_ip=%%i
for /f "tokens=2,3 delims= " %%k in (%TEMP%\location.txt) do (
set your_location=%%k
set true_isp=%%l
)
echo %your_location:~3,-1%>%TEMP%\your_location.txt
for /f "tokens=1,2 delims=省" %%p in (%TEMP%\your_location.txt) do (
set true_province=%%p
set true_city=%%q
)

:: ==================== 获取IP、地理位置及ISP脚本结束 ===================

:: ************************* 获取气温信息脚本开始 ***********************

cscript //nologo /e:vbscript %TEMP%\Text.vbs http://kumho.lin.googlepages.com/city.txt|find /v /i "javascript" 2>nul>%TEMP%\cityInfo.txt
for /f "tokens=1 delims=/" %%i in ('find /i "%true_city%" %TEMP%\cityInfo.txt') do set cityCode=%%i
set "cityAddress=http://weather.news.qq.com/inc/07_dc%cityCode%.htm"
echo Set oDOM = WScript.GetObject(WScript.Arguments(0))>%TEMP%\HTML.vbs
echo Do Until oDOM.readyState = "complete">>%TEMP%\HTML.vbs
echo WScript.sleep 200>>%TEMP%\HTML.vbs
echo Loop>>%TEMP%\HTML.vbs
echo WScript.echo oDOM.documentElement.outerHTML>>%TEMP%\HTML.vbs
echo Set oDOM=nothing>>%TEMP%\HTML.vbs
cscript //nologo /e:vbscript %TEMP%\HTML.vbs %cityAddress% 2>nul>%TEMP%\source.txt

:: ******** 获取气温信息代码 ********

Setlocal EnableDelayedExpansion
set a=1
for /f "tokens=4 delims= " %%i in ('type %TEMP%\source.txt^|find /i "#eef3f8"') do (
set var=%%i
set string=!var:~10!
set num=!string:^<BR^>=#!
for /f "tokens=1,2 delims=#" %%a in ("!num!") do (
set tq!a!=%%a
set wd!a!=%%b
)
set /a a+=1
)
endlocal
:: ******** 获取日期信息代码 ********
Setlocal EnableDelayedExpansion
set b=1
for /f "tokens=4 delims=, " %%i in ('type %TEMP%\source.txt^|find /i "#eeeeee"') do (
set time1=%%i
set time2=!time1:^>=#!
set time3=!time2:^<=#!
for /f "tokens=2 delims=#" %%a in ("!time3!") do set rq!b!=%%a
set /a b+=1
)
endlocal
:: ************************* 获取气温信息脚本结束 ***********************

:: /*-*-*-*-*-*-*-*-*-*-* 获取操作系统版本信息开始 *-*-*-*-*-*-*-*-*-*-*/

Systeminfo 2>nul >%TEMP%\systeminfo.txt
type %TEMP%\systeminfo.txt | Find /I /V "BIOS 版本:" >%TEMP%\eol.txt
For /F "tokens=3*" %%I in ('type %TEMP%\systeminfo.txt ^| Find /I "OS 名称:"') Do Set os_name=%%I %%J
For /F "tokens=3,4,5,6 delims= " %%i in ('type %TEMP%\eol.txt ^| Find /I "OS 版本:"') Do Set os_ver=%%i %%j %%k %%l
Set os_name_ver=%os_name% %os_ver%

:: /*-*-*-*-*-*-*-*-*-*-* 获取操作系统版本信息结束 *-*-*-*-*-*-*-*-*-*-*/

:: ------------------------- 变量显示排版代码开始 -----------------------

:: --------变量注释开始--------
:: OS Version: %os_name_ver%
:: IP Address: %true_ip%
:: 省份: %true_province%
:: 城市: %true_city%
:: ISP:  %true_isp%
:: 日期: %rq1% %rq2% %rq3%
:: 温度: %wd1% %wd2% %wd3%
:: 天气: %tq1% %tq2% %tq3%
:: --------变量注释结束--------

setlocal EnableDelayedExpansion
set a=┌───────────────────────────────────┐
set b=│      %os_name_ver%       │
set c=├───────────────────────────────────┤
set d=│                      %true_province%%true_city%地区72小时天气预报                      │
set e=├───────────┬───────────┬───────────┤
set f=│      %rq1%      │     %rq2%       │     %rq3%       │
set g=├───────────┼───────────┼───────────┤
set h=│      %wd1%      │     %wd1%       │     %wd1%       │
set i=├───────────┼───────────┼───────────┤
set j=│          %tq1%        │        %tq2%          │     %tq3%       │
set k=└───────────┴───────────┴───────────┘
for %%i in (a b c d e f g h i j k) do (
        set/p=   <nul
        for /l %%a in (0,1,100) do (
                if not "!%%i:~%%a,1!"=="" (
                        if %%a==100 echo.&echo;
                        set/p=!%%i:~%%a,1!<nul
                        for /l %%i in (1,1,70) do ver>nul
                )
        )
        echo.
)
endlocal
echo.
echo.
del %TEMP%\location.txt %TEMP%\cityInfo.txt %TEMP%\your_location.txt %TEMP%\source.txt %TEMP%\systeminfo.txt %TEMP%\eol.txt %TEMP%\Text.vbs %TEMP%\HTML.vbs >nul 2>nul
ping -n 6 >nul 2>nul

:: ━━━━━━━━━━━━━━━ 尾部声明开始 ━━━━━━━━━━━━━
setlocal DisableDelayedExpansion
set "P=                 各段代码的功能均有注释,不足之处,请多多指教 !!!"
set "K="
for /l %%j in (1,1,10) do (
set/p=%P%<nul
set/p=%K%<nul
for /l %%i in (1,1,250) do ver>nul
set/p=                                                                  <nul
for /l %%i in (1,1,300) do ver>nul
set/p=%K%<nul
ping -n 1 127.1 >nul 2>nul
)
echo.
(Set,=                        http://kumho.lin.googlepages.com&For,/L,%%g,in,(0,1,85)Do,@Call,Set/P=%%,:~%%g,1%%<Nul&Ping/n 1 127.1>Nul)&Set,=&Ping -n 4 127.1>Nul
:: ━━━━━━━━━━━━━━━ 尾部声明结束 ━━━━━━━━━━━━━
:: ------------------------- 变量显示排版代码结束 -----------------------
:quit
exit

:FullScreen
::查询显示模式

Set ShowMode=0
for /f "delims=" %%i in ('REG QUERY HKEY_CURRENT_USER\Console /v "FullScreen"') do set ShowMode=%%i
Set ShowMode=%ShowMode:~-1%

::设置显示模式为全屏
REG ADD HKEY_CURRENT_USER\Console /v FullScreen /t REG_DWORD /d 1 /f>nul

::全屏启动当前脚本
start "" %0 %ShowMode%

   ┌───────────────────────────────────┐
   │      Microsoft Windows XP Professional 5.1.2600 Service Pack 2       │
   ├───────────────────────────────────┤
   │                      广东广州地区72小时天气预报                      │
   ├───────────┬───────────┬───────────┤
   │            │            │            │
   ├───────────┼───────────┼───────────┤
   │            │            │            │
   ├───────────┼───────────┼───────────┤
   │                  │                  │            │
   └───────────┴───────────┴───────────┘