中国DOS联盟

@goto code
::精简一下
:code
@echo off&chcp 936&cls
set /p txt=(拖进此窗口,开始阅读)
set /p speed=大约每分钟?字[直接回车500字/分钟]
if {%speed%}=={} set/a rate=112&goto start
set /a rate=56200/%speed% &goto start
goto code

:start
::下面两句不可颠倒
call :sleep
chcp 936&cls

call :f_timec "0"
mode con cols=60 lines=38&color 80

for /f "delims= eol=" %%i in ('findstr /n .* %txt%') do (
    set "str=%%i"
    call set "str=%%str:"= %%"
    call set "str=%%str:*:=%%"
    call :pickup
)
goto end

:pickup
if not defined str echo.&goto :eof
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "=%str:~0,1%"<nul
%tmp%\sleep %rate%
set "str=%str:~1%"
if defined str goto pickup
goto :eof

:end
call :f_timec "1"
echo 用时%ht%小时%mt%分钟%st%.%pt%秒
echo 按任意键over!&pause>nul&exit

rem ------- 子函数 --------
:f_timec
set "t=%time%"
if "%t:~0,1%"==" " (set/a t1=0) else set/a t1=%t:~0,1%
set/a t2=%t:~1,1%,t3=%t:~3,1%,t4=%t:~4,1%,t5=%t:~6,1%,t6=%t:~7,1%,t7=%t:~9,1%,t8=%t:~-1%
set/a ft=3600000*%t1%+360000*%t2%+60000*%t3%+6000*%t4%+1000*%t5%+100*%t6%+10*%t7%+%t8%
if %1=="0" (set bt=%ft%) else (set et=%ft%&call :f_timec_s)
goto :eof
:f_timec_s
if %et% lss %bt% set/a et=%bt%+8640000
set/a ct=%et%-%bt%
set/a ht=%ct%/360000
set/a mt=(%ct%-360000*%ht%)/6000
set/a st=(%ct%-360000*%ht%-6000*%mt%)/100
set/a pt=%ct%-360000*%ht%-6000*%mt%-100*%st%
goto :eof
:sleep
cd.>%tmp%\sleep.com
(echo Bj@jzh`0X-`/PPPPPPa(DE(DM(DO(Dh(Ls(Lu(LX(LeZRR]EEEUYRX2Dx=
echo 0DxFP,0Xx.t0P,=XtGsB4o@$?PIyU WwX0GwUY Wv;ovBX2Gv0ExGIuht6
echo T}{z~~@GwkBG@OEKcUt`~}@MqqBsy?seHB~_Phxr?@zAB`LrPEyoDt@Cj?
echo pky_jN@QEKpEt@ij?jySjN@REKpEt@jj?jyGjN@SEKkjtlGuNw?p@pjirz
echo LFvAURQ?OYLTQ@@?~QCoOL~RDU@?aU?@{QOq?@}IKuNWpe~FpeQFwH?Vkk
echo _GSqoCvH{OjeOSeIQRmA@KnEFB?p??mcjNne~B?M??QhetLBgBPHexh@e=
echo EsOgwTLbLK?sFU`?LDOD@@K@xO?SUudA?_FKJ@N?KD@?UA??O}HCQOQ??R
echo _OQOL?CLA?CEU?_FU?UAQ?UBD?LOC?ORO?UOL?UOD?OOI?UgL?LOR@YUO?
echo dsmSQswDOR[BQAQ?LUA?_L_oUNUScLOOuLOODUO?UOE@OwH?UOQ?DJTSDM
echo QTqrK@kcmSULkPcLOOuLOOFUO?hwDTqOsTdbnTQrrDsdFTlnBTm`lThKcT
echo @dmTkRQSoddTT~?K?OCOQp?o??Gds?wOw?PGAtaCHQvNntQv_w?A?it\EH
echo {zpQpKGk?Jbs?FqokOH{T?jPvP@IQBDFAN?OHROL?Kj??pd~aN?OHROd?G
echo Q??PGT~B??OC~?ipO?T?~U?p~cUo0x)>>%tmp%\sleep.com
%tmp%\sleep.com>%tmp%\sleep.exe&del %tmp%\sleep.com
goto :eof

:: TxtRead.cmd (文本阅读程序)
:: 原创: plp626@cn-dos.net 2008-1-15
:: 修改: qzwqzw@cn-dos.net 2008-1-28
:: 来源: http://www.cn-dos.net/forum/viewthread.php?tid=37072
:: 说明: 原代码为了功能牺牲了简洁，在此做了简化
@echo off
set docu=%~sf0
set speed=50
set color=80
set /p "docu=指定阅读文档(可直接将文件拖进此窗口，缺省为本程序代码): "
set /p "speed=指定阅读速度(0最快，数越大越慢，缺省50): "
set /p "color=指定阅读颜色(具体参考color/?，缺省80灰底黑字): "
color %color%

echo ----------------------------------------------------------------------
for /f "delims= eol=" %%i in ('findstr /n .* %docu%') do (
    set "str=%%i"
    call set "str=%%str:"=＂%%"
    call set "str=%%str:*:=%%"
    call :pickup
)
echo ----------------------------------------------------------------------
pause>nul&exit /b

:pickup
if not defined str echo.&goto :eof
if "%str:~0,1%"=="=" set "str=＝%str:~1%"
set /p "=%str:~0,1%"<nul
for /l %%i in (1,1,%speed%00) do set _tmp=%%i
set "str=%str:~1%"
goto pickup

:: TxtRead.cmd (文本阅读程序)
:: 原创: plp626@cn-dos.net 2008-1-15
:: 修改: V2 - qzwqzw@cn-dos.net 2008-1-28
:: 来源: http://www.cn-dos.net/forum/viewthread.php?tid=37072
:: 说明: 原代码为了功能牺牲了简洁，在此做了简化
:: 更新: 增加了鼠标左键暂停和右键继续功能
::       增加逐行阅读模式
::       增加阅读宽度指定
@echo off & setlocal
if not "%title%"=="" shift /1 & goto :Read
set title=批处理文本阅读程序(单击鼠标左键暂停，右键继续)
reg add HKCU\Console\%title% /v QuickEdit /t reg_dword /d 1 /f>nul
set docu=%~sf0
set unit=0
set speed=10
set color=80
set width=120
set /p "docu=指定阅读文档(可直接将文件拖进此窗口，缺省为本程序代码): "
set /p "speed=指定阅读速度(0最快，指定数字越大越慢，缺省%speed%): "
set /p "color=指定阅读颜色(颜色值参考color/?，缺省为%color%-灰底黑字): "
set /p "unit=指定阅读模式(逐行阅读为0，逐字阅读为1, 缺省为%unit%-逐行): "
set /p "width=指定阅读宽度(最小为15，缺省为%width%): "
if "%unit%"=="1" (set ReadMode=CharMode) else set ReadMode=LineMode
start /max "%title%" %~sf0
goto :eof

:Read
mode con cols=%width%
color %color%
for /f "delims= eol=" %%i in ('findstr /n .* %docu%') do (
    set "buffer=%%i"
    call set "buffer=%%buffer:*:=%%"
    call :%ReadMode%
)
pause>nul&exit

:LineMode
setlocal EnableDelayedExpansion
echo.!buffer!
endlocal
for /l %%i in (1,1,%speed%0000) do set _tmp=%%i
goto :eof

:CharMode
call set "buffer=%%buffer:"=＂%%"
:CharLoop
if not defined buffer echo.&goto :eof
if "%buffer:~0,1%"=="=" set "buffer=＝%buffer:~1%"
set /p "=%buffer:~0,1%"<nul
for /l %%i in (1,1,%speed%000) do set _tmp=%%i
set "buffer=%buffer:~1%"
goto :CharLoop

:: TextRead.cmd (文本阅读程序)
:: 原创: plp626@cn-dos.net 2008-1-15
:: 来源: http://www.cn-dos.net/forum/viewthread.php?tid=37072
:: 说明: 原代码为了功能牺牲了简洁，在此做了简化
:: 更新:
::  V2.6 - qzwqzw - 2008-1-28
::      修正含空格路径问题
::  V2.5 - qzwqzw - 2008-1-28
::      修改配置参数指定方式
::      增加阅读高度指定
::      修改Read会话中的标题显示方式
::      调整程序初始化参数
::      修正2.0～2.1的空行显示问题
::  V2.1 - qzwqzw - 2008-1-28
::      修正注册表项未完整删除的问题
::  V2.0 - qzwqzw - 2008-1-28
::      增加了鼠标左键暂停和右键继续功能
::      增加逐行阅读模式
::      增加阅读宽度指定
::  v1.5 - qzwqzw - 2008-1-28
::      精简代码
::      修正空行的输出问题
::

@echo off & setlocal
if not "%prog%"=="" shift /1 & goto :Read
set prog=批处理文本阅读程序
set docu="%~0"
set mode=1
set speed=5
set color=80
set width=128
set height=44

:Config
cls
echo.
echo 当前配置:
echo    阅读文档: %docu%
echo    速度:%speed%   颜色:%color%    模式:%mode%  窗口大小:%width% X %height%
echo.
echo 配置说明：
echo    文档指定: 输入文件路径(可直接将文件拖进此窗口)
echo    速度设定: speed=速度值(0最快，指定数字越大越慢)
echo    颜色设定: color=颜色值(参考color/?)
echo    模式设定: mode=模式值(逐行阅读为0，逐字阅读为1):
echo    宽度指定: width=宽度值(最小为15):
echo    宽度指定: height=高度值(最小为1):
echo.
set config=
set /p "config=请输入配置命令（直接回车取当前配置）: "
if not defined config goto :Run
set "config=%config:"=%"
if exist "%config%" set docu="%config%"
set %config%
goto :Config

:Run
if "%mode%"=="1" (set mode=CharMode) else set mode=LineMode
reg add HKCU\Console\%prog% /v QuickEdit /t reg_dword /d 1 /f>nul
start /max "%prog%" %0
reg delete HKCU\Console\%prog% /f>nul
goto :eof

:Read
title 正在阅读 %docu%... [单击鼠标左键暂停，右键继续] - %prog%
mode con cols=%width% lines=%height%
color %color%
for /f "delims= eol=" %%i in ('findstr /n .* %docu%') do (
    set "buffer=%%i"
    call set "buffer=%%buffer:*:=%%"
    call :%mode%
)
title 完成阅读 %docu% ! [按任意键键结束] - %prog%
pause>nul&exit

:LineMode
setlocal EnableDelayedExpansion
echo.!buffer!
endlocal
for /l %%i in (1,1,%speed%0000) do set _tmp=%%i
goto :eof

:CharMode
if defined buffer call set "buffer=%%buffer:"=＂%%"
:CharLoop
if not defined buffer echo.&goto :eof
if "%buffer:~0,1%"=="=" set "buffer=＝%buffer:~1%"
set /p "=%buffer:~0,1%"<nul
for /l %%i in (1,1,%speed%000) do set _tmp=%%i
set "buffer=%buffer:~1%"
goto :CharLoop