|
hpjustlove
新手上路
积分 12
发帖 5
注册 2008-7-18
状态 离线
|
『楼 主』:
写了个BAT，在日期计算上遇到些问题，望大虾指点
程序的目的就是输入一个日期，然后算出这个日期所在的那一周的周日是几号。
我大概的写了想，不过好像发现问题是出现后面的日期的加减上。大虾帮我看下是不是哪边要改下，或者是有错误，谢谢！
代码：
@echo off
setlocal enabledelayedexpansion
cls
:main
echo. 请输入需要计算的日期
echo. 格式如：08-07-17表示08年7月17日
set /p input= 请输入：
::获取输入数据，并分离出日期，月，年
set year1=%input:~0,2%
::将年前面加"20"字符为了能让星期计算公式正常计算
set year=20%year1%
set month=%input:~3,2%
set day=%input:~6,2%
::获得当天的日期
set tdy=%date:~4,12%
::计算输入的日期是星期几
set /a w=(day+2*month+3*(month+1)/5+year+year/4-year/100+year/400+1)%%7
::计算输入的日期所在周的周末的日期
set /a cw=7-w
::将输入的数据整理成日期格式
set inputday=%year%-%month%-%day%
::计算输入日期所在周的周日的日期
set /a outputday=inputday+cw
echo. 您输入的日期所在周的周日是：%outputday%
pause
goto main
|
|
 2008-7-18 19:38 |
|
|
HAT
版主
积分 9023
发帖 5017
注册 2007-5-31
状态 离线
|
『第
2 楼』:
set命令用来计算的话，应该这样写吧：
set a=100
set b=200
set /a c=%a%+%b%
|
 |
|
|
2008-7-18 20:17 |
|
|
bat-zw
金牌会员
永远的学习者
积分 3105
发帖 1276
注册 2008-3-8
状态 离线
|
『第
3 楼』:
其实计算日期这个问题比较复杂，这是我以前写的，楼主参考下吧：
@echo off&color 9f&mode con lines=10
title 星期查询器
:set
cls
echo.&echo.&echo.
set var=
set /p var= 请输入要查询的日期（格式为2000年08月08日）:
if "%var:~4,1%%var:~7,1%%var:~10,1%"=="年月日" goto year
cls
echo.&echo.&echo.
echo 输入格式不正确！请返回正确输入。&ping /n 3 127.1>nul&goto set
:year
set year=%var:~,4%
set /a str=(%year%-1904)/4&set /a str1=%year%-1904
for /l %%i in (0,1,3) do (
set a=%%i
setlocal enabledelayedexpansion
set /a str2=4*!str!+!a!
if !str1! equ !str2! goto month
)
:month
endlocal
if %a% equ 0 (set /a number1=%str%*1461) else (set /a number1=%str%*1461+%a%*365+1)
if %var:~5,1% equ 0 (set month=%var:~6,1%) else (set month=%var:~5,2%)
set /a month=%month%-1
if %month% equ 0 set /a number2=0&goto day
if %month% equ 1 set /a number2=31&goto day
if %month% equ 2 set /a number2=31+28
if %month% equ 3 set /a number2=31*2+28
if %month% equ 4 set /a number2=31*2+30+28
if %month% equ 5 set /a number2=31*3+30+28
if %month% equ 6 set /a number2=31*3+30*2+28
if %month% equ 7 set /a number2=31*4+30*2+28
if %month% equ 8 set /a number2=31*5+30*2+28
if %month% equ 9 set /a number2=31*5+30*3+28
if %month% equ 10 set /a number2=31*6+30*3+28
if %month% equ 11 set /a number2=31*6+30*4+28
if %a% equ 0 set /a number2=%number2%+1
:day
if %var:~8,1% equ 0 (set day=%var:~9,1%) else (set day=%var:~8,2%)
set /a number3=%day%-1
:week
set /a number=%number1%+%number2%+%number3%
set /a week=%number%/7
for /l %%i in (0,1,6) do (
set b=%%i
setlocal enabledelayedexpansion
set /a str=!week!*7+!b!
if !str! equ !number! goto echo
)
:echo
endlocal
set code=五六天一二三四
set /a move=%b%
cls
echo.&echo.&echo.
call,echo %var%那天是星期%%code:~%move%,1%%
pause>nul
cls
echo.&echo.&echo.
echo 本次查询结束，按键继续，结束请直接关闭窗口。
pause>nul&goto set
|
批处理之家新域名：www.bathome.net |
|
|
2008-7-18 20:39 |
|
|
HAT
版主
积分 9023
发帖 5017
注册 2007-5-31
状态 离线
|
『第
4 楼』:
纯批的可读性、可维护性相对较差，如果允许调用vbs的话，就简单多了：）
|
|
|
|
2008-7-18 20:52 |
|
|
hpjustlove
新手上路
积分 12
发帖 5
注册 2008-7-18
状态 离线
|
『第
5 楼』:
是想用vbs写函数，格式为：
call *.vbs [输入日期] [计算的天数] [输出日期]
碍于vbs压根就不懂，能不能帮忙找个合适的函数。
|
|
|
2008-7-19 08:51 |
|
|
slore
铂金会员
积分 5212
发帖 2478
注册 2007-2-8
状态 离线
|
『第
6 楼』:
msgbox #2008/7/19#+2
|
S smile 微笑,L love 爱,O optimism 乐观,R relax 放松,E enthusiasm 热情...Slore |
|
|
2008-7-19 09:08 |
|
|
hpjustlove
新手上路
积分 12
发帖 5
注册 2008-7-18
状态 离线
|
『第
7 楼』:
就这么一行？也得弄个几行吧。
我是要得到一个返回数然后参与下面的计算的。
|
|
|
2008-7-19 09:30 |
|
|
hpjustlove
新手上路
积分 12
发帖 5
注册 2008-7-18
状态 离线
|
『第
8 楼』:
大虾们看看，能不能就这个BAT更改下，作为函数调用。
@echo off
title 日期查询
color 1f
if [%1]==[] call :Help
call :Date2Day %1 days
set/a days=%days%+%2
call :Day2Date %days% date
echo.
echo -----------结果---------------
echo.
echo 你查询的日期为：%date%
echo ------------------------------
cmd /k
:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF
:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF
:Help
cls
echo ________________________________________________
echo 使用方法：%~nx0 [日期] [天数]
echo.
echo 日期格式：2007-03-31
echo 天数格式：+/-查询的天数
echo 示例：%~nx0 2007-03-31 3 就是查询3天后的日期
echo ________________________________________________
echo.
cmd /k
|
|
|
2008-7-19 09:32 |
|
|
slore
铂金会员
积分 5212
发帖 2478
注册 2007-2-8
状态 离线
|
『第
9 楼』:
返回数你只能用for得到……或者再次调用bat用参数的方式……
如果纯VBS完成就简单了
NewDate=#2008/7/19#+2
NewDate可以拉去计算……
|
S smile 微笑,L love 爱,O optimism 乐观,R relax 放松,E enthusiasm 热情...Slore |
|
|
2008-7-19 09:33 |
|
|
terse
银牌会员
积分 2404
发帖 946
注册 2005-9-8
状态 离线
|
『第
10 楼』:
重写一个 有帮助不？
@echo off
set/p y=请输入:(格式2008-1-11)
for /f "tokens=1-3 delims=-" %%i in ("%y%") do set y=%%i&set m=%%j&set d=%%k
if %m% leq 2 set/a y-=1,m+=12
set/a t=(d+2*m+3*(m+1)/5+y+y/4-y/100+y/400+1)%%7
if %t% neq 0 set/a t=7-t
:lp
if %m% gtr 12 set/a y+=1,m-=12
set/a PN2="!(y%%4) & !(!(y%%100)) | !(y%%400)",PN2=28+PN2
for /f "tokens=%m%" %%i in ("31 %pN2% 31 30 31 30 31 31 30 31 30 31") do set/a d+=t&set pt=%%i
if %d% leq %pt% goto p
set/a d-=pt
set t=0&&set/a m+=1&&goto lp
:p
echo %y%年%m%月%d%日 星期日
pause
|
简单!简单!再简单! |
|
|
2008-7-19 21:11 |
|
|
metoo
初级用户
积分 195
发帖 93
注册 2006-10-28
状态 离线
|
『第
11 楼』:
提个思路，让系统帮你算。。涉及月份变更的话还得改改，懒得动了
| Quote: |
- @echo off
- set ww1=%date%
- echo 请输入要查询的日期（例：2004-07-11)
- set /p tt=
- date %tt%
- echo %date%
- date %ww1:~0,-4%
- ping -n 2 127.1 >nul 2>nul
逐月鹰发表于： 2008-07-19 21:20 |
|
|
|
|
2008-7-19 21:31 |
|
