中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客: 注册 | 登录 | 命令行 | 会员 | 搜索 | 上传 | 帮助 »

中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » [求助][NT]如何获得ECHO当前的开关状态？

BatMan
初级用户

蝙蝠侠是写批处理的人

积分 54
发帖 24
注册 2008-1-4
状态离线

『楼主』: [求助][NT]如何获得ECHO当前的开关状态？

　　我们都知道只输入ECHO可以通过输出知道ECHO当前的开关状态，但如何通过程序来获知呢？

　　我首先想到SETLOCAL/ENDLOCAL，但发现LOCAL似乎并不保存ECHO的状态。

　　然后四处搜索相关资料，希望找到有直接反映当前ECHO状态的内建方法。找不到，可能是我的搜索关键字太水了。　　

　　后来想到一个方案：
1、输入一次ECHO，把它的输出记录在一个变量A中
2、输入一次ECHO ON，然后再输入一次ECHO，把它的输出记录在变量B中
3、如果变量A==变量B，则当前是ECHO ON状态，否则为ECHO OFF状态
4、根据结果，把ECHO设回原来的状态

　　于是考虑如何把ECHO的输出保存为变量，首先考虑传统的FOR方式：

FOR /F "tokens=*" %%I IN ('ECHO') DO SET CUR_ECHO_STATE_DESC=%%I

@ECHO ON

@FOR /F "tokens=*" %%I IN ('ECHO') DO @SET ECHO_ON_STATE_DESC=%%I

@ECHO OFF

FOR /F "tokens=*" %%I IN ('ECHO') DO SET ECHO_OFF_STATE_DESC=%%I

　　发现不行。

　　在FOR的()里面执行的命令似乎运行在另一个上下文中，上述例子中ECHO始终为默认状态——开启。

　　于是稍改一下，得到下文：

FOR /F "tokens=*" %%I IN ('ECHO') DO SET CUR_ECHO_STATE_DESC=%%I

FOR /F "tokens=*" %%I IN ('ECHO ON ^& ECHO') DO SET ECHO_ON_STATE_DESC=%%I

FOR /F "tokens=*" %%I IN ('ECHO OFF ^& ECHO') DO SET ECHO_OFF_STATE_DESC=%%I

　　ECHO ON与ECHO OFF的输出都成功捕获到ECHO_ON_STATE_DESC和ECHO_OFF_STATE_DESC中去了。

　　但当前的ECHO状态，还未能捕获到。于是，重点攻关这个问题。

　　FOR中既然是另一个上下文，那通过FOR似乎是没办法获得当前的ECHO状态了。于是，我考虑用点别的。

　　重定向与管道。

　　一个最简单的尝试：

ECHO | SET /P "CUR_ECHO_STATE_DESC= "

　　不行的，原因是使用管道时，似乎也是运行在另一个上下文中，管道右侧设置的变量的值在语句结束时就不复存在了，通过下文可以验证这个观点：

(ECHO haha | (SET /P "MyVar= " && SET MyVar)) && SET MyVar

　　上文输出中，可以看到首个SET MyVar的输出为haha，但第二个SET MyVar则提示MyVar未定义。即证明管道创建了新的上下文。

　　那么管道也走不通了，我还剩下重定向：

ECHO > "%TEMP%\TmpEchoState.txt"

　　可行，再从文件倒进变量即可，但不得不用到临时文件。

　　期待更简单更直接的方法。

2008-1-6 22:09

(25013672)

everest79
金牌会员

一叶枝头，万树皆春

积分 2564
发帖 1127
注册 2006-12-25
状态离线

『第 2 楼』:

echo|find "关闭"&&echo echo off||echo echo on

2008-1-6 22:32

BatMan
初级用户

蝙蝠侠是写批处理的人

积分 54
发帖 24
注册 2008-1-4
状态离线

『第 3 楼』:

Quote:

Originally posted by everest79 at 2008-1-6 22:32:
echo|find "关闭"&&echo echo off||echo echo on

感谢回应，但，不可行。 :(

我在命令行下，执行这段语句，提示echo on，然后主动echo off，然后再执行这段语句，提示仍然是echo on。或许正如我之前的分析，这是因为管道运行在另一个上下文，那里是默认的echo on状态。:(

另一个问题是依赖于当前的语言设定，如果是英文codepage的话，find "关闭"就不能满足需求了。

2008-1-6 22:41

(25013672)

everest79
金牌会员

一叶枝头，万树皆春

积分 2564
发帖 1127
注册 2006-12-25
状态离线

『第 4 楼』:

管道可能会让echo工作在echo on模式下

2008-1-6 23:05

BatMan
初级用户

蝙蝠侠是写批处理的人

积分 54
发帖 24
注册 2008-1-4
状态离线

『第 5 楼』:

用整理好的临时文件法的函数顶一下，期望能看到不需要临时文件的解法……

:: Get current ECHO state

::

:: Usage：

::        IsEchoOn

::

:: ERRORLEVEL:

::         0 - Echo Close

::        1 - Echo On

::

:IsEchoOn

        @SETLOCAL ENABLEEXTENSIONS

        @ECHO>"%TEMP%\%~n0.tmp"

        @SET /P "ECHO_CUR_STATE_DESC=" < "%TEMP%\%~n0.tmp"

        @DEL /F /Q "%TEMP%\%~n0.tmp"

        @FOR /F "tokens=*" %%I IN ('ECHO ON ^& ECHO') DO @SET ECHO_ON_STATE_DESC=%%I

        @IF "%ECHO_CUR_STATE_DESC%" == "%ECHO_ON_STATE_DESC%" (

                @ENDLOCAL & @EXIT /B 1

        ) 

        @ENDLOCAL & @EXIT /B 0

@GOTO :EOF

2008-1-7 22:51

(25013672)

BatMan
初级用户

蝙蝠侠是写批处理的人

积分 54
发帖 24
注册 2008-1-4
状态离线

『第 6 楼』:

再顶一次，然后就让其随风而去...T-T

2008-1-10 21:45

(25013672)

请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。

可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题

论坛跳转: