中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客: 注册 | 登录 | 命令行 | 会员 | 搜索 | 上传 | 帮助 »

中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 免疫U盘病毒测试鸟

everest79
金牌会员

一叶枝头，万树皆春

积分 2564
发帖 1127
注册 2006-12-25
状态离线

『楼主』: 免疫U盘病毒测试鸟

利用软件安全策略禁止活动盘符可执行文件运行
免疫时先拔下U盘

@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION

SET REGPATH=HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths\{1979a749-e808-fe92-174a-

SET VAR=0123456789abcdefghijklmnopqrstuvwxyz

SET PART=%var:~12%

fsutil fsinfo drives >%temp%\part.dat

for /l %%i in (0,1,23) do find /i "!part:~%%i,1!" %temp%\part.dat 2>nul 1>nul||set disk=!disk!!part:~%%i,1!

for /l %%x in (0,1,2) do (

for /l %%i in (0,1,11) do (

set /a newrandom=!random!%%16

call set ranos=%%var:~!newrandom!,1%%!ranos!

)

REG ADD "%regpath%!ranos!}" /v SaferFlags /t REG_DWORD /d 0 /f >nul

REG ADD "%regpath%!ranos!}" /v ItemData /t REG_EXPAND_SZ /d !disk:~%%x,1!:\ /f >nul

REG ADD "%regpath%!ranos!}" /v LastModified /t REG_BINARY /d 0 /f >nul

REG ADD "%regpath%!ranos!}" /v Description /d !disk:~%%x,1! /f >nul

set ranos=

)

echo n|gpupdate /Force  >nul

pause

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET REGPATH=HKLM\SOFTWARE\Policies\Microsoft\Windows\Safer\CodeIdentifiers\0\Paths\{1979a749-e808-fe92-174a-
SET VAR=0123456789abcdefghijklmnopqrstuvwxyz
SET PART=%var:~12% //part=cdefghijklmnopqrstuvwxyz
fsutil fsinfo drives >%temp%\part.dat  //得到当前使用中的盘符
for /l %%i in (0,1,23) do find /i "!part:~%%i,1!" %temp%\part.dat 2>nul 1>nul||set disk=!disk!!part:~%%i,1!  //生成未使用盘符变量disk
for /l %%x in (0,1,2) do (  //提取未使用盘符中的前三个
for /l %%i in (0,1,11) do (
set /a newrandom=!random!%%16
call set ranos=%%var:~!newrandom!,1%%!ranos!  //生成12位16进制随机数
)
REG ADD "%regpath%!ranos!}" /v SaferFlags /t REG_DWORD /d 0 /f >nul  //写注册表
REG ADD "%regpath%!ranos!}" /v ItemData /t REG_EXPAND_SZ /d !disk:~%%x,1!:\ /f >nul
REG ADD "%regpath%!ranos!}" /v LastModified /t REG_BINARY /d 0 /f >nul
REG ADD "%regpath%!ranos!}" /v Description /d !disk:~%%x,1! /f >nul
set ranos=
)
echo n|gpupdate /Force  >nul  //刷新策略
pause

[ Last edited by everest79 on 2008-1-5 at 03:42 PM ]

此帖被 +8 点积分

点击查看详情