中国DOS联盟

自己所要的功能已经实现，就是代码感觉有点繁琐，不知道能不能精简下
主要是为了学习下CMD的一些技巧

::将下载的CHM格式电子书与手机中的相应文件进行比较

::手机中文件为了阅读方便，可能已经更名为"原文件名+阅读章节数字.CHM"的格式

::如果下载文件比手机中的文件大，就将其复制到手机中并保留手机中已经更改过的文件名

::2008-03-06 By SunTB



@echo off



set book=E:\Downloads\书籍

echo.&set /p udisk=请输入手机U盘分区号（如在 N 盘就输入 N ）: 



    for /f "skip=7 tokens=4,5 delims=. " %%b in ('dir "%book%\*.chm" /on /-c') do (

      for /f "skip=7 tokens=4,5 delims=. " %%u in ('dir "%udisk%:\*.chm" /on /-c') do (

        for /f "delims=0123456789 " %%n in ("%%v") do (

          if %%c==%%n (

            if /i %%b LEQ %%u (echo.&echo 文件 %%c.chm 没有更新)

            if /i %%b GTR %%u (

              echo.&echo 文件 %%c.chm 已经更新，正在复制至手机中......

              copy /y "%book%\%%c.chm" "%udisk%:\%%v.chm">nul

            )

          )

        )

      )

    )

    

echo.&echo 所有更新结束，按任意键退出

pause>nul

麻烦各位了　

经历了从对　for 一无所知到现在能尝试使用多重　for 循环

在DOS联盟论坛中受益匪浅　感谢各位兄弟之前的热心解答

在for的do后面频繁使用dir感觉效率是个问题，不如都用for来解决吧。
不过照你的代码思路来看，如果你的文件名出现下面的情况应该会出错。
E:\Downloads\书籍\无情剑.chm
U:\无情剑1.chm
U:\无情剑2.chm
又或者
E:\Downloads\书籍\无情剑.chm
U:\无情剑客1.chm

注：无情剑.chm和无情剑客.chm是两本书

@echo off

set book=E:\Downloads\书籍

echo.&set /p udisk=请输入手机U盘分区号（如在 N 盘就输入 N ）: 

for /r "%book%" %%a in (*.chm) do (

  for %%b in ("%udisk%:\%%~na*.chm") do (

    if %%~za leq %%~zb (echo.&echo 文件 %%~nxa没有更新) else (

	   echo.&echo 文件 %%~nxa已经更新，正在复制至手机中......

       copy /y "%book%\%%~nxa" "%udisk%:\%%~nxb">nul

    )

  )

)

echo.&echo 所有更新结束，按任意键退出

pause>nul

未测试

谢谢 26933062

代码测试可行