中国DOS联盟

echo off

cls





rem 以下是判断端口

set count=0

:addreginfo

set /a count=%count%+1

if exist 打印机%count%.txt (set filename=打印机%count%.txt) else (goto eof)

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr /I "打印机IP="') do set pIP=%%a

if /I "%pIP%"=="LPT1:" goto addreginfo

if /I "%pIP%"=="LPT2:" goto addreginfo





rem 以下是添加端口在注册表中的信息

set regpath1=HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Print\Monitors\Standard TCP/IP Port\Ports\IP_

set regpath2=HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Monitors\Standard TCP/IP Port\Ports\IP_

:addreg1

@reg add "%regpath1%%pip%" /v "Protocol" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "Version" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "HostName" /d "" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "IPAddress" /d "%pip%" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "HWAddress" /d "" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "PortNumber" /d "9100" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "SNMP Community" /d "public" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "SNMP Enabled" /d "00000000" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "SNMP Index" /d "00000001" /f /t REG_DWORD >nul 2>nul

:addreg2

@reg add "%regpath2%%pip%" /v "Protocol" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "Version" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "HostName" /d "" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "IPAddress" /d "%pip%" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "HWAddress" /d "" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "PortNumber" /d "9100" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "SNMP Community" /d "public" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "SNMP Enabled" /d "00000000" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "SNMP Index" /d "00000001" /f /t REG_DWORD >nul 2>nul

goto addreginfo

:eof





rem 以下是重新启动打印服务，使新端口生效

:restartservice

cls

echo.

echo   请稍候，正在启用打印机端口！

echo.

net stop spooler >nul 2>nul

net start spooler >nul 2>nul





rem 以下是添加打印机

set count=0

:instprinter

set /a count=%count%+1

if exist 打印机%count%.txt (set filename=打印机%count%.txt) else (goto over)

cls

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机IP="') do set pIP=%%a

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机名称="') do set pname=%%a

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机型号="') do set pmodel=%%a

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机INF位置="') do set pinf=%%a

echo.

echo 请稍等，正在添加打印机%count%,相关信息如下：

echo.

echo  IP  ：%pIP%

echo 名称 ：%pname%

echo 型号 ：%pmodel%

echo 驱动 ：%pinf%

if /I "%pIP%"=="LPT1:" (goto ok)

if /I "%pIP%"=="LPT2:" (goto ok) else (set pip=IP_%pip%)

:ok

rundll32 printui.dll,PrintUIEntry /if /b "%pname%" /f "%pinf%" /r "%pIP%" /m "%pmodel%"

goto instprinter





:over

cls 

echo.

echo  打印机添加完毕！

pause

exit

打印机IP=44.44.44.44

打印机名称=柯尼卡 220 打印服务器

打印机型号=KONICA MINOLTA 220

打印机INF位置=D:\sysbak\打印机\220驱动\TSK.inf

打印机IP=LPT1:

打印机名称=本地HP 3050

打印机型号=HP LaserJet 3050 Series PCL 5e

打印机INF位置=D:\sysbak\打印机\hp3055\Drivers\2K_XP_Vista\hppcp501.inf

Purpose:
Batch - add printers according to the printer configuration file. For example, a computer needs to install a local parallel port printer and a network print server at the same time (not sharing the printer of other computers, but the printer that can be connected to the switch with a network cable).

Implementation steps:
1. Poll the "Printer X.txt" in the directory. According to the port description in it, judge whether it is a local LPT port. If it is a local LPT printer, ignore it. If it is a print server, automatically create a new TCP/IP port.
2. Restart the print service to make the newly created local IP port take effect.
3. Poll the "Printer X.txt" in the directory. According to the printer name, driver location, printer model and printer port, add the print server.

Key statement:
rundll32 printui.dll,PrintUIEntry /?

Defect:
Because I don't need local printers with USB ports and don't use shared printers, there are no statements added to judge such printers.

★★★★★★★★★
The following is the batch code

@echo off

cls





rem The following is to judge the port

set count=0

:addreginfo

set /a count=%count%+1

if exist 打印机%count%.txt (set filename=打印机%count%.txt) else (goto eof)

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr /I "打印机IP="') do set pIP=%%a

if /I "%pIP%"=="LPT1:" goto addreginfo

if /I "%pIP%"=="LPT2:" goto addreginfo





rem The following is to add the information in the registry about the port

set regpath1=HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Print\Monitors\Standard TCP/IP Port\Ports\IP_

set regpath2=HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Monitors\Standard TCP/IP Port\Ports\IP_

:addreg1

