中国DOS联盟

我写了个批，什么都写完了，就是有个问题把我难住了，我想让这个批处理从第一次使用时后，30天之后失效，而且自动删除自己，，，，哪个高手支一招，小弟不才，我能把我想到的所有办法用尽了，还是不行，我失眠了~~~~~额？？？好像发错地方了，不好意思~~

谢谢大家帮助，问题已经解决

[ Last edited by mhymhymhy on 2009-4-23 at 03:14 ]

单纯的批命令做不到，不过可以用C或QB写一个小程序，第一次运行时把日期写到某个文件中，以后每次运行时读入日期与现在日期比较，发现差距大于30天就把自己与批文件删除。

第一次运行就往计划任务里加一个删除自身的计划，这是办法之一

或者往注册表记录第一次运行的时间，每次运行都对比一下时间。

可以这样。不知是否可行
if not exist tmp type %outime%>tmp
然后利用tmp的创建时间来作第一次运行参照时间。
%outime%为到期时间.

获取dir/TC tmp 和 %outime% 中的间作比较
到期启动自毁代码

[ Last edited by sady2009 on 2009-4-22 at 21:55 ]

%date%,%time% 与 %~t0 比较

用批处理写没有问题啊 ，不过没有上面说的那么简单。作为学习，自己多看多研究
多试。

1 从第一次运行使用必须记录日期
2 以后每次运行日期必须与第一次运行日期比较
3 （关键代码）年比较， 月比较，日比较（包括跨年，跨月）
4 显示剩余天数
5 自删除

[ Last edited by ZJHJ on 2009-4-23 at 11:37 ]

%~t0可以得到批处理文件本身的修改日期和时间,%date% %time% 可以得到当前日期时间,两者可以比较(比较麻烦,只是提供个思路~~)

如果要精确处理：
可以用批处理时间函数(本坛有下载）把当前日期转化为1970年1 1以来的秒数。
完全变成了一般一数字运算。
30天以后的秒数就是30*24*3600. 最后再把秒数转回成日期。

不需要再考虑年月日还有闰年闰月的问题。



这样就简单了。

没事帮你写一个，呵呵。

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1-8 delims=-/:. " %%a in ("%date% %time%") do (call :datetosecs %%a %%b %%c %%e %%f %%g sec1&set "today=%%a-%%b-%%c %%e:%%f:%%g")
for /f "tokens=1-6 delims=-/:. " %%a in ("%~t0") do (call :datetosecs %%a %%b %%c %%e %%e 0 sec0)
::30天到期修改此处
set /a out=30*24*3600+sec0&call :SecsToDate !out! y1 m1 d1 hh1 mm1 ss1
::倒计时时间
set /a free=(out-sec1)/3600/24
::即将到期警告时间
set /a zy=out-5*3600

echo 启用时间:%~t0:00
echo 到期时间:!y1!-!m1!-!d1! !hh1!:!mm1!:!ss1!
echo 当前时间:!today!
if !sec1! gtr !zy! (echo 注意:到期只有!free!天，请尽快充值!:D) else echo 您还能免费享受：!free!天
::到期处理
if !sec1! gtr !out! (
echo 已到期,进入自杀模式，请稍等...
ping 127.0.0.1 -n 2 >nul 2>nul
echo bye bye!
del /Q XXX.bat
)

::以下写主程序或用call start命令




goto: eof
:datetosecs
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5&set ss=%6
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
set /a j=j*86400+hh*3600+nn*60+ss
endlocal&set %7=%j%&goto :EOF

:SecsToDate
set /a i=%1,ss=i%%60,i/=60,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
if %ss% LSS 10 set ss=0%ss%
endlocal&set %7=%ss%&set %6=%nn%&set %5=%hh%&^
set %4=%dd%&set %3=%mm%&set %2=%yy%&goto :EOF

没有防止日期倒改功能

这个问题很郁闷人，因为有两个可能：
1，如果别人能看懂这个批处理，那么无论用什么方法，只要删除此批处理的相关部分就可以了。。。
2，如果别人看不懂，那么我觉得3楼的办法简单，使用at或Schtasks创建一个任务计划，并在创建之前先检测是否已存在该计划就可以。