标题: 依次横向显示文档中的字符 [打印本页]
作者: 26933062 时间: 2007-2-2 14:41 标题: 依次横向显示文档中的字符
a.txt内容如下
abcefg
1234567
yuhgrte
问题:我运行以下批处理后,显示完第一排字符后就停了,有什么办法能继续显示后面的字符?
@echo off
set s=0
for /f "delims=" %%i in (a.txt) do call :xs %%i
goto :eof
:xs
set a=%1
:top
echo.|call set /p b=%%a:~%s%,1%%
set /a s+=1
goto top
作者: PPdos 时间: 2007-2-2 17:38
学习楼主程序
在下愚见 认为:xs没有定义退出循环的条件 从而不能进入第二行的显示
作者: anqing 时间: 2007-2-2 22:08
xs
set a=%1
:top
echo.|call set /p b=%%a:~%s%,1%%
set /a s+=1
goto top
这些地方看不懂？
作者: namejm 时间: 2007-2-2 22:32
试试下面的代码：
版本一：
@echo off
:: 如果有半角双引号，将不能继续处理下去，但是可以兼容除等号外的其他特殊字符
:: 如果有等号，将在等号出现的地方报错，但可以继续处理下一个字符
:: 忽略以引号打头的行，忽略空行
:: 不能处理unicode格式文本
for /f "delims=" %%i in (test.txt) do (
set "str=%%i"
call :pickup
)
pause
goto :eof
:pickup
ping -n 1 127.1>nul
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if not "%str%"=="" goto pickup
echo.
goto :eof
版本二：:: 如果有半角双引号，将不能继续处理下去，但是可以兼容除等号外的其他特殊字符
:: 如果有等号，将在等号出现的地方报错，但可以继续处理下一个字符
:: 忽略以引号打头的行，忽略空行
:: 不能处理unicode格式文本
for /f "delims=" %%i in (test.txt) do (
set "str=%%i"
call :pickup
)
pause
goto :eof
:pickup
ping -n 1 127.1>nul
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if not "%str%"=="" goto pickup
echo.
goto :eof
@echo off
:: 把半角双引号换成空格，把等号换成〓，兼容其他特殊字符
:: 能处理以分号打头的行，但是会忽略空行；
:: 能兼容unicode格式的文本
:: 每行之间空一行显示
for /f "delims= eol=" %%i in ('type test.txt') do (
set "str=%%i"
call set "str=%%str:"= %%"
call :pickup
)
pause
goto :eof
:pickup
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.&echo.
goto :eof
版本三：:: 把半角双引号换成空格，把等号换成〓，兼容其他特殊字符
:: 能处理以分号打头的行，但是会忽略空行；
:: 能兼容unicode格式的文本
:: 每行之间空一行显示
for /f "delims= eol=" %%i in ('type test.txt') do (
set "str=%%i"
call set "str=%%str:"= %%"
call :pickup
)
pause
goto :eof
:pickup
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.&echo.
goto :eof
@echo off
:: 与版本二的几点区别：
:: 1、不能处理unicode文本
:: 2、每行之间不再强行加上空行，并且能原样显示空行
for /f "delims= eol=" %%i in ('findstr /n .* test.txt') do (
set "str=%%i"
call set "str=%%str:"= %%"
call set "str=%%str:*:=%%"
call :pickup
)
pause
goto :eof
:pickup
if not defined str echo.&goto :eof
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.
goto :eof
[ Last edited by namejm on 2007-2-2 at 01:42 PM ]:: 与版本二的几点区别：
:: 1、不能处理unicode文本
:: 2、每行之间不再强行加上空行，并且能原样显示空行
for /f "delims= eol=" %%i in ('findstr /n .* test.txt') do (
set "str=%%i"
call set "str=%%str:"= %%"
call set "str=%%str:*:=%%"
call :pickup
)
pause
goto :eof
:pickup
if not defined str echo.&goto :eof
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.
goto :eof
作者: anqing 时间: 2007-2-2 23:10
版主的可行，这么显示，挺有意思的
作者: 26933062 时间: 2007-2-3 02:07
学习了 谢谢版主!!!!!!!!
不过我还是没搞明白,我的为什么会停住,set /p 以后只要没了字符就停了,
还有你的 <nul 是什么意识?
作者: namejm 时间: 2007-2-3 02:53
你的代码因为在goto top的时候，没有判断某一行的字符是否取尽，从而造成了死循环，所以会一直在处理第一行而不能处理下一行。
<nul 在set/p中的作用是：在同一行上显示每次获取到的内容。
作者: minmin888 时间: 2007-5-8 10:22
学到东西! 多谢版主!