a.txt：
1jd
2sdfls
3sd
4kop
5df
6sd
我只想提取出3sd
该怎么做？
谢谢~
1jd
2sdfls
3sd
4kop
5df
6sd
我只想提取出3sd
该怎么做？
谢谢~
中国DOS联盟
联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » [求助]怎样提取文本中间的哪一行？
楼 主
[求助]怎样提取文本中间的哪一行？
发表于 2008-04-19 19:44 · 中国 山东 淄博 联通
第 2 楼
下次请把要求写清楚了：
发表于 2008-04-19 20:07 · 中国 湖南 株洲 电信
首先建议搜索。
1按行搜索（第三行）
2按字符搜索（字符为3）
1按行搜索（第三行）
@echo off
for /f "delims=: tokens=1*" %%i in ('findstr /n .* a.txt') do if %%i equ 3 set str=%%j
echo %str%
pause>nul 2按字符搜索（字符为3）
@echo off
for /f "delims=" %%i in ('findstr "3" a.txt') do set str=%%i
echo %str%
pause>nul批处理之家新域名：www.bathome.net
第 3 楼
回复2楼
发表于 2008-04-19 20:11 · 中国 山东 淄博 联通
那2个方法我也会，只是a.txt当中的内容是未知的，也怪我没说清楚，我想提取出a.txt中的第三行，第五行，第七行。。
第 4 楼
这也容易：
发表于 2008-04-19 20:32 · 中国 湖南 株洲 电信
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
set /a n+=1
for %%a in (3,5,7) do if !n! equ %%a set str=%%i&echo !str!
)
pause>nul [ Last edited by zw19750516 on 2008-4-19 at 08:42 PM ]
批处理之家新域名：www.bathome.net
第 5 楼
发表于 2008-04-19 20:41 · 中国 山东 淄博 联通
谢谢~~~ 一指点就明白了~~ 第一段代码，稍作修改下也可以~
@echo off&setlocal enabledelayedexpansion
for /f "delims=:" %%a in ('findstr /n .* a.txt') do set line=%%a
for /f "delims=" %%i in (a.txt) do (
set /a n+=1
for /l %%a in (3,2,%line%) do if !n! equ %%a set str=%%i&echo !str!
)
pause>nul
这样的话 不管有多少行，都会提取从3开始的奇数行了~~
@echo off&setlocal enabledelayedexpansion
for /f "delims=:" %%a in ('findstr /n .* a.txt') do set line=%%a
for /f "delims=" %%i in (a.txt) do (
set /a n+=1
for /l %%a in (3,2,%line%) do if !n! equ %%a set str=%%i&echo !str!
)
pause>nul
这样的话 不管有多少行，都会提取从3开始的奇数行了~~
第 6 楼
发表于 2008-04-19 21:54 · 中国 香港 腾讯云
sed -n "1,2d;$!N;P" a.txt
第 7 楼
发表于 2008-04-20 00:13 · 中国 湖北 武汉 电信
GNU sed
sed -n "3p;3~2p" a.txt
第 8 楼
发表于 2008-04-20 00:21 · 中国 湖北 武汉 电信
@echo off & SetLocal EnableDelayedExpansion
for /f "tokens=1* delims=:" %%a in ('findstr /n .* a.txt') do (
set /a a=%%a%%2
if %%a geq 3 if !a! equ 1 echo.%%b
)
第 9 楼
发表于 2008-04-20 03:06 · 中国 湖南 娄底 电信
从第3行开始取奇数行。
:
:
@echo off&setlocal enabledelayedexpansion
set n=3
for /f "delims=" %%a in ('findstr /n .* a.txt') do (
set str=%%a&set /a m+=1
set str=!str:*:=!
if !m! equ !n! (set /a n+=2&echo.!str!)
)
pause
致精致简！
第 10 楼
发表于 2008-04-20 03:38 · 中国 陕西 西安 电信
第 11 楼
发表于 2008-04-20 04:12 · 中国 湖南 娄底 电信
Originally posted by plp626 at 2008-4-20 03:38:
我来个一句话的：
@for /f "skip=2 delims=" %%a in (test.txt) do @if not defined plp (echo.%%a &set "plp=626") else set "plp="
巧妙！
致精致简！
论坛跳转: