『楼 主』:
网络小说更新追踪查看器
喜欢常看网络玄幻小说,比如盘龙,斗罗大陆等
检测网络小说更新与否,并可直接以记事本打开更新内容,避免了去网站看小说而弹出广告的烦脑.
@echo off
color f0
setlocal enabledelayedexpansion
title 小说更新追踪器 for AX
set strXs=盘龙 斗罗大陆 斗破苍穹 长生界 天王 破灭时空 逍行纪 比蒙传奇 星辰变后传
:lpStart
cls&echo.&set tmpA=&for %%k in (!strXs!) do set /a tmpA+=1&call :subXsVbs "%%k" !tmpA!
for /l %%i in (1,1,80) do <nul set /p=+
echo.&echo [ %date% ] [ %time%]
echo.&set strOpenUrl=&set /p strOpenUrl= 输入要打开的小说代号:
call :subRel !strOpenUrl! 3
goto lpStart
:subXsVbs
echo Set http=createobject("Microsoft.XMLHTTP") >!tmp!\xsCheck.vbs
echo Set objfs=CreateObject("scripting.filesystemobject") >>!tmp!\xsCheck.vbs
echo Set objf=objfs.CreateTextFile("!tmp!\xsResult.txt",True) >>!tmp!\xsCheck.vbs
echo url="http://xntk.net/search.php?keyword=%~1" >>!tmp!\xsCheck.vbs
echo http.open "get",url,false >>!tmp!\xsCheck.vbs
echo http.send >>!tmp!\xsCheck.vbs
echo zhi=zhuanghuan(Http.responsebody) >>!tmp!\xsCheck.vbs
echo s=(zhi) >>!tmp!\xsCheck.vbs
echo objf.write s >>!tmp!\xsCheck.vbs
echo Function zhuanghuan(vIn) >>!tmp!\xsCheck.vbs
echo strReturn = "" >>!tmp!\xsCheck.vbs
echo For i = 1 To LenB(vIn) >>!tmp!\xsCheck.vbs
echo ThisCharCode = AscB(MidB(vIn,i,1)) >>!tmp!\xsCheck.vbs
echo If ThisCharCode ^< ^&H80 Then >>!tmp!\xsCheck.vbs
echo strReturn = strReturn ^& Chr(ThisCharCode) >>!tmp!\xsCheck.vbs
echo Else >>!tmp!\xsCheck.vbs
echo NextCharCode = AscB(MidB(vIn,i+1,1)) >>!tmp!\xsCheck.vbs
echo strReturn = strReturn ^& Chr(CLng(ThisCharCode) * ^&H100 + CInt(NextCharCode)) >>!tmp!\xsCheck.vbs
echo i = i + 1 >>!tmp!\xsCheck.vbs
echo End If >>!tmp!\xsCheck.vbs
echo Next >>!tmp!\xsCheck.vbs
echo zhuanghuan = strReturn >>!tmp!\xsCheck.vbs
echo End Function >>!tmp!\xsCheck.vbs
cscript //nologo !tmp!\xsCheck.vbs
for /f "skip=80 delims=" %%i in (!tmp!\xsResult.txt) do set strHtp=%%i&set strDate=%%i&set strUrl=%%i&goto flag1
:flag1
set tmpVal=&for /l %%i in (1,1,2000) do if "!strDate:~%%i,11!"=="td width=15" set /a tmpVal=%%i + 26 & call :subRel !tmpVal! 1&goto flag2
:flag2
for /l %%i in (1,1,2000) do if "!strHtp:~%%i,1!"=="第" set strHtp=!strHtp:~%%i,30!&goto flag3
:flag3
set tmpVal=&for /l %%i in (1,1,2000) do if "!strUrl:~%%i,6!"=="href=/" set /a tmpVal=%%i + 6 & call :subRel !tmpVal! 2&goto flag4
:flag4
for /l %%i in (1,1,50) do (
if "!strHtp:~%%i,1!"=="<" set strHtp=!strHtp:~0,%%i!
if "!strUrl:~%%i,1!"==">" set strUrl=!strUrl:~0,%%i!)
set strUrl%2=http://xntk.net/!strUrl!
echo !strUrl%2!>!tmp!\xsUrlLink%2.txt
set strXsUpdate=
set strShortDate=!date:~2,8!
if "!strShortDate!"=="!strDate!" set strXsUpdate=★今日已更新★
echo %2 《%~1》 ：!strHtp! [!strDate!] !strXsUpdate!&echo.
goto :eof
:subXsRead
echo Set oDOM = WScript.GetObject(%1) >!tmp!\xsTmp.vbs
echo do until oDOM.readyState = "complete" >>!tmp!\xsTmp.vbs
echo WScript.sleep 200 >>!tmp!\xsTmp.vbs
echo loop >>!tmp!\xsTmp.vbs
echo WScript.echo oDOM.documentElement.outerText >>!tmp!\xsTmp.vbs
cscript //NoLogo /e:vbscript !tmp!\xsTmp.vbs >!tmp!\xsRead1.txt
del !tmp!\xsRead2.txt >nul 2>nul
for /f "skip=5 delims=" %%i in (!tmp!\xsRead1.txt) do set tmpStr=%%i&if not "!tmpStr:~0,6!"=="论坛贴子链接" (echo %%i>>!tmp!\xsRead2.txt&echo.>>!tmp!\xsRead2.txt) else goto flagOut
:flagOut
goto:eof
:subRel
if %2 equ 1 set strDate=!strDate:~%1,8!
if %2 equ 2 set strUrl=!strUrl:~%1,50!
if %2 equ 3 for /f "delims=" %%i in (!tmp!\xsUrlLink%1.txt) do call :subXsRead "%%i"&start /max notepad "!tmp!\xsRead2.txt"
goto :eof
|
