中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客: 注册 | 登录 | 命令行 | 会员 | 搜索 | 上传 | 帮助 »

中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » [已结]如何读取文本文件开头的若干行

yyying67
新手上路

积分 19
发帖 11
注册 2008-7-10
状态离线

『楼主』: [已结]如何读取文本文件开头的若干行

如何读取文本文件开头的若干行

[ Last edited by HAT on 2008-12-5 at 22:55 ]

2008-12-4 22:12

tireless
银牌会员

积分 2025
发帖 1122
注册 2007-9-5
状态离线

『第 2 楼』:

例如要取前 3 行，有以下方法：

1、碰到第 3 行的内容就停止：

@echo off

for /f "delims=" %%a in (a.txt) do (

  echo.%%a

  if "%%a"=="第 3 行的内容" goto out

)

:out

pause

2、每读取一行内容，变量 n 的值加 1，当 n=3，即已经读取了 3 行，就停止：

@echo off & setlocal EnableDelayedExpansion

for /f "delims=" %%a in (a.txt) do (

  echo.%%a

  set /a n+=1 & if !n!==3 goto out

)

:out

pause

如果要处理空行：

@echo off

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* a.txt') do (

  echo.%%b

  if %%a==3 goto out

)

:out

pause

[ Last edited by tireless on 2008-12-5 at 11:20 ]

2008-12-4 23:46

HAT
版主

积分 9023
发帖 5017
注册 2007-5-31
状态离线

『第 3 楼』:

差不多两年前，lxmxn 斑竹给出的代码：
http://www.cn-dos.net/forum/viewthread.php?tid=28639

2008-12-5 09:47

wangff
初级用户

积分 134
发帖 54
注册 2008-11-19
状态离线

『第 4 楼』:

请教tireless: 是否在双for中不能用goto提前跳出里边的for?
以下代码只执行一次循环

@echo off

for /r %%i in (*.txt) do (

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %%~si') do (

  echo.%%b

  if %%a==3 goto out

)

:out

pause

)

如果是怎改?

[ Last edited by wangff on 2008-12-5 at 13:16 ]

2008-12-5 13:13

tireless
银牌会员

积分 2025
发帖 1122
注册 2007-9-5
状态离线

『第 5 楼』: RE 4 楼

@echo off

for %%i in (*.txt) do CALL :3 "%%i"

PAUSE & EXIT /B

:3

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %~s1') do (

  echo.%%b

  if %%a==3 goto :EOF

)

此帖被 +1 点积分点击查看详情

2008-12-5 13:41

wangff
初级用户

积分 134
发帖 54
注册 2008-11-19
状态离线

『第 6 楼』:

谢谢tireless!
但还有问题:遇到两个大的txt(几兆)后按任意键就不再往下执行!

@echo off

for %%i in (*.txt) do CALL :3 "%%i"

exit/b

:3

echo.%1

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %~s1') do (

  echo.%%b

  if %%a==10 (

     pause

     goto :EOF

  )

)

不好意思,是我漏了exit/b

[ Last edited by wangff on 2008-12-5 at 14:20 ]

2008-12-5 14:13

yyying67
新手上路

积分 19
发帖 11
注册 2008-7-10
状态离线

『第 7 楼』:

谢谢各位!
努力学习中.

2008-12-5 22:37

请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。

可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题

论坛跳转: