中国DOS联盟

@echo off



::::::::Base64 Decode {s11ss 2007-12-3}::::::::



setlocal enabledelayedexpansion



echo 请输入要转换的base64编码：

set/p es=



set "base64=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/="

set/a i=0

:base64-hex

set "o=!es:~%i%,1!"

if not "%o%" equ "" (call :b64-h1by1) else (goto :hex-hex2)

set/a i+=1

goto :base64-hex



:hex-hex2

if not defined hex goto :hex2-str

for /l %%a in (1,1,4) do (

	set/a "n=2*(%%a-1)"

	call set x=%%hex:~!n!,2%%

	set "ec%%a=0x!x!"

	if "!x!" equ "40" (set ec%%a=0& set f%%a=0)	

)

set hex=%hex:~8%

set/a c1=%ec1%"<<"2"|"%ec2%">>"4

set/a c2=%ec2%"<<"4"|"%ec3%">>"2

set/a c3=%ec3%"<<"6"|"%ec4%

for /l %%a in (1,1,3) do (

	set/a c%%a=!c%%a!"&"255

	call :dec-hex !c%%a!

)

if "%f3%" equ "0" set "c2="

if "%f4%" equ "0" set "c3="

for /l %%a in (1,1,3) do call set "hex2=%%hex2%%%%r!c%%a!%%"

goto :hex-hex2



:hex2-str

set vbs=%tmp%\tt.vbs

if exist %vbs% goto :runVBS

	:createVBS

set t=^>^>%vbs% echo 

%t%h=wscript.arguments(0)

%t%s=""

%t%for i=1 to len(h) step 2

%t%	a=cint("&h"^&mid(h,i,2))

%t%	if a^>160 then 

%t%		a=cint("&h"^&mid(h,i,4))

%t%		i=i+2

%t%	end if

%t%	s=s^&chr(a)	

%t%next  

%t%wscript.stdout.write(s)

	:runVBS

for /f %%a in ('cscript//nologo %vbs% %hex2%') do set "s=%%a"



:print

echo.

echo.%s%

pause

goto :eof























:b64-h1by1

for /l %%a in (0,1,64) do (

	if "!base64:~%%a,1!" equ "%o%" (

		call :dec-hex %%a

		set hex=!hex!!r%%a!

		goto :eof

	)

)

goto :eof



:dec-hex

set "r%1="

set "h=0123456789ABCDEF"

set/a q=%1

	:1c

	set/a r=%q%%%16

	set/a q=%q%/16

	call set r=%%h:~%r%,1%%

	set r%1=%r%!r%1!

if not %q% equ 0 goto :1c

if %1 leq 0xf set r%1=0!r%1!

@echo off



::::::::Base64 Decode {s11ss 2007-12-3}::::::::



setlocal enabledelayedexpansion



:GetEs

echo 请输入要转换的base64编码：

set/p es=



if "%es%"=="" goto GetEs

echo 转换中...



set "base64=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/="

set/a i=0

:base64-hex

set "o=!es:~%i%,1!"

if not "%o%" equ "" (call :b64-h1by1) else (goto :hex-hex2)

set/a i+=1

goto :base64-hex



:hex-hex2

if not defined hex goto :hex2-str

for /l %%a in (1,1,4) do (

        set/a "n=2*(%%a-1)"

        call set x=%%hex:~!n!,2%%

        set "ec%%a=0x!x!"

        if "!x!" equ "40" (set ec%%a=0& set f%%a=0)        

)

set hex=%hex:~8%

set/a c1=%ec1%"<<"2"|"%ec2%">>"4

set/a c2=%ec2%"<<"4"|"%ec3%">>"2

set/a c3=%ec3%"<<"6"|"%ec4%

for /l %%a in (1,1,3) do (

        set/a c%%a=!c%%a!"&"255

        call :dec-hex !c%%a!

)

if "%f3%" equ "0" set "c2="

if "%f4%" equ "0" set "c3="

for /l %%a in (1,1,3) do call set "hex2=%%hex2%%%%r!c%%a!%%"

goto :hex-hex2



:hex2-str

set vbs=%tmp%\tt.vbs

if exist %vbs% goto :runVBS

        :createVBS

set t=^>^>%vbs% echo 

%t%h=wscript.arguments(0)

%t%s=""

%t%for i=1 to len(h) step 2

%t%        a=cint("&h"^&mid(h,i,2))

%t%        if a^>160 then 

%t%                a=cint("&h"^&mid(h,i,4))

%t%                i=i+2

%t%        end if

%t%        s=s^&chr(a)        

%t%next  

%t%wscript.stdout.write(s)

        :runVBS

for /f "delims=" %%a in ('cscript//nologo %vbs% %hex2%') do set "s=%%a"



:print

echo.

echo 转换结果（不包括最外边的一对引号）：

echo."%s%"

pause

goto :eof























:b64-h1by1

for /l %%a in (0,1,64) do (

        if "!base64:~%%a,1!" equ "%o%" (

                call :dec-hex %%a

                set hex=!hex!!r%%a!

                goto :eof

        )

)

goto :eof



:dec-hex

set "r%1="

set "h=0123456789ABCDEF"

set/a q=%1

        :1c

        set/a r=%q%%%16

        set/a q=%q%/16

        call set r=%%h:~%r%,1%%

        set r%1=%r%!r%1!

if not %q% equ 0 goto :1c

if %1 leq 0xf set r%1=0!r%1!

Originally posted by vkill at 2007-12-3 08:59 PM:
我近来初以为是 debug ，vbs 还是很好的

Originally posted by s11ss at 2007-12-3 22:09:

vkill兄要不用debug来试试？我认为这个完全绝对百分之百不能用debug实现，呵呵

Originally posted by gamevyo at 2008-8-28 05:37 PM:
在执行到
:runVBS
for /f %%a in ('cscript//nologo %vbs% %hex2%') do set "s=%%a"
这里会出现 %a 的值为“输入错误”的情况
我对VBS一窍不通，谁能来帮忙看下是怎么回事？

Originally posted by gamevyo at 2008-8-29 07:28 PM:
奇怪了，刚试了下，又没问题了，不过解出来好像不对
我测试的是这段：
QUFmdHA6Ly9mcmVlMV93d3cuMTdoYXBweS5jbl8xMDM1NjY0Mjc3OjA5Q0NGMTFCM0NDNzZCQzIzRkM2NjI0Q0NCNTZEOEFBJ ...