@reg add "%regpath1%%pip%" /v "Protocol" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "Version" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "HostName" /d "" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "IPAddress" /d "%pip%" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "HWAddress" /d "" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "PortNumber" /d "9100" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "SNMP Community" /d "public" /f >nul 2>nul

@reg add "%regpath1%%pip%" /v "SNMP Enabled" /d "00000000" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath1%%pip%" /v "SNMP Index" /d "00000001" /f /t REG_DWORD >nul 2>nul

:addreg2

@reg add "%regpath2%%pip%" /v "Protocol" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "Version" /d "00000001" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "HostName" /d "" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "IPAddress" /d "%pip%" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "HWAddress" /d "" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "PortNumber" /d "9100" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "SNMP Community" /d "public" /f >nul 2>nul

@reg add "%regpath2%%pip%" /v "SNMP Enabled" /d "00000000" /f /t REG_DWORD >nul 2>nul

@reg add "%regpath2%%pip%" /v "SNMP Index" /d "00000001" /f /t REG_DWORD >nul 2>nul

goto addreginfo

:eof





rem The following is to restart the print service to make the new port take effect

:restartservice

cls

echo.

echo   Please wait, enabling the printer port!

echo.

net stop spooler >nul 2>nul

net start spooler >nul 2>nul





rem The following is to add the printer

set count=0

:instprinter

set /a count=%count%+1

if exist 打印机%count%.txt (set filename=打印机%count%.txt) else (goto over)

cls

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机IP="') do set pIP=%%a

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机名称="') do set pname=%%a

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机型号="') do set pmodel=%%a

for /f "tokens=2 delims==" %%a in ('type %filename% ^|findstr "打印机INF位置="') do set pinf=%%a

echo.

echo Please wait, adding printer %count%, the relevant information is as follows:

echo.

echo IP: %pIP%

echo Name: %pname%

echo Model: %pmodel%

echo Driver: %pinf%

if /I "%pIP%"=="LPT1:" (goto ok)

if /I "%pIP%"=="LPT2:" (goto ok) else (set pip=IP_%pip%)

:ok

rundll32 printui.dll,PrintUIEntry /if /b "%pname%" /f "%pinf%" /r "%pIP%" /m "%pmodel%"

goto instprinter





:over

cls 

echo.

echo  Printer addition is complete!

pause

exit

★★★★★★★★★
The content of the network print server configuration file "Printer 1.txt":

Printer IP=44.44.44.44

Printer Name=Konica 220 Print Server

Printer Model=KONICA MINOLTA 220

Printer INF Location=D:\sysbak\Printers\220 Drivers\TSK.inf

★★★★★★★★★
The content of the local printer configuration file "Printer 2.txt":

Printer IP=LPT1:

Printer Name=Local HP 3050

Printer Model=HP LaserJet 3050 Series PCL 5e

Printer INF Location=D:\sysbak\Printers\hp3055\Drivers\2K_XP_Vista\hppcp501.inf

Last edited by exzzz on 2008-12-15 at 14:46 ]

It is suggested to change the first line to @echo off, and delete all other @

Thanks, moderator, for your concern!

I took a little shortcut, heh heh. The part with @..... was copied from my other batch script, and I was too lazy to replace it. After echo off, I'm used to cls, a bad habit I formed years ago that I still can't get rid of...

What about adding a USB - connected printer? How should it be written?

I haven't installed USB before, but you can first install it manually once. Check what characters are there in the port properties of the printer. I remember it should be something like USB01: or the like. You can modify the printer IP in the txt file and that should work.

And according to the characteristics of USB devices, you should be able to install it on any port randomly, such as network or LPT, then uninstall it after installation. Then when you restart, it will be automatically installed in the background.

Originally posted by exzzz at 2009-3-19 01:40:
I haven't installed USB ones, but you can first install manually once, check what characters are in the printer port properties, remember it should be something like USB01: and so on, modify the printer IP in the txt file...

USB001

But it doesn't work.

I tried it

When installing to the end, it appears that the printer cannot be installed

I don't know the reason

It seems that "virtual printer" is also a new port ah,

Why does USB have to be connected to the printer to work? :(

Because the USB ports are generated randomly, and a USB port is created only when a USB printer is connected.

In Windows 2000 and XP systems, USB interface devices are all regarded as plug-and-play devices, so USB printers will not have a specifically pre-designated port in the list.
Only after connecting the printer will it be randomly assigned according to system interrupts, ports and other issues. So if your printer is a USB port, after you plug in the printer and turn on the printer power, the system will automatically search and install.

This simply cannot achieve the functions you mentioned. Ports cannot be added, let alone installing a printer.