标题: 请问如果在文本中抽取指定字符赋值于变量中 [打印本页]
作者: mp3down 时间: 2006-12-12 06:06 标题: 请问如果在文本中抽取指定字符赋值于变量中
我想,在一个文本文件中,抽取第17行第8-20这一串字符,并将它们赋值于一个变量给接下来的命令用，怎么办？
请各位大侠不要怪我整天问这些太菜的问题，我也觉得有点不好意思。想到不耻下问，这坛子的确令我学到东西，所以就壮胆了。
[ Last edited by namejm on 2006-12-13 at 01:54 PM ]
作者: a9319751 时间: 2006-12-12 06:12
setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.txt ) do (
set /a num+=1
if !num! equ 17 set var=%%i
if !num! equ 17 set var=!var:~7,13!
)
echo !var!
pause
for /f "delims=" %%i in (1.txt ) do (
set /a num+=1
if !num! equ 17 set var=%%i
if !num! equ 17 set var=!var:~7,13!
)
echo !var!
pause
作者: youxi01 时间: 2006-12-12 06:19
@echo off
for /f "skip=16 delims=" %%i in (test.txt) do (
set "str=%%i"
call set "str=%%str:~7,12%%"
goto :exit)
:exit
echo %str%
pause>nul
或者：for /f "skip=16 delims=" %%i in (test.txt) do (
set "str=%%i"
call set "str=%%str:~7,12%%"
goto :exit)
:exit
echo %str%
pause>nul
@echo off
for /f "delims=: tokens=1,2*" %%i in ('findstr /n . test.txt') do (
if %%i EQU 17 (
set "str=%%j"
call set "str=%%str:~7,12%%"
goto :exit))
:exit
echo %str%
pause>nul
[ Last edited by youxi01 on 2006-12-12 at 06:22 AM ]for /f "delims=: tokens=1,2*" %%i in ('findstr /n . test.txt') do (
if %%i EQU 17 (
set "str=%%j"
call set "str=%%str:~7,12%%"
goto :exit))
:exit
echo %str%
pause>nul
作者: NaturalJ0 时间: 2006-12-12 06:21
setlocal enabledelayedexpansion
for /f "skip=16 delims=" %%i in (filename.txt) do (
set var=%%i
set var=!var:~7,13!
goto :outfor)
:outfor
红色部分你可以自己随便替换。
作者: NaturalJ0 时间: 2006-12-12 06:22
哇，我手脚太慢了。 = =b
作者: ccwan 时间: 2006-12-12 06:24
我的手够快吧？
鼓励一下热心的朋友们！
作者: ccwan 时间: 2006-12-12 06:53
还有，楼主注意你的标题！
作者: mp3down 时间: 2006-12-12 07:08
谢谢热心的朋友们，我以后会注意标题了。
作者: namejm 时间: 2006-12-12 09:07
Re all:
用批处理来提取文本内容，要随时注意兼容特殊字符，比如空格，比如连接字符&、||等，因此，youxi01 兄在3F的代码动用了 delims= 和 set "str=%%i" ，这是非常有必要的。
不过，批处理还是不能处理所有的特殊情况，比如：如果有以半角分号开头的行，一般的 for 语句会忽略这些行，用 set /a num+=1 来统计行数会出错，换成 for + findstr /n 就可以避免；但是，for + findstr /n 也不能包打天下，至少，如果某些行以半角冒号打头，则 for /f "tokens=1* delims=:" %%i in ('findstr /n .* test.txt') do echo "%%j" 会把所有行首冒号忽略掉。所以，在处理文本的时候，只能指望这些特殊的情形不一起出现了。不知各位有没有什么好办法来解决。
作者: 3742668 时间: 2006-12-12 10:25
@echo off
setlocal enabledelayedexpansion
set num=
for /f "delims=" %%i in ('findstr .* a.txt') do (
set /a num += 1
set "!num!=%%i"
)
for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
暂时的变更方案，试试有无bug。setlocal enabledelayedexpansion
set num=
for /f "delims=" %%i in ('findstr .* a.txt') do (
set /a num += 1
set "!num!=%%i"
)
for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
作者: namejm 时间: 2006-12-12 11:04
3742668 兄10F的代码仍然不能正确处理行首为分号的情况，也不能正确处理行内带感叹号的情况。
代码1能正确处理行首为分号或冒号，行上带&、||等特殊字符的文本，但是不能正确提取带感叹号的内容，代码2能解决感叹号的问题，但是需要用引号括起来，基本上解决了我在9F提出的问题，请各位测试：
代码1：
@echo off
set num=0
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
echo 第 !num! 行： !str:*:=!
)
pause
代码2：set num=0
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
echo 第 !num! 行： !str:*:=!
)
pause
@echo off
set num=0
::setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
call :display
)
pause
goto :eof
:display
echo 第 %num% 行： "%str:*:=%"
goto :eof
test.txt的内容：set num=0
::setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
call :display
)
pause
goto :eof
:display
echo 第 %num% 行： "%str:*:=%"
goto :eof
:abc
::xy
;
;;;ef &
;:;
::;;
||
&
^
!<
!
%
"
""
'
[ Last edited by namejm on 2006-12-11 at 10:13 PM ]::xy
;
;;;ef &
;:;
::;;
||
&
^
!<
!
%
"
""
'
作者: 3742668 时间: 2006-12-12 11:41
try try this:
@echo off
setlocal enabledelayedexpansion
set num=
for /f "eol= delims=" %%i in ('findstr .* a.txt') do (
setlocal DISABLEDELAYEDEXPANSION
set "tmpstr=%%i"
setlocal enabledelayedexpansion
set /a num += 1
set "!num!=!tmpstr!"
)
for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
exit /b 0
setlocal enabledelayedexpansion
set num=
for /f "eol= delims=" %%i in ('findstr .* a.txt') do (
setlocal DISABLEDELAYEDEXPANSION
set "tmpstr=%%i"
setlocal enabledelayedexpansion
set /a num += 1
set "!num!=!tmpstr!"
)
for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
exit /b 0
作者: namejm 时间: 2006-12-12 12:18
eol= 用得巧，setlocal 用得妙，高，实在是高，嘿嘿。
作者: lxmxn 时间: 2006-12-12 13:47
真是强啊。学习了。。
作者: lxmxn 时间: 2006-12-12 13:50
还有一个问题，就是如果a.txt里面有空行(直接回车)的话，那么就会出错，批处理提示：
| Quote: | |
|
不知道这个问题怎么解决？
作者: amao 时间: 2006-12-12 19:20
等你们各位高手解决好了，我再慢慢学习，CMD的批处理我太菜了，刚开始学习。
作者: namejm 时间: 2006-12-12 22:00
| Quote: | |
|
实际上，并非是由空行引起的，而是行数超出了 setlocal 的限制。根据测试，setlocal 嵌套使用时，单个 setlocal 语句最多只能处理15行内容，超过15行就会超过最大的递归层，解决办法就是在适当的位置加上终止环境变量本地化的语句 endlocal 。
受 3742668 兄12F代码的启发，在11F代码的基础上，得到如下代码。下面的代码能完全兼容感叹号、连接符号、重定向符号、行首分号、行首冒号，解决了 setlocal 递归层的问题，并且能计算空行(以前的代码都会忽略空行)：
@echo off
set num=0
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
setlocal enabledelayedexpansion
echo 第 !num! 行： !str:*:=!
endlocal
)
pause
[ Last edited by namejm on 2006-12-12 at 09:50 AM ]set num=0
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
setlocal enabledelayedexpansion
echo 第 !num! 行： !str:*:=!
endlocal
)
pause
作者: ccwan 时间: 2006-12-12 22:37
namejm兄，我试过之后发现前30行没问题，31行开始报错：
第！num！行：！str:*:=！
已经达到最大的setlacal递归层。
作者: namejm 时间: 2006-12-12 22:47
取消多余的 setlocal 语句之后，不再出现最大递归层的问题，17F代码已经修正，请再次测试。
作者: ccwan 时间: 2006-12-12 22:53
呵呵！果然漂亮！
从namejm兄这里获益良多啊！
等偶冷却期过了给兄加分！^_^
作者: andred0421 时间: 2006-12-13 12:50
强啊，学习中，
呵呵
每次来都有收获
作者: qzwqzw 时间: 2006-12-13 22:45
还不能处理unicode文本，在findstr前加个more可以解决
为了能重定向到文件，稍微作了些修改
还是有问题：原文件是unicode的，目标仍然是ansi，fc必然通不过。
@echo off
(for /f "delims=" %%i in ('more ^< "%~f1" ^| findstr /n .*') do (
set "str=%%i"
setlocal enabledelayedexpansion
echo;!str:*:=!
endlocal
))>test.out
fc "%~f1" test.out
pause
[ Last edited by qzwqzw on 2006-12-13 at 10:28 AM ](for /f "delims=" %%i in ('more ^< "%~f1" ^| findstr /n .*') do (
set "str=%%i"
setlocal enabledelayedexpansion
echo;!str:*:=!
endlocal
))>test.out
fc "%~f1" test.out
pause
作者: lxmxn 时间: 2006-12-14 00:32
不知道楼上的测试了你的代码了么？好像有问题。
作者: qzwqzw 时间: 2006-12-14 01:00
测试代码而已，有问题很正常
不过，以后报问题请报出问题是什么，在什么情况下出现
我发出代码之前自然是没碰到什么未料到的问题
将上面的代码略作改变，方便自己，也方便别人测试
顺便解决了fc与unicode的问题
@echo off
if "%1"=="" %0 "%~f0"
(for /f "delims=" %%i in ('more ^< %1 ^| findstr /n .*') do (
set "str=%%i"
setlocal enabledelayedexpansion
echo;!str:*:=!
endlocal
))>test.tmp
type test.tmp
echo ---------
more < %1 > %1.tmp
fc %1.tmp test.tmp
pause
[ Last edited by qzwqzw on 2006-12-13 at 12:06 PM ]if "%1"=="" %0 "%~f0"
(for /f "delims=" %%i in ('more ^< %1 ^| findstr /n .*') do (
set "str=%%i"
setlocal enabledelayedexpansion
echo;!str:*:=!
endlocal
))>test.tmp
type test.tmp
echo ---------
more < %1 > %1.tmp
fc %1.tmp test.tmp
pause
作者: lxmxn 时间: 2006-12-14 02:43
无论是直接双击运行，还是拖放文件运行，在命令行运行，都报错了，提示此时不应有 and 。
作者: qzwqzw 时间: 2006-12-14 03:31
这显然与测试文本有关，请贴上来看看。
作者: lxmxn 时间: 2006-12-14 06:37
测试了N久，发现问题了。
开始的时候，直接双击会出现“此时不应有and”的错误提示，仔细分析了一下兄的代码，发现兄的代码开始处有一段“if "%1"=="" %0 "%~f0"”，真是这个%~f0的扩展功能是第一参数成了完整路径，而我的批处理都是在C:\Documents and Settings\Administrator\桌面\文件\Temp中测试的，所以导致第一参数为"C:\Documents"，而不是"C:\Documents and Settings\Administrator\桌面\文件\Temp\test.bat"，最终导致提示错误的信息出现了。而且直接拖放文件也会出现类似的提示错误。
所以在带有空格的路径下测试以上代码，就容易报错，建议在代码前面加上处理带有空格路径的语句，我讲%~f0改为了%~s0，问题就解决了。
还有一个小问题，就是不能很好的支持文件的拖放，不知道是我的问题还是代码的问题。
作者: hxuan999 时间: 2006-12-14 07:26
拖放时的错误是一样的.还有在双击时也有,只有在命令行是用参数指定相对路径是正确,都是因为路径中有空格的问题.
另外还有一个问题,双击时调用本身,返回后没有退出.
修改24楼后代码:
| Quote: | |
|
拖放,双击,命令行都没有问题.
[ Last edited by hxuan999 on 2006-12-13 at 07:27 PM ]
作者: hxuan999 时间: 2006-12-14 07:29
另外17楼代码最好加一句:setlocal disabledelayedexpansion.如下:
@echo off
setlocal disabledelayedexpansion
set num=0
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
setlocal enabledelayedexpansion
echo 第 !num! 行： !str:*:=!
endlocal
)
pause
这样可以防止在注册表中修改过DelayedExpansion键值的情况.(本人就是,^&^,所以一直都看不到感叹号,测试了半天才想起来.)setlocal disabledelayedexpansion
set num=0
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set /a num+=1
set "str=%%i"
setlocal enabledelayedexpansion
echo 第 !num! 行： !str:*:=!
endlocal
)
pause
[ Last edited by hxuan999 on 2006-12-13 at 07:33 PM ]
作者: qzwqzw 时间: 2006-12-14 07:41
谢谢楼上的兄弟！
goto :eof 是没有必要的，%0 "%~f0" 之后是不会返回的
usebackq 可以不用，而且最好不用，因为它所带来的隐患比较多
原代码中的问题属于路径参数处理问题，楼上的话收回
因为我从来都是在d:\test下作测试的，很少去注意这些问题，得到一个教训
作者: hxuan999 时间: 2006-12-14 22:56
再测了一下,，%0 "%~f0"后的确不会返回,请问这是为什么?
另外,为了让其它人看到这个问题,楼上的我就不作修改了,在这里认个错,呵呵.
作者: qzwqzw 时间: 2006-12-15 08:55
没有什么为什么 ~@$%
在批处理中直接调用批处理就是不会返回
DOS时代起就是这样的风格
除非用call ，start，%comspec% /c 等方法调用才会返回
所以本质上说，直接调用批处理相当于流程跳转 jump / goto
call 等调用相当于中断执行 int / call
作者: hxuan999 时间: 2006-12-16 03:10
o 明白了.谢谢,呵呵