标题: 如何编一个关机的bat文件? [打印本页]
作者: demond123 时间: 2006-11-15 22:40 标题: 如何编一个关机的bat文件?
我是新手,高手不要见笑.
我昨天把"shutdown/s"存为一个bat文件以为能够实现关机,结果不行.请问该怎样办?
[ Last edited by demond123 on 2006-11-15 at 10:43 PM ]
作者: NaturalJ0 时间: 2006-11-15 22:45
9x
rundll user,exitwindows
nt
shutdown /s /f
试试？
作者: demond123 时间: 2006-11-15 22:49
谢谢,果然可以.但是不知道其中道理,能解释下吗,我只看得最后一行懂啊?
作者: demond123 时间: 2006-11-15 22:51
前面那个
9x
rundll user,exitwindows
好象没什么作用啊,去掉也没什么影响吧?
作者: demond123 时间: 2006-11-15 22:55
还有,为什么我在命令提示符中使用shutdown/s可以直接关机,而在批处理文件中要加入/f参数呢?
作者: ccwan 时间: 2006-11-15 23:27
－f是强制关闭应用程序而没有警告，命令提示符中使用和批处理文件中使用是一样的。
作者: zouzhxi 时间: 2006-11-15 23:31
shutdown -s -t 0
作者: uemuem 时间: 2006-11-18 03:04
Windows XP的关机是由Shutdown.exe程序来控制的，位于Windows＼System32文件夹中
。如果想让Windows 2000也实现同样的效果，可以把Shutdown.exe复制到系统目录下。
比如你的电脑要在22:00关机，可以选择“开始→运行”，输入“at 22:00 Shutdown -s”，这样，到了22点电脑就会出现“系统关机”对话框，默认有30秒钟的倒计时并提示你保存工作。如果你想以倒计时的方式关机，可以输入“Shutdown.exe -s -t 3600”，这里表示60分钟后自动关机，“3600”代表60分钟。
设置好自动关机后，如果想取消的话，可以在运行中输入“shutdown -a”。另外输入“shutdown -i”，则可以打开设置自动关机对话框，对自动关机进行设置。
Shutdown.exe的参数，每个都具有特定的用途，执行每一个都会产生不同的效果，比如“-s”就表示关闭本地计算机，“-a”表示取消关机操作，下面列出了更多参数，大家可以在Shutdown.exe中按需使用。
-f：强行关闭应用程序
-m \\计算机名：控制远程计算机
-i：显示图形用户界面，但必须是Shutdown的第一个选项
-l：注销当前用户
-r：关机并重启
-t时间：设置关机倒计时
-c "消息内容"：输入关机对话框中的消息内容(不能超127个字符)
[ Last edited by uemuem on 2006-11-22 at 10:10 PM ]
附件 1:定时关机小助手.rar (2006-11-18 03:04, 60.53 K, 下载附件所需积分 1点 ,下载次数： 116)
作者: hxuan999 时间: 2006-11-23 04:54
xue xi le...
作者: electronixtar 时间: 2006-11-23 06:54
XP 里 shutdown -s 后 要 -t 0
2003里要 -c
作者: tathatayx 时间: 2006-11-29 10:53
这个不错！
作者: gdstxl 时间: 2006-11-29 11:21
@ECHO off
TITLE greaterthanme-实现定时关机、注销、重启、锁定等功能。
:start
CLS
COLOR 1f
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=41 LINES=18
rem MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO =========================================
ECHO 请选择要进行的操作，然后按回车
ECHO ───────────────
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机
ECHO 3. 删除定时关机任务
ECHO 4. 查看任务状态
ECHO 5. 刷新当前时间
ECHO 6. 重新启动
ECHO 7. 锁定计算机
ECHO 8. 注销
ECHO 9. 退出
ECHO.
:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
ECHO.
GOTO cho
:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour
:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes
:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no
:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start
:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ────────
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime
:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start
:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start
:restart
shutdown -r -t 0
:lock
rundll32.exe user32.dll,LockWorkStation
goto start
:logoff
logoff
:end
exit
看下
作者: BWSkyer 时间: 2006-11-29 11:27
楼上的代码很8错，刚才试验了一下，很方便！！
作者: freeapple 时间: 2006-11-29 13:50
12楼的好人啊，太经典了
作者: gene771771 时间: 2006-11-29 13:53 标题: 我把源码发上来
echo off
cls
@echo off
REM title 自动关机小助手 by:Luem
color 0b
echo.
echo.
echo ===========你正在使用的是由Luem为您设计的定时关机程序==179421778==========
echo.
echo.
echo ╔══════════════════════════════╗
echo ║ ║
echo ║ a.定时关机(在某一时间自动关机，例17:02) ║
echo ║ ║
echo ║ b.倒计时关机(一定时间后自动关机,例60，60=1分钟) ║
echo ║ ║
echo ║ c.取消前面已经设定的自动关机(关闭关机对话框) ║
echo ║ ║
echo ║ 说明：大小写请一致，请按提示格式输入时间，否则无效! ║
echo ║ ║
echo ╚══════════════════════════════╝
echo.
:e
echo.
set /p c=请选择定时方式(a\b\c)：
if "%c%"=="" goto e
if "%c%"=="a" goto s
if "%c%"=="b" goto a
if "%c%"=="c" goto i
:s
echo.
set /p t=你想让电脑在什么时间自动关机？请输入(例17:02)：
if "%t%"=="" goto s
echo.
echo 电脑将在%t%自动关机,按任意键确定...
echo.
pause
at %t% shutdown -s
goto end
:a
echo.
set /p d=你想让电脑在多长时间后关机？请输入(例60=1分钟)：
if "%d%"=="" goto a
echo.
echo 电脑将在%d%秒后自动关机,按任意键确定...
echo.
pause
shutdown -s -t %d%
goto end
:i
shutdown -a
echo.
echo 定时关机已取消,按任意键退出...
echo.
pause
:end
作者: ccwan 时间: 2006-11-29 20:45
没有必要这么麻烦。若要全面，恐怕还得加上注销和重启吧？
做到这样，本身已经不方便使用了。
作者: gene771771 时间: 2006-11-29 21:27 标题: RE：ccwan
其实讨论价值已经高于了批处理本身了
作者: zhoushijie 时间: 2006-11-30 01:45
何必这么麻烦，按一下键盘上的Power(电源)按钮就行了
作者: ccwan 时间: 2006-11-30 01:58
嗯，终于想起来了，12楼的代码在邪八网站上看到过
http://forum.eviloctal.com/read-htm-tid-25643.html
作者: a9319751 时间: 2006-11-30 05:04
at 2:00 shutdown -s
作者: weihua1983 时间: 2006-12-1 08:36
果然好多高手啊！~
作者: lxq73061 时间: 2006-12-3 13:04
什么人把我的代码贴到这里来了???
http://www.oa7t.com/bbs/thread-2181-1-1.html
如何命令建立隐藏的超级用户
用批处理做自动关机程序http://www.oa7t.com/bbs/thread-5-1-1.html
作者: lxmxn 时间: 2006-12-3 13:25
不知道，不是偶干的……=_=
作者: mountvol 时间: 2006-12-3 13:32
22F的连结:
| Quote: | |
|
12月2号发的，这边居然11月就转到你12月的贴了，厉害啊。
几条普通命令的组合而已，这里能写出来的一抓一大把。
作者: lxq73061 时间: 2006-12-30 09:30
真是我做的骗你干嘛 不信你百度一下就知道 了
http://www.baidu.com/s?ct=0& ... 1%C1%CE%CF%FE%C7%E0
http://www.baidu.com/s?ie=gb2312 ... 7%E0%BD%A3&ct=0
http://www.baidu.com/s?ie=gb2312 ... A1lxq73061&ct=0
去年就有了
作者: sihan 时间: 2007-1-6 13:40
ding
作者: fanrenjia 时间: 2007-1-16 10:09 标题: 也发一个
DownFlag=8
set win32_OS=getobject("winmgmts:{(Shutdown)}//./root/cimv2").execQuery("select * from win32_operatingsystem where primary=true")
for each OS in win32_OS
OS.win32shutdown(DownFlag)
next
set win32_OS=nothing
作者: freedomtime 时间: 2008-9-25 23:54 标题: xuexi
haha hao a
作者: hnjzsxn 时间: 2008-9-26 13:33
不错不错
作者: haolongo 时间: 2008-9-26 14:14
我觉的下面的还不错。
作者: willing 时间: 2008-10-1 16:58
一个shudown的问题，楼上没必要高这么复杂吧？！