中国DOS联盟

@echo off
for /f "tokens=1* delims=:" %%i in ('findstr/n ".*" b.txt^|sort/r') do echo.%%j
pause>nul

@echo off
net user 123 >nul 2>nul
if "%errorlevel%" neq "0" (
  net user 123 "123 &^" /add
)

@echo off
rem 输出a.txt中所有以abcd开头的行
for /f "delims=" %%a in ('findstr "^abcd" "a.txt"') do (
  echo %%a
)
rem 输出第一个以abcd开头的行
echo.
for /f "delims=" %%a in ('findstr "^abcd" "a.txt"') do (
  echo %%a
  goto :next
)
:next
rem 输出第二个以abcd开头的行
echo.
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('findstr "^abcd" "a.txt"') do (
  set /a row+=1
  if "!row!" equ "2" (
    echo %%a
    goto :eof
  )
)

@echo off
type nul>num.txt
for /l %%a in (0,1,999) do (
  if %%a lss 10 (
    >>num.txt echo 00%%a
  ) else if %%a lss 100 (
    >>num.txt echo 0%%a
  ) else (
    >>num.txt echo %%a
  )
)

@echo off
type nul>num.txt
set str=1000
:add
>>num.txt echo %str:~-3%
set /a str+=1
if %str% lss 2000 goto :add

@echo off
for %%a in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
  fsutil fsinfo drivetype %%a: | findstr /i "CD">nul && echo 光驱盘符：%%a
)

@echo off
for /f "tokens=2 delims==" %%a in ('wmic LogicalDisk where "DriveType='5'" get * /value ^| findstr /i "^DeviceID"') do echo 光驱盘符：%%a

@echo off
set code=abcdefghijklmnopqrstuvwxyz
cd.>temp.txt
:begin
set /a a=%random%%%26
call,set a=%%code:~%a%,1%%
findstr "%a%" temp.txt>nul&&goto begin||echo %a%>>temp.txt
set var=%var% %a%
set /a n+=1
if %n% lss 10 goto begin
echo 排序前为：%var:~1%
echo.
for /f "delims=" %%i in ('sort temp.txt') do call,set str=%%str%% %%i
echo 排序后为：%str:~1%
pause>nul&del temp.txt

@echo off&setlocal enabledelayedexpansion
set "var=+ - * /"
for /f "tokens=1-4 delims= " %%a in ("%var%") do call :lp %%a %%b %%c %%d
pause>nul&goto :eof
:lp
for /l %%i in (1,1,9) do (
    for /l %%j in (1,1,%%i) do (
        set /a a=%%i%1%%j
        if !a! lss 10 set a= !a!
        set str=!str! %%i%1%%j=!a!
        if %%i equ %%j echo !str!&set "str="
    )
)
if "%1" equ "/" goto :eof
shift
goto lp

@echo off&setlocal enabledelayedexpansion
set codes=a b c d e f g h i j k l m n o p q r s t u v w x y a
set code=%codes: =%
:begin
set /a a=%random%%%26,b=%random%%%10+1
set a=!code:~%a%,1!
echo %var%|findstr "%a%">nul&&goto begin
set var=%var%%a%
set /a n+=1
if %n% lss %b% goto begin
set n=0
echo 随机生成的字母组为：%var%
echo.
:lp
set a=%var:~,1%
set str=%str% %a%
set var=%var:~1%
if defined var goto lp
set str=%str:~1%
for %%a in (%codes%) do (
    call,set /a n+=1
    for %%i in (%str%) do (
        if "%%a" equ "%%i" set /a num+=!n!
    )
)
echo 字母组的数位和为：%num%
pause>nul

@echo off
set t=%time%
for /f "tokens=14-16 delims=:." %%i in ('ipconfig /all^|findstr /c:"IP Address"') do set str=%%i.%%j.%%k.
set str=%str:~1%&arp -d
for /l %%i in (1,1,50) do start /min ping /n 1 %str%%%i>nul
arp -a|findstr "dynamic"
echo %t%
echo %time%
pause>nul