标题: 如何判断变量的长度?? [打印本页]
作者: luxiaoming2001 时间: 2006-11-15 09:51 标题: 如何判断变量的长度??
set dd=1234
我如何判断dd这个变量的长度??请高手指教
作者: namejm 时间: 2006-11-15 10:09
以前 willsort 曾经写过这样的代码，发出来你琢磨一下：
@echo off & setlocal EnableDelayedExpansion
:begin
set mystr=
set /p mystr=输入要计算长度的字符串(直接回车退出):
if not defined mystr goto :eof
for /l %%i in (0,1,1000) do if "!mystr:~%%i,1!"=="" set strlen=%%i && goto :_endfor
:_endfor
::echo 字符串: "%mystr%"
echo 长 度: %strlen%
set strlen=
goto begin
在这个代码的基础上，可以修改为：:begin
set mystr=
set /p mystr=输入要计算长度的字符串(直接回车退出):
if not defined mystr goto :eof
for /l %%i in (0,1,1000) do if "!mystr:~%%i,1!"=="" set strlen=%%i && goto :_endfor
:_endfor
::echo 字符串: "%mystr%"
echo 长 度: %strlen%
set strlen=
goto begin
@echo off
:begin
cls
set mystr=
set /p mystr=输入要计算长度的字符串(直接回车退出):
if not defined mystr goto :eof
set count=0
setlocal enabledelayedexpansion
:intercept
set /a count+=1
for /f %%i in ("%count%") do if not "!mystr:~%%i,1!"=="" goto intercept
echo 长 度: %count%
pause
goto begin
:begin
cls
set mystr=
set /p mystr=输入要计算长度的字符串(直接回车退出):
if not defined mystr goto :eof
set count=0
setlocal enabledelayedexpansion
:intercept
set /a count+=1
for /f %%i in ("%count%") do if not "!mystr:~%%i,1!"=="" goto intercept
echo 长 度: %count%
pause
goto begin
作者: pengfei 时间: 2006-11-15 10:18
其实问题并不像vkill兄说的那样简单, 这不单牵涉到引号配对的问题, 还有诸如控制字符等特殊符号的处理.
经过反复修改下面的代码已经可以处理特殊字符了, 测试暂时没发现错误.
@echo off
set /p str=请输入字符串:
set "str=%str:"= %"
:next
if not "%str%"=="" (
set /a num+=1
set "str=%str:~1%"
goto next
)
echo 输入的字符数:%num%
pause
二楼的代码可以不用FOR语句来实现.set /p str=请输入字符串:
set "str=%str:"= %"
:next
if not "%str%"=="" (
set /a num+=1
set "str=%str:~1%"
goto next
)
echo 输入的字符数:%num%
pause
@echo off
set /p str=请输入字符串:
setlocal enabledelayedexpansion
if not defined str goto :eof
:next
if not "!str:~%num%,1!"=="" (
set /a num+=1
goto next
)
echo 输入的字符数:%num%
pause
[ Last edited by pengfei on 2006-11-20 at 11:10 AM ]set /p str=请输入字符串:
setlocal enabledelayedexpansion
if not defined str goto :eof
:next
if not "!str:~%num%,1!"=="" (
set /a num+=1
goto next
)
echo 输入的字符数:%num%
pause
作者: lxmxn 时间: 2006-11-15 10:48
一下就有三种方法了，收藏一下。
作者: luxiaoming2001 时间: 2006-11-15 22:49
谢谢了,我马上去研究下,DOS的这种命令真是深奥啊,感觉没有SHELL的命令简洁
作者: vkill 时间: 2006-11-16 03:50
我用的也是pengfei兄这样的方法
作者: namejm 时间: 2006-11-16 06:45
3F的代码也不失为一种好方法，只是因为 if not "%ii%"=="" 语句的限制，处理英文状态下的引号的时候会出错，如果字符串中可能存在英文状态下的引号的话，建议采用2F的代码。
作者: vkill 时间: 2006-11-16 07:03
| Quote: | |
|
可以换个别的了,像 if not %ii%*==* ,当然也可以换个很特殊的,三种方法其实都是一种思路,呵呵
[ Last edited by vkill on 2006-11-16 at 07:05 AM ]
作者: pengfei 时间: 2006-11-20 09:00
| Quote: | |
|
vkill兄这样处理遇到的问题会更多, 如果输入特殊字符就无法处理了.
其实这个错误是引号配对引起的, 我们可以先去掉引号再来判断, 代码更新在3楼.
作者: electronixtar 时间: 2006-11-20 09:23
@echo off
set /p a=
echo :%a%>tmp.bat
echo set /a r=%%~z0-21>>tmp.bat
call tmp.bat
echo %r%
pause > nul
del tmp.bat
本人不擅长写批处理，大家多多批评哈set /p a=
echo :%a%>tmp.bat
echo set /a r=%%~z0-21>>tmp.bat
call tmp.bat
echo %r%
pause > nul
del tmp.bat
作者: pengfei 时间: 2006-11-20 09:54
electronixtar兄真不错啊, 想到利用文件大小来判断, 但这样依然存在特殊字符处理的问题. 如果输入管道命令就会出错.
作者: redtek 时间: 2006-11-20 10:21
精彩～～
electronixtar兄的这个~z玩得可是真好玩～：）
欣赏！这方法虽 “另类” 但绝对让人眼前一亮～：）
而且写放tmp.bat文件后 “set /a r=%~z0-21” 本身占16个字符，
还有一个首行的 “:” 标签（这样用户输入的内容会被当做标签，哈哈），这个占1个字符，
还有echo写入时的多余的一行回车换行符2个，
和首行写入（所占的回车换行符）2 个，
一共是 21 ，
所以 %~z0（文件自身的长度）还要减去21就是刚被用户所输入的长度～：）
真是精心计算啊～：）
[ Last edited by redtek on 2006-11-19 at 09:27 PM ]
作者: wchy2006 时间: 2006-11-20 10:41 标题: 请教electronixtar：set /a r=%%~z0-21 是什么意思？
我刚开始学习批处理，对您帖子中的 set /a r=%%~z0-21 这行代码不明白，请指教，多谢拉！
作者: electronixtar 时间: 2006-11-20 10:45
其实偶没有考虑那么多。现随便减了个15，发现相差6，于是就减了个21，完毕。并没有精心计算。
作者: pengfei 时间: 2006-11-20 10:50
利用文件大小判断字符数, 代码改进一下, 可处理特殊字符. 同时, 3楼的代码都已经通用, 目前测试暂时没有发现错误.
@echo off
set /p str=请输入字符串:
set "str=%str:"= %"
>str.txt set /p "auto=%str%"<nul
call :go str.txt
echo 输入的字符数:%size%
del str.txt
pause >nul
exit
:go
set size=%~z1
goto :eof
[ Last edited by pengfei on 2006-11-20 at 11:07 AM ]set /p str=请输入字符串:
set "str=%str:"= %"
>str.txt set /p "auto=%str%"<nul
call :go str.txt
echo 输入的字符数:%size%
del str.txt
pause >nul
exit
:go
set size=%~z1
goto :eof
作者: redtek 时间: 2006-11-20 11:18
哈哈……越来越有意思了～：）
作者: 3742668 时间: 2006-11-20 12:56
Re est:
不错的方案，以前我也尝试过这种方案。不过由于汉字一个字符占用两个字节的原因，尽管当时利用chcp 437和chcp 936的切换来分辨汉字与非汉字基本可以解决这个问题，最终还是将此方案搁浅。
作者: redtek 时间: 2006-11-20 22:38
对于１０楼和１５楼两位哥哥这么好玩的超级代码，一定要用好玩的方法测试～：）
C:\TEMP>echo 中华人民共和国|LEN.BAT
请输入字符串:输入的字符数:14
C:\TEMP>ECHO.|TIME
当前时间: 9:30:58.82
输入新时间:
C:\TEMP>ECHO.|TIME|LEN.BAT
请输入字符串:输入的字符数:21
C:\TEMP>
C:\TEMP>TYPE A.TXT
BBS.CN-DOS.NET
C:\TEMP>TYPE A.TXT|LEN.BAT
请输入字符串:输入的字符数:14
中、英文字符都正确～：）请输入字符串:输入的字符数:14
C:\TEMP>ECHO.|TIME
当前时间: 9:30:58.82
输入新时间:
C:\TEMP>ECHO.|TIME|LEN.BAT
请输入字符串:输入的字符数:21
C:\TEMP>
C:\TEMP>TYPE A.TXT
BBS.CN-DOS.NET
C:\TEMP>TYPE A.TXT|LEN.BAT
请输入字符串:输入的字符数:14
作者: scriptor 时间: 2007-1-12 12:41
困扰我的问题有可以解决了
呵呵
谢谢了
作者: mqw624 时间: 2010-12-6 13:57
受益匪浅！！
作者: DXSX 时间: 2010-12-8 10:15
记得用华罗庚 二分法 判断是最快的算法。
因为如果知道系统变量最大长度限制，就可以循环判断了。