中国DOS联盟论坛 - Powered by Discuz! Board

标题: [求助]帮助分析以下删除指定文件的错误再哪? [打印本页]

作者: tempuser 时间: 2008-10-26 13:51 标题: [求助]帮助分析以下删除指定文件的错误再哪?

我想删除指定的磁盘中某个文件,以下是代码:
:delfile
echo.
echo.
set /p  delfile=请输入你要删除的磁盘文件
for %%a in (C: D: E: F: G: H: I: )  do (
for /f "delims="  %%b in ('dir /s /b /ah %%a\%filename%') do (
del /F /S /Q  %%b
)
)
goto finddel

但是我连系统文件都删除了,搞摊了系统,这是为什么啊!我只是输入了一个普通的文本文件,而以下的代码确没有就没有,为什么呢,请大家帮我查出我的问题在哪啊:

@echo off
set/p f=请输入这个文件的名称:
set/p t=删除文件请按d:
for %%a in (c d e ) do call :%t% %%a
:d
rem  我的理解是for把c d e作为参数传给了%%a ,而%%a又作为call的第一个参数
for /r %1:\ %%i in ("%f%") do del/f/q/a/s "%%i
rem  for先后遍历指定磁盘下的文件再把路径传给%%i,在del
可是我上面的代码也是这个思路啊!怎么就连系统的文件都给删了呢?我的问题出在那呢?

作者: 8657 时间: 2008-10-26 14:56
\%filename%在哪？？？在加个 2^<nul

作者: tempuser 时间: 2008-10-26 15:01
现在不是不删,而是连系统文件都删,太可怕了!

作者: HAT 时间: 2008-10-26 15:14
定义变量的时候用delfile
删除文件的时候却用filename
故意的？还是笔误？

作者: 8657 时间: 2008-10-26 15:18
难道没看明白我的意思么你的 filename没被定义

作者: tempuser 时间: 2008-10-26 15:40
不好意思,被它弄晕了,把%filename%换成%delname%,也无法删除指定的文件.

另外，再问一个古灵精怪的问题,还是那段我找的代码:
:delfile
echo.
echo.
set/p f=请输入这个文件的名称:
set/p t=删除文件请按d:
for %%a in (c d e f) do call :%t% %%a
:d
rem 我的理解是for把c d e作为参数传给了%%a ,而%%a又作为call的第一个参数
for /r %1:\ %%i in ("%f%") do del/f/q/a/s "%%i
rem for先后遍历指定磁盘下的文件再把路径传给%%i,在del

把以上代码单独写一个批处理文件,它是可以删除文件的,但如果把他作为一个标号:delfile,却不执行了,也不出现任何错误提示,你说怪不怪,我快被这个问题蛰么死了!
快帮帮我啊!头快要炸了!

作者: HAT 时间: 2008-10-26 16:35 标题: Re 6楼

那为何现在还不修改顶楼的内容呢？
想再弄晕几个近来帮你回答问题的？
^_^

作者: terse 时间: 2008-10-26 17:03
"%%i
最后面的“那里去了

作者: tireless 时间: 2008-10-26 22:06
第一段：

1：
set /p  delfile=请输入你要删除的磁盘文件

delfile 要改成 %filename% 吧。

2：
for /f "delims=" %%b in ('dir /s /b /ah %%a\%filename%') do (
  del /F /S /Q %%b
)

①你确定只删除隐藏文件吗？是的话改成这样：
for /f "delims=" %%b in ('dir /s /b /a:-dh %%a\%filename%') do (
  del /F /a:h "%%b"
)
del 的参数 /S /Q 在这里是多余的：
/S 是包括删除子文件夹中文件。例如 del /s d:\test.txt 将删除 d 盘下所有的 test.txt。
/Q 是通配符删除时不需要确认。例如 del d:\test*。

②还是...你是想也删除隐藏文件？是的话改成这样：
for /f "delims=" %%b in ('dir /s /b /a:-d %%a\%filename%') do (
  del /F "%%b" 2>nul || del /F /a:h "%%b"
)

第二段：

for /r %1:\ %%i in ("%f%") do del/f/q/a/s "%%i

首先，你可以在 cmd 窗口中测试一下这条命令：
for /r c:\ %a in (reg.exe) do @echo %a
结果会是：

c:\reg.exe
c:\FOUND.000\reg.exe
c:\FOUND.001\reg.exe
c:\FOUND.002\reg.exe
c:\FOUND.003\reg.exe
c:\WINDOWS\reg.exe
c:\WINDOWS\PCHealth\reg.exe
... ...

只列出存在的文件，需要用 if exist 来判断：
for /r c:\ %a in (reg.exe) do @if exist "%a" echo %a
或者用通配符：
for /r c:\ %a in (reg.exe?) do @echo %a
但是好像如果文件名含空格的话，用 for /r 行不通。

[ Last edited by tireless on 2008-10-27 at 00:41 ]

作者: HAT 时间: 2008-10-26 22:38 标题: Re 9楼

如果文件名含空格的话，这样行吗？

for /r C:\test %a in (*.txt) do @if "%~nxa" equ "a b.txt" echo %a

作者: tireless 时间: 2008-10-26 23:32 标题: Re 10 楼

可行。很慢就是，不过用 for /r 搜索含空格的文件只有这个方法了。

作者: tempuser 时间: 2008-10-27 10:26
还是忙然!
1.如果我想删除任指定文件而不管它是否隐藏,那代码应该是

@echo off
set /p filename=请输要删出的文件名
for  %%a  in (c: d:) do (
   for /f "delims=" %%b in ('dir /s /b /a:-d %%a\%filename%') do (
   del /F "%%b" 2>nul || del /F /a:h "%%b"
   )
)
但是我现在的执行它,不仅批处理本身被删,而切windows文件保护又来了,估计我又要恢复系统了,还好我有GHO!
2.请问 del /a:-dh中的d什么意?
del /?中没有d?

作者: tireless 时间: 2008-10-27 11:30 标题: Re 12楼

额..你先用 echo，看被删除的文件对不对。

@echo off
set /p filename=请输要删出的文件名:
for  %%a  in (c: d:) do (
   for /f "delims=" %%b in ('dir /s /b /a:-d %%a\%filename% 2^>nul') do (
   echo del /F "%%b" 2>nul
   echo del /F /a:h "%%b" 2>nul
   )
)
pause

我测试了下，没什么问题啊:

Quote:

请输要删出的文件名:notepad.exe
del /F "c:\WINDOWS\notepad.exe"
del /F "c:\WINDOWS\system32\notepad.exe"
请按任意键继续. . .

2.dir /a:d 是列出目录，dir /a:-d 就是列出非目录，即文件。

Quote:

DIR [drive:][path][filename] [/A[[:]attributes]] [/B] [/C] [/D] [/L] [/N]
  [/O[[:]sortorder]] [/P] [/Q] [/S] [/T[[:]timefield]] [/W] [/X] [/4]

  [drive:][path][filename]
            指定要列出的驱动器、目录和/或文件。

  /A       显示具有指定属性的文件。
  attributes D  目录             R  只读文件
            H  隐藏文件          A  准备存档的文件
            S  系统文件          -  表示“否”的前缀

[ Last edited by tireless on 2008-10-27 at 11:48 ]

作者: tempuser 时间: 2008-10-27 14:39
谢谢,已解决,但不知为什么先前的出了问题，我也是拷贝的代码啊!

另外,还得请教个问题:
echo del /F "%%b" 2>nul中的2>nul是前面的命令出了错误要屏蔽出错信息吧！
那for /f "delims=" %%b in ('dir /s /b /a:-d %%a\%filename% 2^>nul')中为什么用2^>nul而不是2>nul呢？它们的作用不一样吗？还是有什么特殊要求？

作者: tireless 时间: 2008-10-27 14:54 标题: Re 14 楼

2^>nul 中的 ^ 是“转义字符”。
例如要显示 | 等特殊符号，执行 echo | 是显示不出来的，要用 echo ^|

[ Last edited by tireless on 2008-10-27 at 14:55 ]

作者: tempuser 时间: 2008-10-27 15:06

Quote:

Originally posted by tireless at 2008-10-27 11:30:
额..你先用 echo，看被删除的文件对不对。

@echo off
set /p filename=请输要删出的文件名:
for %%a in (c: d:) do (
for /f "del ...

又一个测试中的问题：
我在批处理文件所在的目录建立了1.txt和2.txt，随便在其他的某个磁盘下也建立了1.txt和2.txt，其中2.txt是隐藏的，但奇怪的是只删除：
1.txt和批处理目录下的2.txt，但另一个2.txt没删除，当我再次运行批处理删除这个隐藏属性的2.txt可以删除，为什么删除不是一次性的？

作者: tireless 时间: 2008-10-27 15:30 标题: Re 16 楼

我测试能删除。输入 1.txt;2.txt 或 1.txt 2.txt 都可以。

@echo off

set /p filename=请输要删出的文件名:

for %%a in (c: d:) do (

  for /f "delims=" %%b in ('dir /s /b /a:-d %%a\%filename% 2^>nul') do (

    del /F "%%b" 2>nul

    del /F /a:h "%%b" 2>nul

  )

)

pause

[ Last edited by tireless on 2008-10-27 at 15:32 ]

作者: tempuser 时间: 2008-10-27 15:42
我也测试了多遍啊！同批处理在一个目录下的文件没问题，但其它盘符下的隐藏文件就不能一次性删除，麻烦您在测试一下好吗？当然，我也得在测试测试！

作者: tempuser 时间: 2008-10-27 15:48
我又测试了一遍，还是不行。
测试条件：

1。C盘下有1.txt和2.txt，2.txt是隐藏的；
2。D盘下有1.txt和2.txt，2.txt是隐藏的，批处理文件也在D盘下。
执行：
双击批处理文件，无论输入1.txt 2.txt还是1.txt;2.txt，测试结果都相同。

测试结果：
C盘下的1.txt删除掉；
D盘下的有1.txt和2.txt都删除掉了。

C盘下的隐藏文件2.txt没有被删除。

作者: tireless 时间: 2008-10-27 16:05
抱歉，我也不知道为什么，确实会出现你说的情况。改成这样就可以：

@echo off

set /p filename=请输要删出的文件名:

for %%a in (c: d:) do (

  cd /d %%a\

  for /f "delims=" %%b in ('dir /s /b /a:-d %filename% 2^>nul') do (

    del /F "%%b" 2>nul

    del /F /a:h "%%b" 2>nul

  )

)

[ Last edited by tireless on 2008-10-27 at 16:07 ]