中国DOS联盟

@echo off
:: 把半角双引号换成空格，把等号换成〓，兼容其他特殊字符
:: 能处理以分号打头的行，但是会忽略空行
:: 能兼容unicode格式的文本
:: 每行之间空一行显示
for /f "delims= eol=" %%i in ('type %1') do (
    set "str=%%i"
    call set "str=%%str:"= %%"
    call :pickup
)
pause
goto :eof

:pickup
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.&echo.
goto :eof

@echo off
:: 与版本一的几点区别：
::　　 1、不能处理unicode文本
:: 　　2、每行之间不再强行加上空行，并且能原样显示空行
for /f "delims= eol=" %%i in ('findstr /n .* %1') do (
    set "str=%%i"
    call set "str=%%str:"= %%"
    call set "str=%%str:*:=%%"
    call :pickup
)
echo.
pause
goto :eof

:pickup
if not defined str echo.&goto :eof
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "=%str:~0,1%"<nul
ping -n 1 127.1>nul
set "str=%str:~1%"
if defined str goto pickup
echo.
goto :eof

@echo off

:: 逐行逐字阅读文本，并且原样显示文本内容
:: ① 为了显示文本的所有内容，使用了for+findstr的句式
:: ② 为了能原样显示文本，使用变量延迟并在合适的位置终止延迟
:: ③ 为了能正确显示引号和等号，在语句 set /p= !str:~0,1!<nul 中，等号后空一格，并使用退格键

for /f "delims=" %%i in ('findstr /n .* test.txt') do (
    set "str=%%i"
    setlocal enabledelayedexpansion
    set str=!str:*:=!
    call :pickup
    endlocal
)
pause
goto :eof

:pickup
ping -n 1 127.1>nul
if defined str (
    set /p= !str:~0,1!<nul
    set str=!str:~1!
    goto pickup
)
echo.
goto :eof