中国DOS联盟

如何读取文本文件开头的若干行

Last edited by HAT on 2008-12-5 at 22:55 ]

例如要取前 3 行，有以下方法：

1、碰到第 3 行的内容就停止：

@echo off

for /f "delims=" %%a in (a.txt) do (

  echo.%%a

  if "%%a"=="第 3 行的内容" goto out

)

:out

pause

2、每读取一行内容，变量 n 的值加 1，当 n=3，即已经读取了 3 行，就停止：

@echo off & setlocal EnableDelayedExpansion

for /f "delims=" %%a in (a.txt) do (

  echo.%%a

  set /a n+=1 & if !n!==3 goto out

)

:out

pause

如果要处理空行：

@echo off

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* a.txt') do (

  echo.%%b

  if %%a==3 goto out

)

:out

pause

Last edited by tireless on 2008-12-5 at 11:20 ]

差不多两年前，lxmxn 斑竹给出的代码：
http://www.cn-dos.net/forum/viewthread.php?tid=28639

请教tireless: 是否在双for中不能用goto提前跳出里边的for?
以下代码只执行一次循环

@echo off

for /r %%i in (*.txt) do (



for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %%~si') do (

  echo.%%b

  if %%a==3 goto out

)



:out

pause

)

如果是怎改?

Last edited by wangff on 2008-12-5 at 13:16 ]

@echo off

for %%i in (*.txt) do CALL :3 "%%i"



PAUSE & EXIT /B



:3

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %~s1') do (

  echo.%%b

  if %%a==3 goto :EOF

)

谢谢tireless!
但还有问题:遇到两个大的txt(几兆)后按任意键就不再往下执行!

@echo off

for %%i in (*.txt) do CALL :3 "%%i"

exit/b



:3

echo.%1

for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %~s1') do (

  echo.%%b

  if %%a==10 (

     pause

     goto :EOF

  )

)

不好意思,是我漏了exit/b

Last edited by wangff on 2008-12-5 at 14:20 ]

谢谢各位!
努力学习中.