中国DOS联盟

@echo off
if not %1*==* set num1=%1 & set num2=%2 & goto jmp
:input
cls
set num1=
set /p num1=input primary number:
set num2=
set /p num2=input number two number:
:jmp
set numx=%num1%
set numy=%num2%
echo %num1% | find "." >nul || set num1=%num1%.0
echo %num2% | find "." >nul || set num2=%num2%.0
if "%num1:~-1%"=="." set num1=%num1%0
if "%num2:~-1%"=="." set num2=%num2%0
if "%num1:~0,1%"=="." set num1=0%num1%
if "%num2:~0,1%"=="." set num2=0%num2%
set num=0
setlocal enabledelayedexpansion
for %%a in (%num1% %num2%) do (
    set /a num+=1
    for /f "tokens=1,2 delims=." %%i in ("%%a") do (
        if "!num!"=="1" (set one=%%i) else (set one_=%%i)
        if "!num!"=="1" (set two=%%j) else (set two_=%%j)
    )
)
call :omit %one%
set one=%want%
call :omit %one_%
set one_=%want%
call :raze %two%
set two=%want_%
call :raze %two_%
set two_=%want_%
if "%one%"=="" set one=0
if "%one_%"=="" set one_=0
call :go %one%
set countx=%wish%
call :go %one_%
set countx_=%wish%
if "%two%"=="" set two=0
if "%two_%"=="" set two_=0
call :go %two%
set county=%wish%
call :go %two_%
set county_=%wish%
set after=
set front=0
if %countx% lss %countx_% (
    set /a result=%countx_%-%countx%
    call :fine !result! %one%
    set one=!incept!
) else (
    set /a result=%countx%-%countx_%
    call :fine !result! %one_%
    set one_=!incept!
)
set after=0
set front=
if %county% lss %county_% (
    set /a result=%county_%-%county%
    call :fine !result! %two%
    set two=!incept!
) else (
    set /a result=%county%-%county_%
    call :fine !result! %two_%
    set two_=!incept!
)
set outcome=0
call :scale @%two% @%two_%
set decimal=%numeral:~0,-1%
call :scale @%one% @%one_%
if "%note%"=="0" (
    set integer=%numeral:~0,-1%
) else (
    set integer=1%numeral:~0,-1%
)
call :raze %decimal%
set decimal=%want_%
if "%decimal%"=="" (set dot=) else (set dot=.)
if "%numx:~0,1%"=="." set numx=0%numx%
if "%numy:~0,1%"=="." set numy=0%numy%
if "%numx:~-1%"=="." set numx=%numx:~0,-1%
if "%numy:~-1%"=="." set numy=%numy:~0,-1%
cls
echo ===============
echo 运算结果^^!
echo ===============
echo.
echo.
echo %numx%+%numy%=%integer%%dot%%decimal%
pause >nul
goto :eof

:scale
set value=%1
set value_=%2
set numeral=
:repeat
set numeral=%outcome:~-1%%numeral%
set note=0%outcome:~0,-1%
if not "%value:~-1%"=="@" (
    set xx=!value:~-1!
    set value=!value:~0,-1!
)
if not "%value_:~-1%"=="@" (
    set yy=!value_:~-1!
    set value_=!value_:~0,-1!
    call :operation !xx! !yy!
)
goto :eof
:operation
set refer=%1
set refer_=%2
set /a outcome=%refer%+%refer_%+%note%
goto repeat
:go
set remove=%1@
set wish=0
:go_
if not "!remove:~0,1!"=="@" (
    set fault=1
    for /l %%c in (0,1,9) do (
        if "!remove:~0,1!"=="%%c" (
            set /a wish+=1
            set remove=!remove:~1!
            set fault=2
            goto go_
        )
    )
    if "!fault!"=="1" goto error
    goto go_
)
goto :eof
:fine
set take=%1
set incept=%2
:fine_
if not "%take%"=="0" (
    set /a take-=1
    set incept=%front%!incept!%after%
    goto fine_
)
goto :eof
:omit
set want=%1
:omit_
if "%want:~0,1%"=="0" (
    set want=%want:~1%
    goto omit_
)
goto :eof
:raze
set want_=%1
:raze_
if "!want_:~-1!"=="0" (
    set want_=!want_:~0,-1!
    goto raze_
)
goto :eof
:error
cls
echo =====================================
echo.
echo 你的输入了非法字符^^!
echo.
echo =====================================
echo.
echo.
echo 按任意键重新输入...
pause >nul
goto input

@echo off
:: 分别把两个数的整数和小数部分提取出来
:: 整数部分在高位用0补齐，小数部分在低位用0填充，使得两个数的数位各自对齐
:: 从小数的最低位开始，按位计算两个数的和，超过9就向次高位进1，只到整数的最高位为止
:: 例如：要计算 4567.5+5.6789，则处理后的数字为4567.5000+0005.6789，然后按位做加法操作

:main
cls
set num1=
set num2=
set /p num1=请输入第一个数：
call :input_check "%num1%" num1
set /p num2=请输入第二个数：
call :input_check "%num2%" num2

setlocal enabledelayedexpansion
for /f "tokens=1-4 delims=." %%i in ("%num1%.%num2%") do (
    set int1=%%i
    set int2=%%k
    set dec1=%%j
    set dec2=%%l
    call :get_length int1 %%i
    call :get_length int2 %%k
    call :get_length dec1 %%j
    call :get_length dec2 %%l
    call :add_zero
    call :sum
)
pause
goto :eof

:input_check
rem =========== 检测输入是否正确 ===========
echo %1|findstr "\.">nul||set %~2=%~1.0
for /f "tokens=1* delims=." %%i in (%1) do (
    echo %%i%%j|findstr "^[0-9]*$">nul || goto main
)
goto :eof   

:get_length
rem =========== 计算各部分数字的长度 ===========
set count=0
:intercept
set /a count+=1
for /f %%i in ("%2") do (
    set var=%%i
    if not "!var:~%count%,1!"=="" goto intercept
    set %1_length=!count!
)
goto :eof

:add_zero
rem =========== 分别在整数部分和小数部分添加0字符串 ===========
:: 在数位不够的整数部分添0补齐
set /a int_length_diff=%int1_length%-%int2_length%
set int_length_diff=%int_length_diff:-=%
call :creat_zero int_zero %int_length_diff%
if %int1_length% gtr %int2_length% (
    set int2=%int_zero%%int2%
    set int_length_max=%int1_length%
    ) else (
    set int1=%int_zero%%int1%
    set int_length_max=%int2_length%
)
:: 在数位不够的小数部分添0补齐
set /a dec_length_diff=%dec1_length%-%dec2_length%
set dec_length_diff=%dec_length_diff:-=%
call :creat_zero dec_zero %dec_length_diff%
if %dec1_length% gtr %dec2_length% (
    set dec2=%dec2%%dec_zero%
    set dec_length_max=%dec1_length%
    ) else (
    set dec1=%dec1%%dec_zero%
    set dec_length_max=%dec2_length%
)
goto :eof

:creat_zero
rem =========== 根据数字字符串长度的差异，生成相应长度的0字符串 ===========
set zero=
for /l %%i in (1,1,%2) do set zero=!zero!0
set %1=%zero%
goto :eof

:sum
rem =========== 对小数部分和整数部分分别求和 ===========
:: 计算小数部分
set dec_sum=
set tmp_sum=
set switch=0
for /l %%i in (1,1,%dec_length_max%) do (
    set dec1_char=!dec1:~-%%i,1!
    set dec2_char=!dec2:~-%%i,1!
    set /a tmp_sum=!dec1_char!+!dec2_char!+!switch!
    if !tmp_sum! gtr 9 (
        set /a tmp_sum=!tmp_sum!-10
        set switch=1
        ) else (
        set switch=0
    )
    set dec_sum=!tmp_sum!!dec_sum!
)

:: 计算整数部分
set int_sum=
set tmp_sum=
for /l %%i in (1,1,%int_length_max%) do (
    set int1_char=!int1:~-%%i,1!
    set int2_char=!int2:~-%%i,1!
    set /a tmp_sum=!int1_char!+!int2_char!+!switch!
    if !tmp_sum! gtr 9 (
        set /a tmp_sum=!tmp_sum!-10
        set switch=1
        ) else (
        set switch=0
    )
    set int_sum=!tmp_sum!!int_sum!
)
if %switch% equ 1 (
    echo  %num1%+%num2%=1%int_sum%.%dec_sum%
    ) else (
    echo  %num1%+%num2%=%int_sum%.%dec_sum%
)
goto :eof

@echo off
setlocal enabledelayedexpansion
if not %1*==* (set num1=%1&if not %2*==* (set num2=%2&goto jmp) ELSE goto err)
ECHO 1
:input
set/p num1=请输入第一个小数:
set/p num2=请输入第二个小数:
:jmp
if %num1%*==* goto err
if %num2%*==* goto err
set err=0
if %num1:~0,1%==. set num1=0%num1%
call :qc "%num1%" num1
if %num2:~0,1%==. set num2=0%num2%
call :qc "%num2%" num2
if %err%==1 goto err
for /f "tokens=1* delims=." %%a in ("%num1%") do (set o1=%%a
set t1=%%b)
for /f "tokens=1* delims=." %%a in ("%num2%") do (set o2=%%a
set t2=%%b)
call :qs0 %o1%
set o1=%sw%
call :qs0 %o2%
set o2=%sw%
call :qw0 %t1%
set t1=%sw%
call :qw0 %t2%
set t2=%sw%
call :js %t1%
set s1=%sw%
call :js %t2%
set s2=%sw%
If %s1% Geq %s2% (set/a s3=%s1%-%s2%
call :j0 !s3! %t2%
set tmp1=%o1%%t1%
set tmp2=%o2%!sw!
) ELSE (set/a s3=%s2%-%s1%
call :j0 !s3! %t1%
set tmp1=%o1%!sw!
set tmp2=%o2%%t2%
set s1=%s2%)
set jg1=0
set jg=
ECHO %tmp1% %tmp2%
:js2
set/a jg0=%tmp1:~-1%+%tmp2:~-1%+%jg1%
set jg1=0%jg0:~0,-1%
set jg=%jg0:~-1%%jg%
set tmp1=%tmp1:~0,-1%
set tmp2=%tmp2:~0,-1%
if %tmp1%*==* (if %tmp2%*==* (if %jg1%==01 (set jg=1%jg%&goto xs) ELSE goto xs) ELSE set tmp1=0&goto js2)
if %tmp2%*==* (if %jg1%==01 (set tmp2=0&goto js2) ELSE (set jg=%tmp1%%jg%&goto xs))
goto js2
:xs
call :qw0 !jg:~-%s1%!
set jg=!jg:~0,-%s1%!.%sw%
if %jg:~-1%==0 set jg=%jg:~0,-2%
:cls
echo 计算结果是：
if not %t1%==0 set o1=%o1%.%t1%
if not %t2%==0 set o2=%o2%.%t2%
echo %o1%+%o2%=%jg%
pause
goto :eof

:qs0
set sw=%1
:qs1
if %sw%==0 goto :eof
if %sw:~0,1%==0 set sw=!sw:~1!&goto qs1
goto :eof
:qw0
set sw=%1
:qw1
if %sw%==0 goto :eof
if %sw:~-1%==0 set sw=!sw:~0,-1!&goto qw1
goto :eof
:js
set sw=0
set sw1=%1
if %sw1%==0 set sw=1&goto :eof
:js1
if not %sw1%*==* set sw1=%sw1:~1%&set/a sw+=1&goto js1
goto :eof
:qc
echo %1|findstr "\.">nul||set %~2=%~1.0
for /f "tokens=1* delims=." %%i in (%1) do echo %%i%%j|findstr "^[0-9]*$">nul||set err=1
goto :eof
:j0
set sw1=%1
set sw=%2
if %sw1%==0 goto :eof
for /l %%c in (1,1,%sw1%) do set sw=!sw!0
goto :eof
:err
echo 你输入了非法字符^!
echo 请重新输入...
goto input