中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 自制照片按日期分类 Bat

tyuang
新手上路

积分 4
发帖 1
注册 2008-6-19
状态离线

『楼主』: 自制照片按日期分类 Bat

拷贝下面代码到Bat文件存到照片目录双击即可。可以按照照片生成的日期分类照片。如果存在相同文件则会修改文件名。

@echo off
mode con lines=10 cols=42

echo ****************************************
echo *****    照片按日期分类    ********
echo ****************************************

echo 分类中，请稍等.............

set move_num=0
set nmove_num=0
set cmove_num=0
set filenum=0
set dirnum=0

for /F "delims=" %%i in ('dir /a-d /b *.jpg *.bmp *.gif *.jpeg *.avi *.thm *.wav') do (
call :md_copy "%%~ti"
call :move_photo "%%i" "%%~ti" "%%~ni" %%~xi
set /a filenum+=1)

echo 分类结束! 处理 %filenum% 文件 !! 新建 %dirnum% 目录 !!
echo          %move_num%  文件成功归类!!
echo          %nmove_num% 文件未归类!!
echo          %cmove_num% 文件重命名!!
pause>nul
goto :eof

:: *****************************************
:: ** MD dir of date and move the file
:: *****************************************
:md_copy
set dir_n=%1
set "dir_n=%dir_n:~1,10%"

if not exist %dir_n%\nul (md %dir_n% 1>nul 2>nul
set /a dirnum+=1)

goto :eof

:: *******************************************************
:: ** move the photo if file is already exist. change name
:: *******************************************************
:move_photo
set seq_num=0
set dir_n=%2
set "dir_n=%dir_n:~1,10%"
set file_name=%3
set "file_name=%file_name:~1,-1%"

if not exist %dir_n%\%1 (move %1 %dir_n%
set /a move_num+=1) else (set /a cmove_num+=1
call :cn_move %1 %dir_n% %3 %4)
goto :eof

:: *******************************************************
:: ** Change file name move file
:: *******************************************************
:cn_move
set /a seq_num+=1
set file_name=%3
set "file_name=%file_name:~1,-1%"

if not exist %2\"%file_name%%seq_num%%4" (move %1 %2\"%file_name%%seq_num%%4"
set /a move_num+=1) else call :cn_move %1 %2 "%file_name%" %4
goto :eof

2008-6-30 14:27

请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。

可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题

论坛跳转: