标题: CALL 和 SET 的問題 [打印本页]
作者: qoozen 时间: 2008-2-1 17:46 标题: CALL 和 SET 的問題
set str1=abcdefghijklmnopqrstuvwxyz
set str2=ABCDEFGHIJKLMNOPQRSTUVWXYZ
:main
cls
set str=
set /p str= 請輸入字符串(退出請直接按回車)：
if not defined str exit
cls
echo.
echo 轉換前："%str%"
echo.
for /l %%i in (0,1,25) do (
call set char1=%%str1:~%%i,1%%
call set char2=%%str2:~%%i,1%%
call :change
)
echo ____________________________________________
echo.
echo 轉換後："%str%"
echo.
echo 按任意鍵進行下一次演示...
pause>nul
goto main
:change
call set "str=%%str:%char1%=%char2%%%"
goto :eof
想問問Call Set xxxx 有什麼作用呢?
作者: slore 时间: 2008-2-1 17:56
貌似和启用延时变量的效果一样
就是让FOR循环中的SET在内部的改变有效。
作者: qoozen 时间: 2008-2-1 18:14
| Quote: | |
|
多謝你的回答,但如果用setlocal enabledelayedexpansion能做到和上面的效果嗎?
作者: qoozen 时间: 2008-2-1 18:16
Set C1=!!str1:~%%a,1!!
Set C2=!!str2:~%%a,1!!
已經試過ok了,
作者: pinghu 时间: 2008-2-12 19:06
call set char1=%%str1:~%%i,1%%
一句实际上把set语句执行了两遍：
第一遍set char1=%str1：~0，1%
第二遍set char1=a
作者: terrytong 时间: 2008-5-6 19:10
call set "str=%%str:%char1%=%char2%%%"
谁能详细解释一下这句啊。不胜感激...
作者: bat-zw 时间: 2008-5-6 19:24 标题: 运行以下代码你就明白了：
@echo off
set a=123456789
echo a=%a%
set b=%a:~,4%&set c=%a:~5,4%
echo b=%b% c=%c%
echo call,set a=%%a:%b%=%c%%%
call,set a=%%a:%b%=%c%%%
echo a=%a%
pause>nul
set a=123456789
echo a=%a%
set b=%a:~,4%&set c=%a:~5,4%
echo b=%b% c=%c%
echo call,set a=%%a:%b%=%c%%%
call,set a=%%a:%b%=%c%%%
echo a=%a%
pause>nul
作者: moniuming 时间: 2008-5-6 20:16
| Quote: | |
|
我是在别的地方看到的,现在奉献出来:)
使用call进行变量延迟遵循以下两个步骤的替换,有n个call,就进行n+1次替换
1.如果分号的数量为单(只看一边),则把最里面的分号用变量替换
2.把双数的分号去掉一半(只看一边)
call set "str=%%str:%char1%=%char2%%%"
比如输入的是"a",转换过程如下(有1个call,则进行2次替换,每次有两个步骤):
1.(1)把单个分号的用变量替换,得
"str=%%str:a=A%%"
(2)把双数的分号去掉一半,得
"str=%str:a=A%"
2.(1)把单个分号的用变量替换,得
"str=A"
(2)把双数的分号去掉一半,由于没有分号了,故为A
其实在本例中,可以不用call :change的,用下面一句代替也完全可以达到同样效果:
call call set str=%%%%str:%%char1%%=%%char2%%%%%%
举个例子加深印象:
@echo off
set "a=cn-dos"
set "b=a"
set "c=b"
set "d=c"
echo %a%
call echo %%%b%%%
call call echo %%%%%%%c%%%%%%%
call call call echo %%%%%%%%%%%%%%%d%%%%%%%%%%%%%%%
pause
set "a=cn-dos"
set "b=a"
set "c=b"
set "d=c"
echo %a%
call echo %%%b%%%
call call echo %%%%%%%c%%%%%%%
call call call echo %%%%%%%%%%%%%%%d%%%%%%%%%%%%%%%
pause
作者: HAT 时间: 2008-5-6 20:22
willsort 兄对逃逸字符的讲解也许对楼主有帮助。
作者: joyn 时间: 2008-5-6 23:16
call,set..这些我不太明白哪里有参考资料?可否贡献一下
作者: terrytong 时间: 2008-5-7 15:16
| Quote: | |
|
你举的例子我能看的懂，但是
"str=%str:a=A%"
把单个分号的用变量替换,怎么得到
"str=A" ?
应该是"str=a:a=A 啊。
不好意思。见笑了。
作者: moniuming 时间: 2008-5-7 17:36
环境变量替换已如下增强:
%PATH:str1=str2%
会扩展 PATH 环境变量，用 "str2" 代替扩展结果中的每个 "str1"。
要有效地从扩展结果中删除所有的 "str1"，"str2" 可以是空的。
"str1" 可以以星号打头；在这种情况下，"str1" 会从扩展结果的
开始到 str1 剩余部分第一次出现的地方，都一直保持相配。
作者: jia332 时间: 2008-5-21 09:19
那位有这方面的资料，能否共享一下，让小弟系统的学习一下
十分感谢