中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 自动修改IP、网关、DNS的批命令【原创】

zhqw
新手上路

积分 18
发帖 6
注册 2006-3-29
状态离线

『楼主』: 自动修改IP、网关、DNS的批命令【原创】

把下面内容保存为IP.BAT或IP.CMD

@echo off

rem 把IP地址和gateway(网关)改成常用的值

set IP=192.168.3.148
set mask=255.255.255.0
set gateway=192.168.3.254
set DNS1=202.96.64.68
set DNS2=202.96.75.68
set Interface=本地连接

cls
echo.
echo 当前网络连接属性如下：
ipconfig /all
echo.
pause

rem ============== 手动选择设置开始 ==============
:MANUAL
cls
echo.
echo.
echo 请选择网络连接的编号，回车默认选“1. 本地连接”
echo.
echo    1. 本地连接
echo    2. 本地连接２
echo    3. 本地连接３
echo    4. 本地连接４
echo    5. 本地连接５
echo.
set KEY=1
set /p KEY=Interface:
if %KEY% == 1 set Interface=本地连接
if %KEY% == 2 set Interface=本地连接 2
if %KEY% == 3 set Interface=本地连接 3
if %KEY% == 4 set Interface=本地连接 4
if %KEY% == 5 set Interface=本地连接 5

echo.
echo 默认IP地址为 %IP% ，请输入新IP地址，按回车键设为默认值
echo.
set /p IP=IP:
echo.
echo 默认子网掩码地址为 %mask% ，请输入新Mask，按回车键设为默认值
echo.
set /p mask=Mask:
echo.
echo 默认网关地址为 %gateway% ，请输入新Gateway，按回车键设为默认值
echo.
set /p gateway=Gateway:
ECHO.
echo 默认主DNS地址为 %DNS1% ，请输入新主DNS，按回车键设为默认值
echo.
set /p DNS1=DNS1:
echo.
echo 默认备用DNS地址为 %DNS2% ，请输入新备用DNS，按回车键设为默认值
echo.
set /p DNS2=DNS2:

cls
echo.
echo 你对 “%Interface%” 设置如下：
echo.
ECHO    IP地址:    %IP%
ECHO    Mask:       %mask%
ECHO    Gateway地址: %gateway%
ECHO    主DNS地址: %DNS1%
ECHO    备用DNS地址: %DNS2%
echo.
echo.
set KEY=EXIT
echo 启用上面设置请按“1”，重新设置请按“2”，退出请按任意键
echo.
set /p KEY=Choice:
if %KEY% == 1 goto DO
if %KEY% == 2 goto MANUAL
GOTO END
rem ============== 手动选择设置结束 ==============

:DO
echo.
echo 正在更改IP . . .
echo.
netsh interface ip set address name="%Interface%" source=static addr=%IP% mask=%mask%
echo IP地址及子网掩码设置完成！
echo.
netsh interface ip set address name="%Interface%" gateway=%gateway% gwmetric=1
echo 网关地址设置完成！
echo.
netsh interface ip set dns name="%Interface%" source=static addr=%DNS1%
echo 主DNS地址设置完成！
echo.
netsh interface ip add dns name="%Interface%" addr=%DNS2% index=2
echo 第二DNS地址设置完成！

:END
pause && exit

[ Last edited by zhqw on 2007-11-6 at 11:28 AM ]

2007-11-6 11:23

hlowd
初级用户

积分 65
发帖 29
注册 2007-11-3
状态离线

『第 2 楼』: 支持原创

不错支持原创.代码清晰,比较实用!

2007-11-8 16:18

30082400
新手上路

积分 2
发帖 1
注册 2007-11-8
状态离线

『第 3 楼』:

新来的，看不懂呀，学习学习一下

2007-11-8 17:02

请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。

可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题

论坛跳转: