中国DOS联盟论坛 - Powered by Discuz! Board

标题: [求助]批处理列出所有开机启动项 [打印本页]

作者: fjcyz 时间: 2007-11-1 20:00 标题: [求助]批处理列出所有开机启动项

如题：

或者列出注册表相关键值

作者: luckboy45 时间: 2007-11-1 20:35
下面是JM写的代码,可能对你有用!~

@echo off
:: 考虑到程序并非都安装在系统盘下，所以还要用!str:~-1!来截取盘符
:: 如果路径中含有N个中文字符的话，此路径的最后N个字符将不显示(一个中文字符占两个字符位)
:: code by jm 2006-7-27
setlocal enabledelayedexpansion
echo.
echo 开机自启动的程序有：
echo.
for /f "skip=4 tokens=1* delims=:" %%i in ('reg query HKLM\Software\Microsoft\Windows\CurrentVersion\Run') do (
set str=%%i
set var=%%j
set "var=!var:"=!"
if not "!var:~-1!"=="=" echo !str:~-1!:!var!
)
pause>nul

作者: everest79 时间: 2007-11-2 10:44

@ECHO OFF

SET RQ=REG QUERY

SET CU=HKEY_CURRENT_USER

SET LM=HKEY_LOCAL_MACHINE

SET FS=FINDSTR /V /B "! HKEY_"^|FINDSTR "."

SET WS=\Software\Microsoft\Windows\CurrentVersion\

SET WT=\Software\Microsoft\Windows NT\CurrentVersion\

SET CK=\SYSTEM\CurrentControlSet\Control\Session Manager

SET RT=LoadUserinitWindowsWinlogonShellRunOnceExPolicies\Explorer\RunBootExecute

SET RP=ECHO -------------------------------------------------------------------------------

%RP%&ECHO %ALLUSERSPROFILE%^&%USERNAME%\「开始」菜单\程序\启动

FOR %%i IN (ALLUSERSPROFILE;USERPROFILE) DO CALL DIR /B /S "%%%%i%%\「开始」菜单\程序\启动"

%RP%

FOR /F "tokens=1-8 delims=: " %%A IN ('FINDSTR /B "::" "%~nx0"') DO (

    CALL :REGQUERY 1 %%A %%B %%C %%D %%E %%F %%G ">NUL"

    )

SET /A 1/%~1 2>NUL&&GOTO :EOF

SET /p CONU=导出为文本文档?(Y/N):

ECHO %CONU%|FIND /I "N" 1>NUL 2<&1&&GOTO :EOF

CALL %~nx0 1 >%~n0%.txt

ECHO file list:%~dpn0%.txt

PAUSE>NUL&"%~dpn0%.txt"

GOTO :EOF

::CU WT 12  7 V  0  4

::LM WT 19  8 V  4  8

::LM WT 19  8 V 27  5

::CU WS 32  3 S  0  0

::LM WS 32  3 S  0  0

::CU WS 32  7 S  0  0

::LM WS 32  7 S  0  0

::CU WS 32  9 S  0  0

::LM WS 32  9 S  0  0

::CU WS 41 21 S  0  0

::LM WS 41 21 S  0  0

::LM CK  0  0 V 62 11

:REGQUERY

CALL SET PR=%%%~2%%%%%~3%%%%rt:~%~4,%~5%%&CALL SET PZ=%%rt:~%~7,%~8%%

ECHO [%PR%] %~9&%RQ% "%PR%" /%6 %PZ% 2>NUL|%FS% %~9&&%RP%&&SET/A 1/%1 2>NUL&&CALL %0 0 %2 %3 %4 %5 %6 %7 %8

GOTO :EOF

作者: lxmxn 时间: 2007-11-2 12:22
everest79兄的代码很有特色，已经形成自己的风格了哈，暂一个。

作者: fjcyz 时间: 2007-11-2 13:54
FOR %%i IN (ALLUSERSPROFILE;USERPROFILE) DO CALL DIR /B /S "%%%%i%%\「开始」菜单\程序\启动"

这句 CALL 跟 %%%%i%% 的作用是什么?

我改成这样子就不行了

FOR %%i IN (ALLUSERSPROFILE;USERPROFILE) DO ( DIR /B /S "%%%%i%%\「开始」菜单\程序\启动" )

[ Last edited by fjcyz on 2007-11-2 at 01:56 PM ]

作者: fjcyz 时间: 2007-11-2 15:21
麻烦3楼解释一下各条批处理的作用,看的头都晕了.

作者: fjcyz 时间: 2007-11-2 18:47
@ECHO OFF

ECHO 用户启动项 >%TEMP%\a.txt
dir /b /s "%USERPROFILE%\「开始」菜单\程序\启动" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows\CurrentVersion\Run | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows" "NT\CurrentVersion\Windows /v load | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows\CurrentVersion\RunOnce | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\Run | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt

reg query HKCU\Software\Microsoft\Windows\CurrentVersion\RunServicesOnce | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows\CurrentVersion\RunServices | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows\CurrentVersion\RunOnce\Setup | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt
reg query HKCU\Software\Microsoft\Windows\CurrentVersion\RunOnceEx | findstr /v /C:"! REG.EXE VERSION" /C:"HKEY_CURRENT_USER" >>%TEMP%\a.txt

ECHO 全局启动项 >>%TEMP%\a.txt
DIR /B /S "%ALLUSERSPROFILE%\「开始」菜单\程序\启动" >>%TEMP%\a.txt
reg query HKLM\Software\Microsoft\Windows\CurrentVersion\Run | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer\Run | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows" "NT\CurrentVersion\Winlogon /v Shell | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows" "NT\CurrentVersion\Winlogon /v Userinit | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt

reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunServicesOnce | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunServices | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce\Setup | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx | findstr /v /C:"! REG.EXE VERSION" /c:"HKEY_LOCAL_MACHINE" >>%TEMP%\a.txt
if exist %TEMP%\b.txt del /f %TEMP%\b.txt
for /f "delims=" %%i in (%TEMP%\a.txt) do echo %%i >>%TEMP%\b.txt
CLS
type %TEMP%\b.txt
pause >nul

本人写的开机启动项,代码还没经过优化,画面杂了一点.

[ Last edited by fjcyz on 2007-11-2 at 06:52 PM ]

作者: everest79 时间: 2007-11-2 19:39

Quote:

Originally posted by lxmxn at 2007-11-2 12:22 PM:
everest79兄的代码很有特色，已经形成自己的风格了哈，暂一个。

原来写的呀，哈哈，一直找不到借口贴上来

作者: everest79 时间: 2007-11-2 20:06

Quote:

Originally posted by fjcyz at 2007-11-2 03:21 PM:
麻烦3楼解释一下各条批处理的作用,看的头都晕了.

我用的也是通过注册表来查询，不过采用了格式化输入输出，同时用了大量的变量代替正常代码，所以看起来很复杂，你可以打开回显后观察

你上一个问题解释起来太费脑筋，论坛有相关贴子主题应是 call 变量延迟