标题: 用批处理模拟搞笑开机画面 [打印本页]
作者: bagpipe 时间: 2006-5-15 17:27 标题: 用批处理模拟搞笑开机画面
这个是我从网上看到很多人用这个作为自己的签名图片，我想大家也许也看到过，我想想，编写成批处理也不是不可能，不过最后一步没有实现，有兴趣的还请大家一起来研究，下面是代码和文件........
@echo off
cls
echo Microsoft Windows 2000 [Version 5.00.2195]
echo (C) 版权所有 1985-2000 Microsoft Corp.
echo;
set/p=%cd%^><nul&ping -n 2 127.1>nul&set/p="开"<nul&ping -n 2 127.1>nul&set/p="机"<nul&ping -n 2 127.1>nul&echo;
echo '开机' 不是内部或外部命令，也不是可运行的程序
echo 或批处理文件。
echo.
set/p=%cd%^><nul&ping -n 2 127.1>nul&set/p="快"<nul&ping -n 2 127.1>nul&set/p="开"<nul&ping -n 2 127.1>nul&set/p="机"<nul&ping -n 2 127.1>nul&echo;
echo '快开机' 不是内部或外部命令，也不是可运行的程序
echo 或批处理文件
echo:
set/p=%cd%^><nul&ping -n 2 127.1>nul&set/p="他"<nul&ping -n 2 127.1>nul&set/p="妈"<nul&ping -n 2 127.1>nul&set/p="的"<nul&ping -n 2 127.1>nul&set/p="开"<nul&ping -n 2 127.1>nul&set/p="机"<nul&ping -n 2 127.1>nul&echo;
echo '他妈的开机' 不是内部或外部命令，也不是可运行的程序
echo 或批处理文件
echo;
set/p=%cd%^><nul&ping -n 2 127.1>nul&set/p="你"<nul&ping -n 2 127.1>nul&set/p="他"<nul&ping -n 2 127.1>nul&set/p="妈"<nul&ping -n 2 127.1>nul&set/p="的"<nul&ping -n 2 127.1>nul&set/p="快"<nul&ping -n 2 127.1>nul&set/p="开"<nul&ping -n 2 127.1>nul&set/p="机"<nul&ping -n 2 127.1>nul&echo.
echo '你他妈的快开机' 不是内部或外部命令，也不是可运行的程序
echo 或批处理文件
echo;
set/p=%cd%^><nul&ping -n 2 127.1>nul&set/p="操"<nul&ping -n 2 127.1>nul&set/p="!"<nul&ping -n 1 127.1>nul&set/p="!"<nul&ping -n 2 127.1>nul&set/p="不"<nul&ping -n 2 127.1>nul&set/p="开"<nul&ping -n 2 127.1>nul&set/p="机"<nul&ping -n 2 127.1>nul&set/p="我"<nul&ping -n 2 127.1>nul&set/p="就"<nul&ping -n 2 127.1>nul&set/p="砸"<nul&ping -n 2 127.1>nul&set/p="了"<nul&ping -n 2 127.1>nul&set/p="你"<nul&ping -n 2 127.1>nul&set/p="!"<nul&ping -n 4 127.1>nul&echo.
echo.
echo.
echo Loading Windows 2000...
echo ================================================================================
不过觉得自己写的有些过于烦琐，望高手提供最佳方法来实现........
[ Last edited by namejm on 2007-2-3 at 06:35 PM ]
附件 1:hellokiki.rar (2006-5-15 17:27, 465 bytes, 下载附件所需积分 1点 ,下载次数： 272)
作者: 3742668 时间: 2006-5-15 19:18
最后的进度条可以尝试用cls+type+echo来解决。
先把屏幕上的输出保存到文件中，然后用一个循环来type那个文件的内容，并echo出进度条出来，在循环的开始部分用cls来清屏。
或者在最后一步调用一个vbs脚本，利用Wscript.StdOut的Write方法完成一个进度条是很容易的。
建议参考一下 无奈何 兄的签名。
作者: doscc 时间: 2006-5-16 08:46
看过那样的签名!.
是可以用 批处理来做一个.
作者: bagpipe 时间: 2006-5-16 08:48
3742668兄，你好，对于使用无奈何兄的签名代码的方法我也实验过了，在开始我本来就想用无奈何兄的签名代码的方式来编写，不过无奈何兄的代码在写入％cd％时候效果不是很好也没有找到合适的方法解决所以就只能这样写了，对于进度还3742668
兄指点一二!
作者: bagpipe 时间: 2006-5-16 09:31
doscc既然你说的这么轻松，写出来一个共享一下
作者: doscc 时间: 2006-5-16 10:47
我子细看了 破烂兄的代码.
前面部份兄以经写出来了.
但是我并没有说 得很轻松.请不要误会了.
下面是我写的 最后的进度 可能不是很好.不过兄可以参考一下. 用无奈何兄的代码可能更好吧.
@echo off
set a==
set n=1
:t
cls
echo Loading Windows 2000...
echo %a%
set a=%a%=
set /a n+=1
if %n%==80 goto end
ping 2 172.1>nul
goto t
:end
set a==
set n=1
:t
cls
echo Loading Windows 2000...
echo %a%
set a=%a%=
set /a n+=1
if %n%==80 goto end
ping 2 172.1>nul
goto t
:end
作者: bagpipe 时间: 2006-5-16 10:52
"破烂兄",呵呵，有意思，不过你的代码我测试了一下，我希望的是用">"来逐个代替“="来进行进程的显示，兄的代码好像就是”＝“逐步往前推进吧!!!!!!!!
作者: doscc 时间: 2006-5-16 11:00
呵呵.是 没错 逐步往前推进
用>可能不是很好.>在批处理是有特殊意议的.不过可以用 》来代替 试试
作者: bagpipe 时间: 2006-5-16 11:06
NO, NO ,NO,兄好像还没有明白我的意思，我的意思就是用“>"逐步代替"="，就是说“=“符号已经充满整个DOS行，然后用>符号逐步去替代，不是是">"逐步往前走，是代替
作者: doscc 时间: 2006-5-16 11:47
不好意思啊。是我理解错误.
下面是我改过的代码 不过在变量堪套 %b:~%n%% 时出错（我也不知道为什么出错）。如果没有出错就可以实现最后的进度了。
@echo off
set b=================================================================================
set b1=-
set n=1
:t1
cls
set b1=%b1%-
echo Loading Windows 2000...
echo %b1%%b:~%n%%
set /a n+=1
if %n%==80 goto end
ping 2 172.1 >nul
goto t1
:end
set b=================================================================================
set b1=-
set n=1
:t1
cls
set b1=%b1%-
echo Loading Windows 2000...
echo %b1%%b:~%n%%
set /a n+=1
if %n%==80 goto end
ping 2 172.1 >nul
goto t1
:end
作者: 3742668 时间: 2006-5-16 13:31
@echo off
set b==
set /a flag = 1
call :began 80 rem 保存80个等号到变量b中
call :main %flag%
exit
:began rem 初始化b
set b=%b%=
set /a flag = %flag% + 1
if %flag% geq %1 goto :eof
goto began
:main rem 显示
set b=%b:~1%
set a=%a%0
set /a newflag = newflag + 1
cls
for /l %%i in (1,1,20) do @echo.
echo Loading Windows 2000...
echo %a:0=^>%%b%
call :delay 100 rem 数字可以调整显示速度
if %newflag% equ %1 goto :eof
goto main
:delay rem 延时
set /a num=num + 1
if %num% geq %1 (set num=) && goto :eof
goto delay
由于使用的结构是call和goto，所以代码很是臃肿，不过这种代码利于阅读，所以就用的这种机构。set b==
set /a flag = 1
call :began 80 rem 保存80个等号到变量b中
call :main %flag%
exit
:began rem 初始化b
set b=%b%=
set /a flag = %flag% + 1
if %flag% geq %1 goto :eof
goto began
:main rem 显示
set b=%b:~1%
set a=%a%0
set /a newflag = newflag + 1
cls
for /l %%i in (1,1,20) do @echo.
echo Loading Windows 2000...
echo %a:0=^>%%b%
call :delay 100 rem 数字可以调整显示速度
if %newflag% equ %1 goto :eof
goto main
:delay rem 延时
set /a num=num + 1
if %num% geq %1 (set num=) && goto :eof
goto delay
这个脚本其实主要要解决的问题应该是显示字符">"的问题，因为CMD默认是把它当作重定向来使用的，所以直接echo >是会出错的，正确的方法应该是在前面用符号"^"来转义。在批处理中连续赋">"到变量中并在最后用echo显示出来要用到的^符号是惊人的，所以干脆就用了set命令的替换功能，先赋值0到变量a中，然后在显示的时候把0全部替换成^>，并把变量b依次减少一位，这样就实现了模拟进度的显示。
另外值得注意的一点就是在这个模拟显示中延时的问题，如果用ping来实现的话，由于ping在系统内部返回是需要消耗时间 的，所以就算用ping -n 1 -w 1 0.0.0.2 来处理都不能实现要求，在这个脚本中用的是goto延时，考虑到不同机器的时钟频率不尽相同，所以设置了延时过程(暂且叫它过程吧)的参数，如果觉得效果不好的话可以自行修改。(当然，利用wmic的强大功能也可以根据不同CPU的频率来自动调节参数，不过这就不是这个话题的讨论范围了)
作者: 3742668 时间: 2006-5-16 14:37
另外关于依次显示字符的问题:
@echo off
call :显示文字 "操，再不开机老子砸了你" 80
goto :eof
:显示文字
setlocal ENABLEDELAYEDEXPANSION
set 显示字符=%1
set 显示速度=%2
if "%2" == "" set 显示速度=100
set 显示速度
for /l %%i in (0,1,1000) do (
if %%i == 0 (
set /p cxs=%cd%^><nul
) else (
echo !显示字符:~%%i,1! | findstr /i "ECHO" >nul 2>nul && goto quit || (
set /p cxs=!显示字符:~%%i,1!<nul
for /l %%j in (1,1,%显示速度%) do @call %%j 2>nul)
)
)
:quit
echo.
endlocal
为了便于阅读，把代码格式改改...call :显示文字 "操，再不开机老子砸了你" 80
goto :eof
:显示文字
setlocal ENABLEDELAYEDEXPANSION
set 显示字符=%1
set 显示速度=%2
if "%2" == "" set 显示速度=100
set 显示速度
for /l %%i in (0,1,1000) do (
if %%i == 0 (
set /p cxs=%cd%^><nul
) else (
echo !显示字符:~%%i,1! | findstr /i "ECHO" >nul 2>nul && goto quit || (
set /p cxs=!显示字符:~%%i,1!<nul
for /l %%j in (1,1,%显示速度%) do @call %%j 2>nul)
)
)
:quit
echo.
endlocal
[ Last edited by 3742668 on 2006-5-16 at 15:02 ]
作者: bagpipe 时间: 2006-5-16 16:09
谢谢3742668兄的代码，认真学习中...............无限佩服中 .......................呵呵
：》
作者: doscc 时间: 2006-5-16 16:27
谢谢 3742668版主.
下面是我改过后的代码 虽然不是很好不过改一改还是好一点.
我真傻啊 前面用 set b1=%b1%- 来逐步增加 记然想不到用set b=%b:~1%来减少
@echo off
set b================================================================================
set b1=-
set n=1
:t1
cls
set b1=%b1%-
set b=%b:~1%
echo Loading Windows 2000...
echo %b1%%b%
set /a n+=1
if %n%==80 goto end
ping 2 172.1 >nul
goto t1
:end
还有版主 下面代码为什么 只显示 b%%而不是123? 变量不可以堪套吗?set b================================================================================
set b1=-
set n=1
:t1
cls
set b1=%b1%-
set b=%b:~1%
echo Loading Windows 2000...
echo %b1%%b%
set /a n+=1
if %n%==80 goto end
ping 2 172.1 >nul
goto t1
:end
set a=123456789
set b=3
echo %a:~0,%b%%
set b=3
echo %a:~0,%b%%
作者: doscc 时间: 2006-5-16 16:30
是不是变量只能是 以!为扩搌符时 才可以堪套
像这个 !显示字符:~%%i,1!
作者: 3742668 时间: 2006-5-16 19:53
| Quote: | |
|
这就是为什么要用setlocal ENABLEDELAYEDEXPANSION来启用延时的环境变量的原因。当然，并不是说不启用延时的环境变量就不能实现变量的嵌套，比如用显示命令的叠加来转换:
echo %a:~0,^%b%^% | findstr .
作者: doscc 时间: 2006-5-16 20:45
谢谢了
作者: bagpipe 时间: 2006-5-17 11:23
延时是采用3742668兄的代码，不过效果我觉得不怎么好
@echo off
setlocal enabledelayedexpansion
set /a b=81
set a=">>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>================================================================================"
:back
cls
for /l %%i in (1,1,20) do @echo.
echo Loading Windows 2000...
set /a b-=1
echo !a:~%b%,80!
if !b! == 1 goto :eof
call :delay 80
goto back
:delay
set /a num=num + 1
if %num% geq %1 (set num=) && goto :eof
goto delay
作者: maya0su 时间: 2006-7-24 16:25
另
1.jpg为有@echo off 的结果！
2.jpg为没有@echo off的结果！
本来的系统的winxp sp1 ！:o
附件 1:1.JPG (2006-7-24 16:25, 95.48 K, 下载附件所需积分 1点 ,下载次数： 4)
附件 2:
作者: maya0su 时间: 2006-7-26 02:59
现在在SP2的环境下测试，情况依旧！
作者: voiL 时间: 2006-7-27 05:22
XP SP2运行正常.
附件 1:
作者: my3439955 时间: 2006-10-2 03:49
基于以上诸位的探讨
我来给个总结性的发言
批处理如下
@echo off
setlocal EnableDelayedExpansion
set _tmp_F_S=C:\_delay.vbs
set _tmp_F_F=C:\_tmp.tmp
set delay=50
set s1=开机
set s2=快开机
set s3=他妈的开机
set s4=你他妈到底开不开机
set s5=操！！再不开机老子砸了你！！
echo if WScript.Arguments.count = 1 then WScript.Sleep CInt(WScript.Arguments(0)) end if>%_tmp_F_S%
if exist %_tmp_F_F% del %_tmp_F_F%
for /L %%i in (1,1,4) do (call :show %%s%%i%% && call :fail %%s%%i%%)
call :show %s5%
call :suc
if exist %_tmp_F_S% del %_tmp_F_S%
if exist %_tmp_F_F% del %_tmp_F_F%
ping -n 1 127.1>nul
goto :EOF
:show
if "%~1"=="" goto :EOF
set s=%1
set /p ans=%cd%^><nul
set /A len=0
:comp_len
echo %%s:~%len%,1%% | find "ECHO">nul && goto end_comp
set /A "len+=1"
goto comp_len
:end_comp
set /A "len-=1"
for /L %%i in (0,1,%len%) do (cscript //nologo %_tmp_F_S% %delay% && set /p ans=!s:~%%i,1!<nul)
cscript //nologo %_tmp_F_S% 500
echo.
echo %cd%^>%1>>%_tmp_F_F%
echo.>>%_tmp_F_F%
goto :EOF
:fail
echo '%1' 不是内部或外部命令，也不是可运行的程序
echo 或批处理文件。
echo.
echo '%1' 不是内部或外部命令，也不是可运行的程序>>%_tmp_F_F%
echo 或批处理文件。>>%_tmp_F_F%
echo.>>%_tmp_F_F%
goto :EOF
:suc
ping -n 1 127.1>nul
set eqq================================================================================
set gtr=^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>
echo Loading Windows 2000 ...>>%_tmp_F_F%
echo.>>%_tmp_F_F%
for /L %%i in (0,1,79) do (set /A new=2*%%i && type %_tmp_F_F% && echo !gtr:~0,%%i!!eqq:~%%i,80! && ping -n 1 127.1>nul && cls)
goto :EOF
setlocal EnableDelayedExpansion
set _tmp_F_S=C:\_delay.vbs
set _tmp_F_F=C:\_tmp.tmp
set delay=50
set s1=开机
set s2=快开机
set s3=他妈的开机
set s4=你他妈到底开不开机
set s5=操！！再不开机老子砸了你！！
echo if WScript.Arguments.count = 1 then WScript.Sleep CInt(WScript.Arguments(0)) end if>%_tmp_F_S%
if exist %_tmp_F_F% del %_tmp_F_F%
for /L %%i in (1,1,4) do (call :show %%s%%i%% && call :fail %%s%%i%%)
call :show %s5%
call :suc
if exist %_tmp_F_S% del %_tmp_F_S%
if exist %_tmp_F_F% del %_tmp_F_F%
ping -n 1 127.1>nul
goto :EOF
:show
if "%~1"=="" goto :EOF
set s=%1
set /p ans=%cd%^><nul
set /A len=0
:comp_len
echo %%s:~%len%,1%% | find "ECHO">nul && goto end_comp
set /A "len+=1"
goto comp_len
:end_comp
set /A "len-=1"
for /L %%i in (0,1,%len%) do (cscript //nologo %_tmp_F_S% %delay% && set /p ans=!s:~%%i,1!<nul)
cscript //nologo %_tmp_F_S% 500
echo.
echo %cd%^>%1>>%_tmp_F_F%
echo.>>%_tmp_F_F%
goto :EOF
:fail
echo '%1' 不是内部或外部命令，也不是可运行的程序
echo 或批处理文件。
echo.
echo '%1' 不是内部或外部命令，也不是可运行的程序>>%_tmp_F_F%
echo 或批处理文件。>>%_tmp_F_F%
echo.>>%_tmp_F_F%
goto :EOF
:suc
ping -n 1 127.1>nul
set eqq================================================================================
set gtr=^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>^>
echo Loading Windows 2000 ...>>%_tmp_F_F%
echo.>>%_tmp_F_F%
for /L %%i in (0,1,79) do (set /A new=2*%%i && type %_tmp_F_F% && echo !gtr:~0,%%i!!eqq:~%%i,80! && ping -n 1 127.1>nul && cls)
goto :EOF
作者: gzdx0615 时间: 2006-10-3 09:08
| Quote: | |
|
行是行/但是到了最后会一直重复前面的内容
作者: my3439955 时间: 2006-10-5 22:28
不明白楼上的意思
是不是说最后屏幕的闪烁?
作者: bg 时间: 2006-10-8 23:43 标题: 我写的，个人感觉还好。
@echo off
color 1f
title.
mode con lines=10
rem 进度条 ▉▉▉▉▉
set work=0
set n=0
set mo=0
set number=0
rem all是总数
set all=60
set time=%all%
:show
:check
if %number% GTR %mo% set num=%num%▉&set /a mo=%mo%+1&goto check
:2
cls
echo 进度： %n% / %all% 剩余时间:%time%秒
echo.
echo.
echo 完成 %work% %%%
echo.
if not "%num%"=="" echo %num%
if not "%num%"=="" echo %num%
if %work%==100 goto end
ping 127.1 -n 3 >nul
set /a n=%n%+1
set /a time=%all%-%n%
set /a work=(%n%)*100/(%all%)
set /a number=%work%/3
set /a number=%number%+1
goto show
endlocal
:end
endlocal
pause>nul
作者: weilong888 时间: 2006-10-9 01:01
很有意思的，试了一下，真的可行。
作者: h2o 时间: 2006-10-9 10:42
太精彩了！！！
作者: vkill 时间: 2006-10-9 21:51
| Quote: | |
|
很好哈~正想要这个的
作者: electronixtar 时间: 2006-11-4 11:46
http://forum.dirshell.com/read.php?tid=1309&keyword=
有内奸。拖出去毙了
作者: vkill 时间: 2006-11-5 05:39
就是,晕,抄也不写出处,bs
作者: maobin 时间: 2006-11-17 19:42
@echo off
cls
echo Microsoft Windows 2000 [Version 5.00.2195]
echo (C) 版权所有 1985-2000 Microsoft Corp.
echo.
set/p=%cd%^><nul&ping -n 1 172.1>nul&set/p=开<nul&ping -n 1 172.1>nul&set/p=机<nul&ping -n 1 172.1>nul
echo.
echo."开机"不是内部或外部命令,也不是可运行的程序
echo. 或批处理文件.
echo.
set/p=%cd%^><nul&ping -n 1 172.1>nul&set/p=快<nul&ping -n 1 172.1>nul&set/p=开<nul&ping -n 1 172.1>nul&set/p=机<nul&ping -n 1 172.1>nul
echo.
echo."快开机"不是内部或外部命令,也不是可运行的程序
echo. 或批处理文件.
echo.
set/p=%cd%^><nul&ping -n 1 172.1>nul&set/p=你<nul&ping -n 1 172.1>nul&set/p=他<nul&ping -n 1 172.1>nul&set/p=妈<nul&ping -n 1 172.1>nul&set/p=的<nul&ping -n 1 172.1>nul&set/p=开<nul&ping -n 1 172.1>nul&set/p=机<nul&ping -n 1 172.1>nul
echo.
echo."你他妈的开机"不是内部或外部命令,也不是可运行的程序
echo. 或批处理文件.
echo.
set/p=%cd%^><nul&ping -n 1 172.1>nul&set/p=你<nul&ping -n 1 172.1>nul&set/p=他<nul&ping -n 1 172.1>nul&set/p=妈<nul&ping -n 1 172.1>nul&set/p=的<nul&ping -n 1 172.1>nul&set/p=快<nul&ping -n 1 172.1>nul&set/p=开<nul&ping -n 1 172.1>nul&set/p=机<nul&ping -n 1 172.1>nul
echo.
echo."你他妈的快开机"不是内部或外部命令,也不是可运行的程序
echo. 或批处理文件.
echo.
set/p=%cd%^><nul&ping -n 1 172.1>nul&set/p=操<nul&ping -n 1 172.1>nul&set/p= <nul&ping -n 1 172.1>nul&set/p=你<nul&ping -n 1 172.1>nul&set/p=他<nul&ping -n 1 172.1>nul&set/p=妈<nul&ping -n 1 172.1>nul&set/p=的<nul&ping -n 1 172.1>nul&set/p=在<nul&ping -n 1 172.1>nul&set/p=不<nul&ping -n 1 172.1>nul&set/p=开<nul&ping -n 1 172.1>nul&set/p=机<nul&ping -n 1 172.1>nul&set/p=老<nul&ping -n 1 172.1>nul&set/p=子<nul&ping -n 1 172.1>nul&set/p=砸<nul&ping -n 1 172.1>nul&set/p=了<nul&ping -n 1 172.1>nul&set/p=你<nul&ping -n 1 172.1>nul
echo.
@echo off
@set b================================================================================
set b1=}
set n=1
:t1
cls
set b1=%b1%}
set b=%b:~1%
echo Loading Windows 2000...
echo %b1%%b%
set /a n+=1
if %n%==80 goto end
ping 2 172.1 >nul
goto t1
:end
cls
color b4
@echo.
@echo ※※※※※※※ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
@echo ※ 我的文档 ※ ╔━╗ ┊风┊的┊伤┊软┊看┊远┊选┊
@echo ※※※※※※※ ┃封┃ ┊而┊我┊痕┊弱┊破┊离┊择┊
@echo. ┃爱┃ ┊散┊已┊纍┊也┊也┊爱┊逃┊
@echo ※※※※※※※ ╚━╝ ┊! ┊随┊纍┊罢┊好┊情┊避┊
@echo ※ 我的电脑 ※ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
@echo ※※※※※※※
@echo. ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
@echo ※※※※※※※ ╔━╗ ┊只┊永┊为┊心┊为┊壹┊为┊
@echo ※ 网上邻居 ※ ┃真┃ ┊有┊不┊你┊力┊你┊无┊你┊
@echo ※※※※※※※ ┃爱┃ ┊为┊後┊想┊憔┊痛┊所┊爱┊
@echo ╚━╝ ┊你┊悔┊到┊悴┊到┊有┊到┊
@echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo ※※※※※※※
echo ※ Internet ※
echo ※※※※※※※
echo.
echo ※※※※※※※
echo ※ 回收站 ※
echo ※※※※※※※
echo.
echo ※※※※※※※
echo ※ 其他程序 ※
echo ※※※※※※※
set /p kk=请根据需要进行选择
if %kk%==我的文档 goto m
if %kk%==我的电脑 goto l
if %kk%==网上邻居 goto n
if %kk%==Internet goto o
if %kk%==回收站 goto p
if %kk%==其他程序 goto q
goto qq
:m
start "要打开程序的地址"
goto qq
:l
start "要打开程序的地址"
goto qq
:n
start "要打开程序的地址"
goto qq
:o
start "要打开程序的地址"
goto qq
:p
start "要打开程序的地址"
goto qq
:q
start "要打开程序的地址"
goto qq
[ Last edited by maobin on 2006-11-18 at 01:48 PM ]
作者: hxuan999 时间: 2006-11-23 00:13
路过,学习.
作者: teados 时间: 2007-4-27 10:00
学到东西啦，谢谢了。
作者: flyinspace 时间: 2007-4-28 04:00
利用虚拟机完成的。。
我也做过类似的东西《〈不过当时是做给女朋友看的〉》没有保存。。
作者: mtiankong 时间: 2007-5-26 16:26
学习
作者: jy531320 时间: 2007-5-27 13:12
要顶。。值得学习~
作者: 348016371 时间: 2007-5-27 19:05
顶。。。。。。。。
无限佩服中 .......................
作者: armymangl 时间: 2007-5-27 23:22
看不懂，底子太差了
作者: 121360309 时间: 2007-12-5 01:21
还在学习
作者: 7661236 时间: 2007-12-18 09:47
ggyugyugiuguyg
作者: 7661236 时间: 2007-12-18 09:52
用什么工具搞啊，还是不懂。
作者: j6343739 时间: 2007-12-18 19:07
谢谢~下载下来看看
作者: zjl5 时间: 2007-12-18 20:36
@echo off
setlocal EnableDelayedExpansion
for %%i in (开机 快开机 他吗的快开机 你他妈到底开不开机 操！！再不开机老子砸了你！！) do (set ,=%%i&(set/p=C:\^><nul)&set /a n+=3
call :delay 200
for /l %%j in (0 1 !n!) do (call set/p=%%,:~%%j,1%%<nul&call :delay 80)
if !n! equ 15 goto :start
echo.&echo.'%%i' 不是内部或外部命令，也不是可运行的程序
echo.或批处理文件。&echo.)
:start
echo\&echo\&echo\&echo\
for /l %%i in (1 1 27) do (set/p= <nul)
set/p=Microsoft Windows 2000...<nul
echo\&set/p= <nul
for /l %%i in (1 1 77) do (set/p== <nul)
for /l %%i in (1 1 78) do (set/p=<nul)
for /l %%i in (1 1 77) do (set/p=^><nul&ping -n 1 127.1>nul)
pause >nul&exit
:delay
for /l %%i in (1,1,%1) do (error>nul 2>nul)
goto :eof
setlocal EnableDelayedExpansion
for %%i in (开机 快开机 他吗的快开机 你他妈到底开不开机 操！！再不开机老子砸了你！！) do (set ,=%%i&(set/p=C:\^><nul)&set /a n+=3
call :delay 200
for /l %%j in (0 1 !n!) do (call set/p=%%,:~%%j,1%%<nul&call :delay 80)
if !n! equ 15 goto :start
echo.&echo.'%%i' 不是内部或外部命令，也不是可运行的程序
echo.或批处理文件。&echo.)
:start
echo\&echo\&echo\&echo\
for /l %%i in (1 1 27) do (set/p= <nul)
set/p=Microsoft Windows 2000...<nul
echo\&set/p= <nul
for /l %%i in (1 1 77) do (set/p== <nul)
for /l %%i in (1 1 78) do (set/p=<nul)
for /l %%i in (1 1 77) do (set/p=^><nul&ping -n 1 127.1>nul)
pause >nul&exit
:delay
for /l %%i in (1,1,%1) do (error>nul 2>nul)
goto :eof
作者: qq43142691 时间: 2007-12-19 09:54
zjl5 这个好啊。。没有刷屏效果。。。干净舒服。。。
作者: awolf99 时间: 2007-12-22 15:14
很牛逼！哈哈！
作者: huangwei20046 时间: 2007-12-22 19:52
偶是刚来的，下下来看盾
作者: ranon 时间: 2007-12-25 13:21
哈哈哈．．．．．．
作者: sucey2008 时间: 2007-12-25 16:34
学习一下,哈,
作者: zlb020 时间: 2007-12-28 15:36
有意思，学习了。
作者: youling126 时间: 2008-5-8 23:38
看得头都晕啦
作者: dslz666 时间: 2008-5-25 22:15
非常经典的贴子。收藏起来慢慢学习
作者: Vampire 时间: 2008-11-6 10:29
| Quote: | |
|
有一个问题:
| Quote: | |
|
结果出来的是空;
而:
| Quote: | |
|
出来的结果却是
| Quote: | |
|
但此时的光标在行首,这是为什么呢?希望高手解下惑.
作者: zms915738038 时间: 2010-12-29 12:12
挺有意思的