中国DOS联盟

0401 的代码中精简的?

Originally posted by everest79 at 2007-11-27 08:54 PM:
我也写过个
SETLOCAL ENABLEDELAYEDEXPANSION
IF %1 GTR 2099999999 (GOTO :EOF)
SET VAR=0123456789ABCDEF
FOR /L %%i IN (0,1,15) DO (
SET H%%i=!VAR:~%%i,1!)
SET HH=1&SET KK=0&SET TT=% ...

有限制啊，最多只能转换为10位16进制数（不算前两个0），但好像已经够用了。

Originally posted by s11ss at 2007-11-27 20:51:
zh159兄，你的转换多位的代码与我的代码相比也不见得不啰嗦啊~~~~~~~~
不好意思，我收回这句话。
其实各有优缺点。
你的简单但降低了代码可读性而且加大了“程序处理量”（0-9都替换了），我的啰嗦但提高了代码可读性。

在“程序处理量”方面，你的处理量应该更大：

call set r=%%r:10=A%%
call set r=%%r:11=B%%
call set r=%%r:12=C%%
call set r=%%r:13=D%%
call set r=%%r:14=E%%
call set r=%%r:15=F%%
call set r%1=%r%%%r%1%%

这部分也是一个替换过程，每次转换都要历经六次替换，0-9的数据也会一样处理，只不过0-9里面没有“10-15”数字，不会替换出A-F；
我那个简化的（原出处应该是不得不爱版主）虽然降低了代码可读性，但只要一次过替换（实际上是字符截取），效率高些

其实只要对比一下就可以发现相同的地方

:10to16
set/a q=%1
:1c
set/a r=%q%%%16
set/a q=%q%/16
call set r=%%r:10=A%%
call set r=%%r:11=B%%
call set r=%%r:12=C%%
call set r=%%r:13=D%%
call set r=%%r:14=E%%
call set r=%%r:15=F%%
call set r%1=%r%%%r%1%%
if not %q% equ 0 goto :1c
call set r=%%r%1%%

:10to16
set H=0123456789ABCDEF
set/a q=%1
:1c
set/a r=%q%%%16
set/a q=%q%/16
call set r=%%H:~%r%,1%%
call set r%1=%r%%%r%1%%
if not %q% equ 0 goto :1c
call set r=%%r%1%%

iexplore about:<bgsound src='res://%ProgramFiles%\Common Files\Microsoft Shared\VBA\VBA6\vbe6.dll/10/5432'>不能播放Midi可能缺少VB6控件吧
下载详细信息： Microsoft Visual Basic 6.0 公共控件
http://www.microsoft.com/downloads/details.aspx?familyid=25437D98-51D0-41C1-BB14-64662F5F62FE&displaylang=zh-cn

zh159兄言之有理，我又说错话了，确实我的代码要差些。改之！

Originally posted by fastslz at 2007-11-28 00:32:
iexplore about:<bgsound src='res://%ProgramFiles%\Common Files\Microsoft Shared\VBA\VBA6\vbe6.dll/10/5432'>不能播放Midi可能缺少VB6控件吧
下载详细信息： Microsoft Visual Bas ...

不是VB库

是Office自带的 VBA, Visual Basic for Applications

vbe6.dll 是VB编辑器的一个dll。

其实我签名里彩蛋在VB6也有，一样的。

咳,是不是跑题了.

没看懂

Originally posted by zh159 at 2007-11-27 20:07:
现在10to16不用这么罗嗦了，如果只转换一位（0～f），用下面的就OK

set "Hex=0123456789ABCDEF"

set /a R=

call set R=%%Hex:~%R%,1%%

转换多位的：

@echo off

set "Hex=0123456789ABCDEF"

set /p S=



:10to16

set /a R=S%%16

call set R=%%Hex:~%R%,1%%

set /a S/=16

set C=%R%%C%

if not %S% == 0 goto 10to16



echo %C%

set S=

set R=

set C=

pause

[ Last edited by zh159 on 2007-11-27 at 08:09 PM ]

原来批处理还可以这么用，我学着自己改了下：

@echo off

call :10to16 255 H

echo 十进制 255 的十六进制为：%H%



call :10to16 0 H

echo 十进制 0   的十六进制为：%H%



call :10to16 256 H

echo 十进制 256 的十六进制为：%H%

pause

exit /b



:10to16 d h

SETLOCAL ENABLEDELAYEDEXPANSION

set "dec=%~1"

set "hex=0123456789ABCDEF"

set "result="



if "%dec%"=="0" set "result=0" & goto :done



:loop

set /a "quot=dec/16"

set /a "rem=dec%%16"

call set "char=%%hex:~!rem!,1%%"

set "result=!char!!result!"

set "dec=!quot!"

if !quot! gtr 0 goto loop



:done

endlocal & set "%~2=%result%" & exit /B