中国DOS联盟

@set file="rn.bat" "Returnx.bat"
@echo off
for %%a in (%file%) do (call :setup %%~a)
exit
:setup
if not exist smalltool md smalltool
set "act="
for /f "delims= eol=" %%a in (%~nx0) do (
  if "%%a"=="::%* end" (goto :eof)
  if defined act echo,%%a>>"smalltool\%*"
  if "%%a"=="::%*" errcommand>"smalltool\%*" 2>nul&set act=act
)
::Returnx.bat
@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%a in ('dir back* /b') do (
  set /p now=<%%a
  echo, %%~na -- !now!
)
set /p cho="输入对应的还原批处理脚本名称（无需格式）:"
call %cho%.cmd
del %cho%.cmd
echo,执行完成
pause

::Returnx.bat end
::rn.bat
@echo off &setlocal enabledelayedexpansion
title 批量重命名工具
echo, &echo,  请输入将执行批量重命名操作的路径,如: F:\tempfolder\
echo, &echo,  注:  输入路径不需要加双引号,由批处理做统一处理.
echo,
:a
  set /p in="请输入操作路径:"
if not exist "%in%" (echo, -输入不正确&echo, &goto :a)
if not "%in:~-1%"=="\" (set in=%in%\)
:b
  set /p in2="请输入将要批量重命名的文件的格式（如: txt）:"
if not exist "%in%*.%in2%" (echo, 不存在该格式 &echo, &goto :b)
:
set bk=1
:sortback
if exist back* (set "inp=%~dp0" &set "inp2=cmd" &set "spc=back" &call :listname ::)
set inp=%in%
set inp2=%in2%

:
   echo,&echo, 1  批量把%inp% 目录下的 %inp2%文件按pak1~pakn 顺序重命名
   echo,&echo, 2  批量给文件后缀加s
   echo,
:
  :c
  set /p inp3="请选择操作模式:"
  echo,::%date% , %time% , %inp% 选择的操作 %inp3% >backz.cmd
  if "%inp3%"=="1" (goto :listname)
  if "%inp3%"=="2" (goto :adds) else (echo, -请正确输入 &goto :c)

:listname
if "%1"=="" (set spc=pak)
set /a n=1
ren "%inp%*.%inp2%" *.x_x
::上面这句ren是为了避免偶尔出现的细节上的冲突
for /f "tokens=*" %%a in ('dir "%inp%*.x_x" /b') do (
%1 echo,ren "%inp%%spc%!n!.%inp2%" "%%a">>backz.cmd
   ren "%inp%%%a" %spc%!n!.%inp2%
   set /a n+=1
)
%1 echo,ren "%inp%*.x_x" *.%inp2%>>backz.cmd
if "%1"=="::" (goto :eof)
goto :over
:
:adds
ren "%inp%*.%inp2%" *.%inp2%s
echo,ren "%inp%*.%inp2%s" *.%inp2%>>backz.cmd
goto :over
:
:over
echo,任务结束。Press any key to exit...
pause>nul &exit

::rn.bat end

@set file="rn.bat" "Returnx.bat" "说明.txt"
@echo off
for %%a in (%file%) do (call :setup %%~a)
exit
:setup
if not exist smalltool md smalltool
set "act="
for /f "delims= eol=" %%a in (%~nx0) do (
   if "%%a"=="::%* end" (goto :eof)
   if defined act echo,%%a>>"smalltool\%*"
   if "%%a"=="::%*" errcommand>"smalltool\%*" 2>nul&set act=act
)
::Returnx.bat
@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%a in ('dir *.x /b') do (
   set /p now=<%%a
   echo, %%~na -- !now!
)
set /p cho="输入对应操作的编码(最后一个为Z)以恢复: "
ren %cho%.x %cho%.cmd
call %cho%.cmd
del %cho%.cmd
echo,执行完成
pause

::Returnx.bat end
::rn.bat
@echo off &setlocal enabledelayedexpansion
title 批量重命名工具
echo, &echo,   请输入将执行批量重命名操作的路径,如: F:\tempfolder\
echo, &echo,   注:   输入路径不需要加双引号,由批处理做统一处理.
echo,
:a
   set /p in="请输入操作路径:"
if not exist "%in%" (echo, -输入不正确&echo, &goto :a)
if not "%in:~-1%"=="\" (set in=%in%\)
:b
   set /p in2="请输入将要批量重命名的文件的格式（如: txt）:"
if not exist "%in%*.%in2%" (echo, 不存在该格式 &echo, &goto :b)
:
set bk=1
:sortback
if exist back* (set "inp=%~dp0" &set "inp2=x" &set "spc=back" &call :listname ::)
set inp=%in%
set inp2=%in2%

:
echo,&echo,当前所在目录"%inp%"
echo,&echo,    输入特征前缀如: x 则把 %inp2% 文件按:
echo,&echo, x1.%inp2% , x2.%inp2% , x3.%inp2%....  顺序重命名
echo,
:
   :c
   set /p inp3="请输入特征前缀[一般为字母，不要输入符号]: "
   echo,: %date:~0,10% %time%  处理 %inp2%文件 特征符%inp3%>z.x

:listname
if "%1"=="" (set spc=%inp3%)
set /a n=1
ren "%inp%*.%inp2%" *.x_x
::上面这句ren是为了避免偶尔出现的细节上的冲突
for /f "tokens=*" %%a in ('dir "%inp%*.x_x" /b') do (
%1 echo,ren "%inp%%spc%!n!.%inp2%" "%%a">>z.x
ren "%inp%%%a" %spc%!n!.%inp2%
%1 echo, %spc%!n!.%inp2%
set /a n+=1
)
%1 echo,ren "%inp%*.x_x" *.%inp2%>>z.x
if "%1"=="::" (goto :eof)
goto :over

:over
echo,任务结束。Press any key to exit...
pause>nul &exit

::rn.bat end


::说明.txt

实现了可选择多个恢复的功能

    主代码执行生成 smalltool 文件夹   里面有 rn.bat 和 Returnx.bat

    执行 rn.bat 为重命名操作。 如果要恢复，可以打开Returnx.bat  

    它会列出每个对应的时间和当时选择的操作，这个时候自己根据信息选择
一个编号。

::说明.txt end