标题: 小写字母转大写 [打印本页]
作者: namejm 时间: 2007-1-17 07:01 标题: 小写字母转大写
字母小写转大写，可以通过罗列 set str=%str:a=A%、set str=%str:b=B%……的方式来解决，但是，这是纯体力活，毫无技巧可言。以下演示代码能让你在把字母小写转换为大写的时候，不再做毫无乐趣可言的 复制+粘贴+修改 这一重复劳动：
@echo off
:: 稍微修改一下代码就可以实现大写转小写
set str1=abcdefghijklmnopqrstuvwxyz
set str2=ABCDEFGHIJKLMNOPQRSTUVWXYZ
:main
cls
set str=
set /p str= 请输入字符串(退出请直接按回车)：
if not defined str exit
cls
echo.
echo 转换前："%str%"
echo.
for /l %%i in (0,1,25) do (
call set char1=%%str1:~%%i,1%%
call set char2=%%str2:~%%i,1%%
call :change
)
echo ____________________________________________
echo.
echo 转换后："%str%"
echo.
echo 按任意键进行下一次演示...
pause>nul
goto main
:change
call set "str=%%str:%char1%=%char2%%%"
goto :eof
:: 稍微修改一下代码就可以实现大写转小写
set str1=abcdefghijklmnopqrstuvwxyz
set str2=ABCDEFGHIJKLMNOPQRSTUVWXYZ
:main
cls
set str=
set /p str= 请输入字符串(退出请直接按回车)：
if not defined str exit
cls
echo.
echo 转换前："%str%"
echo.
for /l %%i in (0,1,25) do (
call set char1=%%str1:~%%i,1%%
call set char2=%%str2:~%%i,1%%
call :change
)
echo ____________________________________________
echo.
echo 转换后："%str%"
echo.
echo 按任意键进行下一次演示...
pause>nul
goto main
:change
call set "str=%%str:%char1%=%char2%%%"
goto :eof
作者: tao0610 时间: 2007-1-17 07:08
不错,不过还是习惯用Ultraedit转换.
作者: zh159 时间: 2007-1-17 09:53
好像不用这么复杂，一句for就搞定：
@echo off
:main
cls
set str=
set /p str= 请输入字符串(退出请直接按回车)：
if not defined str exit
cls
echo.
echo 转换前："%str%"
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set str=%%str:%%i=%%i%%
echo ____________________________________________
echo.
echo 转换后："%str%"
echo.
echo 按任意键进行下一次演示...
pause>nul
goto main
大转小改一下(a b c d e f g h i j k l m n o p q r s t u v w x y z)就OK:main
cls
set str=
set /p str= 请输入字符串(退出请直接按回车)：
if not defined str exit
cls
echo.
echo 转换前："%str%"
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set str=%%str:%%i=%%i%%
echo ____________________________________________
echo.
echo 转换后："%str%"
echo.
echo 按任意键进行下一次演示...
pause>nul
goto main
[ Last edited by zh159 on 2007-1-16 at 08:54 PM ]
作者: namejm 时间: 2007-1-17 09:59
3楼充分利用了替换语句不区分大小写的特点，巧妙。
作者: redtek 时间: 2007-1-17 10:07
１楼和３楼代码的两种不同解决方法太精彩了～：）））
[ Last edited by redtek on 2007-1-16 at 09:08 PM ]
作者: tashaxin 时间: 2007-1-20 08:20
果然利害、
作者: greenworld 时间: 2007-9-15 21:48
多谢LZ和3 楼的老大,强啊,学习了.......
作者: 106942397 时间: 2008-5-11 17:10
不知为了什么搞那复杂呢?
setlocal ENABLEDELAYEDEXPANSION
set /p str=请输入字符串(退出请直接按回车)：
for /l %%l in (0,1,100) do (
call set s%%l=!str:~%%l,1!
set Q=!s%%l!
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if /i !Q!==%%i set/p=%%i<nul
)
if "!Q!"=="" goto :Q1
)
:Q1
ECHO\
%0
这样可以吗？
[ Last edited by 106942397 on 2008-5-11 at 09:29 PM ]
作者: 26933062 时间: 2008-5-11 17:33
呵呵，8楼 请你输入 abcd 然后运行你的代码和3楼的代码 对比一下结果。
再说了，3楼的比你的复杂吗？
作者: 106942397 时间: 2008-5-11 21:24
大小写互换
setlocal ENABLEDELAYEDEXPANSION
set /p str=请输入字符串(退出请直接按回车)：
for /l %%l in (0,1,100) do (
call set s%%l=!str:~%%l,1!
set Q=!s%%l!
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
for %%k in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
if !Q!==%%i if /i !Q!==%%k set/p=%%k<nul
if !Q!==%%k if /i !Q!==%%i set/p=%%i<nul
))
if "!Q!"=="" goto :Q1
)
:q1
echo\
%0
[ Last edited by 106942397 on 2008-5-11 at 09:30 PM ]
作者: olslyang 时间: 2008-6-20 22:36
老大，那个罗列的地方我看不懂，能不能给讲一下！不明白那个替换语句的用法！
str=%%str:%%i=%%i%%这一段我理解不了，有高人给指点一下不！！
我的QQ 362998909
作者: olslyang 时间: 2008-6-20 22:36
老大，那个罗列的地方我看不懂，能不能给讲一下！不明白那个替换语句的用法！
str=%%str:%%i=%%i%%这一段我理解不了，有高人给指点一下不！！
我的QQ 362998909
作者: moniuming 时间: 2008-6-20 23:08
| Quote: | |
|
"变量延迟"
这样应该可以看得懂了吧:
call set str=%%str:%%i=%%i%%