中国DOS联盟

@echo off
title 正在导出cmd帮助信息到cmdhelp目录内, 稍等...
md cmdhelp||(pause&exit)
chcp 437>nul&call :help E
graftabl 936>nul&call :help C
cd cmdhelp
set mark=───────────────────────────────────

::英文+中文>合并
for %%i in (*.E) do (
    echo.>>%%i &echo %mark%>>%%i
    copy %%~ni.E+%%~ni.C EC_%%~ni.txt>nul
    echo %mark%>>EC_%%~ni.txt &echo.>>EC_%%~ni.txt
)

::删除临时文件
del *.c;*.e
title 已完成.
pause
goto :eof

rem ----------------- subprocess -------------------
:help
for /f %%i in ('help^|findstr "^[A-Z]"') do help %%i>>cmdhelp\%%i.%1
goto :eof
rem -------------------- end ----------------------

@echo off&mode con lines=40 cols=100&title 变量扩充举例
::(这里是用%0为例,在for语句中可以用相应的变量代换0)

echo 用百分号0得到本批处理文件的带双引号的自身完整路径:
echo %0
echo.
echo 用 百分号~0
echo 打印结果: %~0
echo 用 百分号~f0
echo 打印结果: %~f0
echo 用 百分号~d0
echo 打印结果: %~d0
echo 用 百分号~p0
echo 打印结果: %~p0
echo 用 百分号~n0
echo 打印结果: %~n0
echo 用 百分号~x0
echo 打印结果: %~x0
echo 用 百分号~s0
echo 打印结果: %~s0
echo 用 百分号~a0
echo 打印结果: %~a0
echo 用 百分号~t0
echo 打印结果: %~t0
echo 用 百分号~z0
echo 打印结果: %~z0
echo 用 百分号~$PATH:0
echo 打印结果: %~$PATH:0
echo ----------------可以用组合修饰符来得到多重结果:
echo.
echo 用 百分号~dp0
echo 打印结果: %~dp0
echo 用 百分号~nx0
echo 打印结果: %~nx0
echo 用 百分号~fs0
echo 打印结果: %~fs0
echo 用 百分号~dp$PATH:0
echo 打印结果: %~dp$PATH:0
echo 用 百分号~ftza0
echo 打印结果: %~ftza0
pause>nul