 『楼 主』:
[分享]绿色OFFICE通用安装卸载设置程序
最近研究绿色软件，很有成效，制作出了PROE，UG，OFFICE全系列 PS AUTOCAD等大型绿色软件，可以参考ONEGREEN.NET，我发布的绿色软件全部采用批处理制作安装卸载和设置，还得感谢在CN-DOS学习期间各位前辈从而使用学习的技术能应用到实际工作中。
一.通用安装程序使用说明.
这个程序适合绿色版本OFFICE97-2007版本的安装设置，自动识别OFFICE版本和组件，相当智能化，结合批处理EXE打包工具，基本看不出是批处理编写的程序；你可以使用本安装程序和设置程序来制作自己的单组件或是EXCEL\PPT\WORD\ACCESS四合一OFFICE绿色版。
一。绿色OFFICE通用安装程序和使用说明。
使用说明：
1.安装程序自动检测安装环境是否匹配并给出相应提示，主要检测环境是：是否是管理员，无管理员权限则不允许安装；检测是否缺少必要的安装工具和配置文件；检测是否把安装设置程序放到了正确的位置，一般为OFFICEX同名的目录；根据MSO.DLL文件或OPA文件自动检测OFFICE程序版本；检测是否是2007-08-08，不是该时间则禁止安装，这个时间限制主要是为了纪念奥运会1年倒记时的，所以安装前必须把系统时间调整到2007年8月8号。
2.支持多语言系统安装,安装程序自动检测系统语言环境并自动转换安装程序本身和注册表文件,因此不管是繁体系统还是简体系统或是其他系统,都可以使用本工具进行安装而不会出现乱码的情况.
3.支持注册表备份和恢复.自动检测是否进行过注册表备份并提示是否继续安装,建议新安装前进行备份以便与OFFICE其他版本冲突,备份时根据用户GTOOLS下的REGBAK.LST的内容进行备份,用户可以自行修改,决定那些需要备份那些不需要备份,格式为保存的文件名和项使用=连接,如CLSID=HKEY_CLASSES_ROOT\CLSID,备份文件存放到GTOOLS\REGBAK下面.
4.支持注册表自动导入并自动转换路径.制作绿色软件离不开注册表,大多数绿色软件都需要导入注册表才能使用.本程序支持自动导入注册表并根据安装路径自动转化注册表对应路径,从而使OFFICE能安装到任何路径.但是这里需要注意以下几点,一是注册表文件必须命名为GREEN.SVR并保存为GTOOLS下,如果必要,还可以存在一个附带的注册表,但必须命名为REGME.SVR;二是安装程序是根据安装目录来自动替换注册表对应路径的,所以绿色安装路径最好不要使用中文字体或是带空格的路径;三是需要在GREEN.SVR第四行指明原安装路径,格式必须是:";SETUPPATH;安装路径",如:";SETUPPATH;D:\\OFFICE2007",注意没有引号
5.支持自动解压文件到指定路径.安装程序安装过程中自动检测GTOOLS下是否存在WinSxS.exe(OFFICE2007专用)\HELP.EXE\FONTS.EXE\PYDS.EXE\MSTSSC.EXE(OFFICE2003繁简转换专用)\OTHER.EXE等WINRAR自解压文件并自动释放,有关WINRAR自解压格式的制作参考WINRAR帮助或本人以前发布的有关WINRAR教程.
6.支持全自动注册DLL和OCX控件.安装程序自动检测是否在GTOOLS目力下存在控件配置文件REGME.LST,如果存在在根据该配置文件指定的路径注册控件,如果不存在该配置文件则检测当前目录和所有子目录的DLL\OCX控件并自动注册.需要说明几点的是:一是最好使用配置文件REGME.LST来指定控件路径，这样可以加快安装速度;二是如果使用配置REGME.LST,指定的控件路径必须是相对路径,而且必须相对于主目录路径;三是主目录如果不存在PLUGINS文件,用户可以创建改文件夹,并把用户自己需要注册的控件放到该目录，安装程序会自动注册里面的所有控件.
7.自动检测OFFICE版本并创建快捷方式.安装程序根据MSO和OPA文件的名称来判断OFFICE文件版本,所以不要更改这些文件的名称;安装程序自动检测安装的组见并创建快捷方式,但目前仅支持EXCEL WORD PPT,ACCESS几个组件,请不要更改其可执行文件名称;安装程序会读GREEN.SVR第三行的内容并把其名称做为创建快捷方式的名称,因为用户可以自己修改改名称以便个性化程序名称,但格式必须是:";GREENNAME;快捷方式名称",如";GREENNAME;完美精简版",注意没有引号
8.自动检测是否存在OFFICE设置工具并在安装程序结束后给出提示.
程序代码:
@ECHO OFF
CLS
REM 本程序经过多层加密,如果你能看到源代码,恭喜你;但因编写本程序花费了作者不少心血,所以希望只供做学习研究之用,不得用于任何商业用途,否则本人将追加法律责任
REM 程序说明:本程序是OFFICE通用安装程序,适合OFFICE97-2007程序安装,自动检测OFFICE版本并根据安装的组件自动建立对应的快捷方式等一系列操作,编写这个程序经历了至少10余次的修改和完善,现已相当完美了;本程序只能把系统时间调整到2007-08-08才能安装.
REM 参数说明1:QHID安装时是否隐藏界面,默认为YES表示隐藏;QSTART安装后是否打开程序,默认NO不打开(这个变量已被VBS提示代替);QREADME是否显示版权信息,默认NO不显示.这三个变量主用于批量安装.
REM 参数说明2:QTHINSTALL是否采用虚拟方式安装,默认NO表示在本机安装,YES则表示虚拟环境安装(不向注册表和系统写文件,所以不需要备分,建立快捷方式等操作)
VER|FIND "4.1"
IF ERRORLEVEL 1 GOTO:WINXP
IF ERRORLEVEL 0 GOTO:WIN9X
:WINXP
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /V "CheckedValue" /T "REG_DWORD" /D "0" /F>NUL
SET PATH=%CD%;%CD%\GTOOLS\;%CD%\OFFICE\STARTUP;%PATH%
TITLE OFFICE通用绿化安装工具V2
mode con cols=20 lines=1
COLOR 02
CMDOW @ /DIS
SET QHID=YES
REM SET QSTART=NO
REM SET QREADME=NO
REM SET QTHINSTALL=YES
IF NOT EXIST "%TEMP%" MD "%TEMP%"
IF /I "%QHID%"=="YES" (SET TIMEOUT=1) ELSE (SET TIMEOUT=5)
IF /I "%QHID%"=="YES" (CMDOW @ /HID)
FOR /F "TOKENS=1,2 DELIMS=: " %%I IN ('CHCP') DO SET LAN=%%J
IF "%LAN%" NEQ "950" GOTO :CHS
IF "%JUT%"=="1" GOTO CHS
:CHT
SET JUT=1
IF NOT EXIST ".\GTOOLS\CT.exe" SET ERR=缺少代码转换工具&&GOTO:ERROR
TYPE %0>"%TEMP%\GSETUP.BAT"
START /WAIT CT.EXE /B /S "%TEMP%\GSETUP.BAT" /D "%TEMP%\GSETUPCHT.BAT"
START /B/WAIT "" "%TEMP%\GSETUPCHT.BAT"
IF EXIST "%TEMP%\GSETUP.BAT" DEL /F/Q "%TEMP%\GSETUP.BAT"
IF EXIST "%TEMP%\GSETUPCHT.BAT" DEL /F/Q "%TEMP%\GSETUPCHT.BAT"
EXIT
:CHS
CLS
mode con cols=70 lines=20
ECHO.
ECHO ╔──────────────────────────────╗
ECHO │ │
ECHO │ OFFICE通用绿化安装程序 │
ECHO │ 本程序由鸿越软件小布点编写制作 │
ECHO │ 本程序用于快速绿化安装和维护各版本OFFICE │
ECHO │ 本程序可以自由复制,使用和发布,版权归作者本人所有 │
ECHO │ QQ:9399100 QQ群号:29946542 E-MAIL:xiaobudian528@sina.com │
ECHO │ │
ECHO ╚──────────────────────────2007─㊣╝
ECHO.
PING 127.0.0.1 -n %TIMEOUT% >NUL
FOR /F "TOKENS=1-3 DELIMS=/- " %%I IN ('DATE /T') DO (SET DY=%%I&&SET DM=%%J&&SET DD=%%K)
IF "%DY%-%DM%-%DD%" NEQ "2007-08-08" SET ERR=你所使用的软件已经过期,请联系鸿越软件QQ:9399100 TEL:076921033442&&GOTO:ERROR
net user "%username%"|FIND /I "Administrators"
IF "%ERRORLEVEL%"=="1" SET ERR=你没有权限安装和运行本程序,请联系你的管理员&&GOTO:ERROR
IF NOT EXIST OFFICE SET ERR=本工具只能放于与OFFICE同名的目录&&GOTO:ERROR
IF NOT EXIST GTOOLS\GREEN.SVR SET ERR=GTOOLS下缺少注册表文件&&GOTO:ERROR
IF NOT EXIST ".\GTOOLS\BS.exe" SET ERR=缺少字符替换工具&&GOTO:ERROR
IF NOT EXIST ".\GTOOLS\SC.exe" SET ERR=缺少快捷方式创建工具&&GOTO:ERROR
IF /I "%QREADME%" NEQ "NO" IF EXIST ".\README.htm" (START /WAIT "" ".\README.htm")
ECHO SET CPATH=%CD%>"%TEMP%\CPATH.BAT"&&BS "%TEMP%\CPATH.BAT" \ \\ >NUL&CLS
CALL "%TEMP%\CPATH.BAT"
DEL /Q/F "%TEMP%\CPATH.BAT">NUL
IF /I "%QHID%" NEQ "YES" (CMDOW @ /MIN)
CLS
REM 1.根据QTHINSTALL设置决定是否备份文件:为YES时不备份
IF /I "%QTHINSTALL%"=="YES" GOTO:GOON
SET REGBAKDIR=REGBAK
IF "%LAN%"=="950" SET REGBAKDIR=REGBAKF
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("你已安装过或是直接拷贝了该软件,要保留注册表REGBAK备份并继续吗?" + vbCrLf + vbCrLf + "注意:如果是前者建议保留备份或是运行UINSTALL卸掉后再运行本程序"+ vbCrLf +"如果是后者建议直接删除GTOOLS\REGBAK整个目录后再运行本程序,切记!", vbExclamation+vbYesNo+vbDefaultButton1, "鸿越软件温馨提示您!")
>>"%TEMP%\Temp.vbs" Echo IF intAnswer = vbYes THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "GOON"
>>"%TEMP%\Temp.vbs" Echo ELSEIF intAnswer = vbNo THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "FEXIT"
>>"%TEMP%\Temp.vbs" Echo END If
IF EXIST ".\GTOOLS\%REGBAKDIR%\*.SVR" (For /f "delims=" %%I In ('"cscript //nologo "%TEMP%\Temp.vbs""') do (GOTO:%%I))
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("安装前是否要备份注册表?建议已安装了OFFICE其他版本或组件的备份以便恢复!", vbExclamation+vbYesNo+vbDefaultButton1, "鸿越软件温馨提示您!")
>>"%TEMP%\Temp.vbs" Echo IF intAnswer = vbYes THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "REGBAK"
>>"%TEMP%\Temp.vbs" Echo ELSEIF intAnswer = vbNo THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "GOON"
>>"%TEMP%\Temp.vbs" Echo END If
For /f "delims=" %%I In ('"cscript //nologo "%TEMP%\Temp.vbs""') do (GOTO:%%I)
:REGBAK
IF NOT EXIST ".\GTOOLS\REGBAK.LST" SET ERR=缺少注册表备份列表文件GTOOLS\REGBAK.LST&&GOTO:ERROR
IF NOT EXIST ".\GTOOLS\%REGBAKDIR%" MD ".\GTOOLS\%REGBAKDIR%"
IF NOT EXIST ".\GTOOLS\%REGBAKDIR%\*.SVR" (
FOR /F "EOL=; TOKENS=1-2 DELIMS==" %%X IN (.\GTOOLS\REGBAK.LST) DO (
REG EXPORT "%%Y" ".\GTOOLS\%REGBAKDIR%\%%X.SVR" /nt4>NUL&CLS))
)
:GOON
CLS
REM 2.注册程序和控件如要根据REGME.LST注册必须进入该目录(这里加密了注册表以及注册表文件)
TYPE GTOOLS\GREEN.SVR|FINDSTR /I/V "%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a">"%TEMP%\TGREEN.SVR"
IF "%LAN%"=="950" START /WAIT CT.EXE /B /S "%TEMP%\TGREEN.SVR" /D "%TEMP%\TGREEN.SVR"
IF EXIST "%TEMP%\TGREEN.SVR" (FOR /F "TOKENS=2 DELIMS=;" %%I IN ('FINDSTR /I "SETUPPATH" "%TEMP%\TGREEN.SVR"') DO SET SETUPPATH=%%I)
BS "%TEMP%\TGREEN.SVR" "%SETUPPATH%" "%CPATH%" /I >NUL&CLS
BS "%TEMP%\TGREEN.SVR" "C:\\WINDOWS\\FONTS" "%WINDIR%\\FONTS" /I >NUL&CLS
REGEDIT /S "%TEMP%\TGREEN.SVR" >NUL
IF EXIST ".\GTOOLS\REGME.SVR" REGEDIT /S ".\GTOOLS\REGME.SVR" >NUL
IF EXIST ".\GTOOLS\WinSxS.exe" START /WAIT "" ".\GTOOLS\WinSxS.exe"
IF EXIST ".\GTOOLS\HELP.EXE" START /WAIT "" ".\GTOOLS\HELP.EXE"
IF EXIST ".\GTOOLS\FONTS.EXE" START /WAIT "" ".\GTOOLS\FONTS.EXE"
IF EXIST ".\GTOOLS\PYDS.EXE" START /WAIT "" ".\GTOOLS\PYDS.EXE"
IF EXIST ".\GTOOLS\MSTSSC.EXE" START /WAIT "" ".\GTOOLS\MSTSSC.EXE"
IF EXIST ".\GTOOLS\OTHER.EXE" START /WAIT "" ".\GTOOLS\OTHER.EXE.EXE"
REM --------------------------------------------------------------------------------------------------------------
IF EXIST OFFTOOLS\H2Viewer (FOR %%I IN (.\OFFTOOLS\H2Viewer\hxds.dll .\OFFTOOLS\H2Viewer\hxvz.dll .\OFFTOOLS\H2Viewer\ITIRCL55.DLL .\OFFTOOLS\H2Viewer\msitss55.dll) DO REGSVR32 /S "%%I")
IF EXIST ".\GTOOLS\REGME.LST" (
FOR /F "EOL=;DELIMS=" %%I IN (.\GTOOLS\REGME.LST) DO REGSVR32 /S "%%I"
IF EXIST PLUGINS (FOR /F "DELIMS=" %%I IN ('DIR /S/B PLUGINS\*.DLL PLUGINS\*.OCX') DO REGSVR32 /S "%%I")
GOTO:CSC
)
FOR /F "DELIMS=" %%I IN ('DIR /S/B *.DLL *.OCX') DO REGSVR32 /S "%%I"
REM --------------------------------------------------------------------------------------------------------------
CLS
:CSC
REM 3.建立快捷方式和根据语言覆盖文件(需同WINRAR,另外根据文件来检测OFFICE版并根据GREEN第三行文字来说明绿色OFFICE的名称,如;GREENNAME:完美精简版)
IF /I "%QTHINSTALL%"=="YES" GOTO:END
IF EXIST "%TEMP%\TGREEN.SVR" (FOR /F "TOKENS=2 DELIMS=;" %%I IN ('FINDSTR /I "GREENNAME" "%TEMP%\TGREEN.SVR"') DO SET GREENNAME=%%I)
IF EXIST ".\OFFICE\MSO97.DLL" SET OFFV=97%GREENNAME%
IF EXIST ".\OFFICE\MSO9.DLL" SET OFFV=2000%GREENNAME%
IF EXIST ".\OFFICE\OPA11.BAK" SET OFFV=2003%GREENNAME%
IF EXIST ".\OFFICE\OPA12.BAK" SET OFFV=2007%GREENNAME%
IF "%LAN%"=="936" (SET DESKTOP=桌面&& SET PROGRAM=「开始」菜单\程序\【HYSOFT】\OFFICE%OFFV%&&GOTO:SC)
IF "%LAN%"=="950" (SET DESKTOP=桌面&& SET PROGRAM=「开始」功能表\程式集\【HYSOFT】\OFFICE%OFFV%) ELSE (SET DESKTOP=DESKTOP&& SET PROGRAM=Start Menu\Programs\【HYSOFT】\OFFICE%OFFV%)
:SC
IF NOT EXIST "%ALLUSERSPROFILE%\%PROGRAM%" MD "%ALLUSERSPROFILE%\%PROGRAM%"
IF EXIST ".\OFFICE\WINWORD.EXE" SC /F:"%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\WORD%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\WINWORD.EXE" /W:"%CD%\OFFICE">NUL
IF EXIST ".\OFFICE\EXCEL.EXE" SC /F:"%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\EXCEL%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\EXCEL.EXE" /W:"%CD%\OFFICE">NUL
IF EXIST ".\OFFICE\POWERPNT.EXE" SC /F:"%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\PPT%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\POWERPNT.EXE" /W:"%CD%\OFFICE">NUL
IF EXIST ".\OFFICE\MSACCESS.EXE" SC /F:"%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\ACCESS%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\MSACCESS.EXE" /W:"%CD%\OFFICE">NUL
IF EXIST ".\OFFICE\WINWORD.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\WORD%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\WINWORD.EXE">NUL
IF EXIST ".\OFFICE\EXCEL.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\EXCEL%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\EXCEL.EXE">NUL
IF EXIST ".\OFFICE\POWERPNT.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\PPT%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\POWERPNT.EXE">NUL
IF EXIST ".\OFFICE\MSACCESS.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\ACCESS%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\MSACCESS.EXE">NUL
IF NOT EXIST "%ALLUSERSPROFILE%\%PROGRAM%\TOOLS" MD "%ALLUSERSPROFILE%\%PROGRAM%\TOOLS"
IF EXIST ".\OFFICE\SNAPVIEW.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\ACCESS SNP文件查看工具.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\SNAPVIEW.EXE">NUL
IF EXIST ".\OFFICE\PPTVIEW.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\演示文件查看工具.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\PPTVIEW.EXE">NUL
IF EXIST ".\OFFICE\SELFCERT.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\数字证书创建工具.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\SELFCERT.EXE">NUL
IF EXIST ".\OFFICESET.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\鸿越OFFICE通用设置工具.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICESET.EXE" /W:"%CD%">NUL
IF EXIST ".\OFFTOOLS\PPT2EXE\PPT2EXE.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\鸿越幻PPT打包制作工具.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\PPT2EXE\PPT2EXE.EXE" /W:"%CD%\OFFTOOLS\PPT2EXE">NUL
IF EXIST ".\OFFTOOLS\DOCRTOOLS\DOCRTOOLS.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\鸿越文档修复工具包.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\DOCRTOOLS\DOCRTOOLS.EXE" /W:"%CD%\OFFTOOLS\DOCRTOOLS">NUL
IF EXIST ".\OFFTOOLS\PASSWARE\PASSWARE.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\鸿越密码恢复工具包.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\PASSWARE\PASSWARE.EXE" /W:"%CD%\OFFTOOLS\PASSWARE">NUL
IF EXIST ".\OFFTOOLS\PDFTOOLS\PDFTOOLS.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\鸿越超级PDF工具包.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\PDFTOOLS\PDFTOOLS.EXE" /W:"%CD%\OFFTOOLS\PDFTOOLS">NUL
IF EXIST ".\OFFTOOLS\IMETOOLS\IMETOOLS.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\鸿越输入法及其工具包.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\IMETOOLS\IMETOOLS.EXE" /W:"%CD%\OFFTOOLS\IMETOOLS">NUL
IF EXIST ".\OFFTOOLS\2K3MENU\2K3MENU.EXE" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\TOOLS\OFFICE2007经典菜单设置.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\2K3MENU\2K3MENU.EXE" /W:"%CD%\OFFTOOLS\2K3MENU">NUL
IF EXIST ".\OFFTOOLS\H2Viewer\H2Viewer.exe" IF NOT EXIST "%ALLUSERSPROFILE%\%PROGRAM%\HELPS" MD "%ALLUSERSPROFILE%\%PROGRAM%\HELPS"
IF EXIST ".\OFFTOOLS\H2Viewer\H2Viewer.exe" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\HELPS\OFFICE2007帮助文件查看器.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFTOOLS\H2Viewer\H2Viewer.exe" /W:"%CD%\OFFTOOLS\H2Viewer">NUL
IF EXIST "D:\OFFICE2007\OFFICE12\1033\MSACCESS.HXS" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\HELPS\ACCESS2007帮助文件.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\CLVIEW.EXE" /P:"MSACCESS HYSoft-ACCESS" /W:"%CD%\OFFICE">NUL
IF EXIST "D:\OFFICE2007\OFFICE12\1033\WINWORD.HXS" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\HELPS\WORD2007帮助文件.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\CLVIEW.EXE" /P:"WINWORD HYSoft-WORD" /W:"%CD%\OFFICE">NUL
IF EXIST "D:\OFFICE2007\OFFICE12\1033\EXCEL.HXS" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\HELPS\EXCEL2007帮助文件.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\CLVIEW.EXE" /P:"EXCEL HYSoft-EXCEL" /W:"%CD%\OFFICE">NUL
IF EXIST "D:\OFFICE2007\OFFICE12\1033\POWERPNT.HXS" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\HELPS\PPT2007帮助文件.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\CLVIEW.EXE" /P:"POWERPNT HYSoft-POWERPNT" /W:"%CD%\OFFICE">NUL
IF EXIST "D:\OFFICE2007\OFFICE12\1033\OUTLOOK.HXS" SC /F:"%ALLUSERSPROFILE%\%PROGRAM%\HELPS\OUTLOOK2007帮助文件.LNK" /A:C /D:"鸿越软件" /T:"%CD%\OFFICE\CLVIEW.EXE" /P:"OUTLOOK HYSoft-OUTLOOK" /W:"%CD%\OFFICE">NUL
:END
CLS
REM 4.提示安装完成并根据QSTART设置决定是否启动
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("安装完成,是否要立即进行OFFICE语言设置?" , vbQuestion+vbYesNo, "鸿越软件温馨提示您!")
>>"%TEMP%\Temp.vbs" Echo IF intAnswer = vbYes THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "QSTART"
>>"%TEMP%\Temp.vbs" Echo ELSEIF intAnswer = vbNo THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "FEXIT"
>>"%TEMP%\Temp.vbs" Echo END If
For /f "delims=" %%I In ('"cscript //nologo "%TEMP%\Temp.vbs""') do (GOTO:%%I)
:QSTART
CLS
IF EXIST ".\OFFICESET.EXE" START "" ".\OFFICESET.EXE"
GOTO:FEXIT
:WIN9X
CLS
REM 如果是WIN9X程序,则简单运行代码即可(注意这里获取CPATH路径的方式)
SET ERR=本工具暂时不能在WIN9X上安装运行
GOTO:ERROR
ECHO EXIT|%comspec% /k prompt SET CPATH=$P$_|FIND "CPATH">"%TEMP%\CPATH.BAT"
CALL"%TEMP%\CPATH.BAT"
PATH=%CPATH%;%CPATH%\GTOOLS\;%PATH%
BS "%TEMP%\CPATH.BAT" \ \\>NUL
CALL"%TEMP%\CPATH.BAT"
DEL "%TEMP%\CPATH.BAT"
TYPE STARTUP\GREEN.SVR>"%TEMP%\TGREEN.SVR"
BS "%TEMP%\TGREEN.SVR" "D:\\OFFICE2007" "%CPATH%" /I
BS "%TEMP%\TGREEN.SVR" "C:\\WINDOWS\\FONTS" "%WINDIR%\\FONTS" /I >NUL&CLS
REM BS "%TEMP%\TGREEN.SVR" "C:\\WINDOWS\\SYSTEM32" "%WINDIR%\\SYSTEM32" /I >NUL&CLS
CLS
REGEDIT /S "%TEMP%\TGREEN.SVR" >NUL
REGEDIT /S ".\GTOOLS\REGME.SVR" >NUL
IF EXIST ".\OFFICE\1033\MTEXTRA.TTF" COPY /Y ".\OFFICE\1033\MTEXTRA.TTF" "%WINDIR%\FONTS\"
START REGSVR32 /S ".\OFFICE\PLUGINS\Comdlg32.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Fm20.dll"
START REGSVR32 /S ".\OFFICE\PLUGINS\mscomctl.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Msbcode9.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Mscal.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Mscomct2.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Mscomm32.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Msflxgrd.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Mswinsck.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Richtx32.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\Vsflex3.ocx"
START REGSVR32 /S ".\OFFICE\PLUGINS\SNAPVIEW.OCX"
SC /F:"%WINDIR%\Application Data\Microsoft\Internet Explorer\Quick Launch\OFFICE%OFFV%.LNK" /A:C /D:"鸿越软件" /T:"%CPATH%\OFFICE\MSACCESS.EXE" /W:"%CPATH%\OFFICE">NUL
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("安装完成,祝您工作愉快,如有任何问题请联系鸿越软件",vbYes, "鸿越软件温馨提示您!")
cscript //nologo "%TEMP%\Temp.vbs"
GOTO:FEXIT
:ERROR
REM CMDOW @ /MIN
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("%ERR%" , vbYes, "鸿越软件温馨提示您!")
cscript //nologo "%TEMP%\Temp.vbs"
GOTO:FEXIT
:FEXIT
CLS
IF EXIST "%TEMP%\*.UBK" DEL "%TEMP%\*.UBK"
IF EXIST "%TEMP%\TGREEN.SVR" DEL "%TEMP%\TGREEN.SVR"
IF EXIST "%TEMP%\Temp.vbs" DEL "%TEMP%\Temp.vbs"
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /V "CheckedValue" /T "REG_DWORD" /D "1" /F>NUL
IF NOT EXIST "%WINDIR%\FONTS\DESKTOP.INI" ECHO [.ShellClassInfo]>"%WINDIR%\FONTS\DESKTOP.INI"&&ECHO UICLSID={BD84B380-8CA2-1069-AB1D-08000948F534}>>"%WINDIR%\FONTS\DESKTOP.INI"
ATTRIB +H +R %WINDIR%\FONTS\DESKTOP.INI
ATTRIB +H +R %WINDIR%\FONTS
EXIT 二.通用设置程序使用说明.
通用设置程序主要可以完成OFFICE界面语言的设置,ACCESS专业版本和运行时版本的切换和其他插件工具的设置,如OFFICE2003经典菜单设置和OFFICE2007帮助文件查看器等.
使用说明:
1.OFFICE语言界面设置.设置程序根据GTOOLS下是否存在LANS.INI语言配置文件而决定是否显示语言设置界面,如果你没有多语言包,请删除该配置文件,否则你可能无法进行其他设置;OFFICE多语言包必须使用WINRAR压缩制作成自解压EXE文件包,并根据LANS.INI中的语言名称为文件名保存到OFFTOOLS\LANG下,否则无法自动调用,目前我制作了OFFICE2003的十国语言和OFFICE2007的五国语言包,需要的可以联系本人.
2.自动检测ACCESS组件及其版本并提示是否进行版本切换.设置程序根据是否存在MSACCESS.EXE文件显示设置界面,如果OFFICE组件没有该组件则不出现提示界面;设置程序根据OPA和MSO文件名来检测OFFICE版本,所以不要更改这些文件名称;设置程序根据不同的OFFICE版本并提示用户进行专业版本和运行时版本的切换.运行时版本专门用来发布ACCESS程序.
程序代码:
@ECHO OFF
CLS
REM 本程序经过多层加密,如果你能看到源代码,恭喜你;但因编写本程序花费了作者不少心血,所以希望只供做学习研究之用,不得用于任何商业用途,否则本人将追加法律责任.
REM 程序说明:本程序是OFFICE通用设置程序,适合OFFICE97-2007程序安装,自动检测OFFICE版本并根据是否存在对应的语言设置,2003经典菜单设置和ACCESS RT设置组件而自动提示用户,编写这个程序经历了至少10余次的修改和完善,现已相当完美了.系统时间调整到2007-08-08才能安装.
REM 参数说明1:QHID安装时是否隐藏界面,默认为YES表示隐藏;QSTART安装后是否打开程序,默认NO不打开(这个变量已被VBS提示代替);QREADME是否显示版权信息,默认NO不显示.这三个变量主用于批量安装.
REM 参数说明2:QTHINSTALL是否采用虚拟方式安装,默认NO表示在本机安装,YES则表示虚拟环境安装(不向注册表和系统写文件,所以不需要备分,建立快捷方式等操作)
VER|FIND "4.1"
IF ERRORLEVEL 1 GOTO:WINXP
IF ERRORLEVEL 0 GOTO:WIN9X
:WINXP
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /V "CheckedValue" /T "REG_DWORD" /D "0" /F>NUL
SET PATH=%CD%;%CD%\GTOOLS\;%PATH%
TITLE OFFICE通用设置工具V2
mode con cols=20 lines=1
COLOR 02
CMDOW @ /DIS
SET QHID=YES
REM SET QSTART=NO
IF /I "%QHID%"=="YES" (SET TIMEOUT=1) ELSE (SET TIMEOUT=5)
FOR /F "TOKENS=1,2 DELIMS=: " %%I IN ('CHCP') DO SET LAN=%%J
IF "%LAN%" NEQ "950" GOTO :CHS
IF "%JUT%"=="1" GOTO CHS
:CHT
SET JUT=1
IF NOT EXIST ".\GTOOLS\CT.exe" CLS&&SET ERR=缺少代码转换工具&&GOTO:ERROR
TYPE ".\GTOOLS\LANS.INI">"%TEMP%\LANS.INI"
START /WAIT CT.EXE /B /S "%TEMP%\LANS.INI" /D "%TEMP%\LANS.INI"
TYPE %0>"%TEMP%\GSETUP.BAT"
START /WAIT CT.EXE /B /S "%TEMP%\GSETUP.BAT" /D "%TEMP%\GSETUPCHT.BAT"
START /B/WAIT "" "%TEMP%\GSETUPCHT.BAT"
IF EXIST "%TEMP%\GSETUP.BAT" DEL /F/Q "%TEMP%\GSETUP.BAT"
IF EXIST "%TEMP%\GSETUPCHT.BAT" DEL /F/Q "%TEMP%\GSETUPCHT.BAT"
EXIT
:CHS
CLS
mode con cols=60 lines=15
ECHO.
ECHO ╔──────────────────────────────╗
ECHO │ │
ECHO │ OFFICE通用设置工具V2 │
ECHO │ 本程序由鸿越软件小布点编写制作 │
ECHO │ 本程序专用于OFFICE多语言和AC运行时设置 │
ECHO │ 本程序可以自由复制,使用和发布,版权归作者本人所有 │
ECHO │ QQ:9399100 QQ群号:29946542 E-MAIL:xiaobudian528@sina.com │
ECHO │ │
ECHO ╚──────────────────────────2007─㊣╝
ECHO.
PING 127.0.0.1 -n %TIMEOUT% >NUL
FOR /F "TOKENS=1-3 DELIMS=/- " %%I IN ('DATE /T') DO (SET DY=%%I&&SET DM=%%J&&SET DD=%%K)
IF "%DY%-%DM%-%DD%" NEQ "2007-08-08" SET ERR=你所使用的软件已经过期,请联系鸿越软件QQ:9399100 TEL:076921033442&&GOTO:ERROR
net user "%username%"|FIND /I "Administrators"
IF "%ERRORLEVEL%"=="1" SET ERR=你没有权限安装和运行本程序,请联系你的管理员&&GOTO:ERROR
IF NOT EXIST OFFICE CLS&&SET ERR=本工具只能放于与OFFICE同名的目录&&GOTO:ERROR
IF NOT EXIST ".\GTOOLS\Rar.exe" CLS&&SET ERR=缺少解压缩工具GTOOLS\Rar.exe&&GOTO:ERROR
cmdow /t|findstr /i "winword excel powerpnt msaccess">nul
IF "%ERRORLEVEL%"=="0" CLS&&SET ERR=你必须关闭任何OFFICE程序后才能继续使用本程序&&GOTO:ERROR
SET CPATH=%CD%
:LLS
CLS
IF NOT EXIST ".\GTOOLS\LANS.INI" CLS&&GOTO:MENUS
CMDOW @ /ACT
SET LANG=
IF "%LAN%"=="950" (SET LANSFILE=%TEMP%\LANS.INI) ELSE (SET LANSFILE=.\GTOOLS\LANS.INI)
ECHO =================================
TYPE "%LANSFILE%"
ECHO.
ECHO =================================
SET /P LS=请你输入大写字母来选择使用的OFFICE的语言界面(Q退出):
IF /I "%LS%"=="Q" GOTO:MENUS
FOR /F "EOL=; TOKENS=1-3 DELIMS=.:" %%I IN ('TYPE "%LANSFILE%"^|FINDSTR /C:"%LS%"') DO (SET LANG=%%J)
IF NOT DEFINED LANG GOTO :LLS
REM IF /I "%LANG%"=="ENGLISH" GOTO :RAF
IF NOT EXIST ".\OFFTOOLS\LANG\%LANG%.EXE" CLS&&ECHO 没有对应的%LANG%语言文件,请按任意键...&&PAUSE>NUL&&GOTO:LLS
:RAF
IF EXIST "%TEMP%\ERR.LOG" DEL /F/Q "%TEMP%\ERR.LOG"
REM IF EXIST ".\OFFTOOLS\LANG\%LANG%.EXE" RAR.EXE X -Y .\OFFTOOLS\LANG\%LANG%.EXE .\OFFICE\|FINDSTR /C:": "
IF EXIST ".\OFFTOOLS\LANG\%LANG%.EXE" RAR.EXE X -Y -INUL -ILOG"%TEMP%\ERR.LOG" .\OFFTOOLS\LANG\%LANG%.EXE .\OFFICE\
IF EXIST "%TEMP%\ERR.LOG" CLS&&SET ERR=语言设置错误,详细情况请查询ERR.LOG文本&&GOTO:ERROR
:MENUS
IF /I "%QHID%"=="YES" (CMDOW @ /HID)
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("是否要把OFFICE设置为2003经典菜单样式?" , vbQuestion+vbYesNo+vbDefaultButton2, "鸿越软件温馨提示您!")
>>"%TEMP%\Temp.vbs" Echo IF intAnswer = vbYes THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "2K3MENU"
>>"%TEMP%\Temp.vbs" Echo ELSEIF intAnswer = vbNo THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "ACCR"
>>"%TEMP%\Temp.vbs" Echo END If
IF EXIST ".\OFFTOOLS\2K3MENU" (For /f "delims=" %%I In ('"cscript //nologo "%TEMP%\Temp.vbs""') do (GOTO:%%I))
GOTO:ACCR
:2K3MENU
CLS
IF EXIST ".\OFFTOOLS\2K3MENU\2K3MENU.EXE" (FOR /F "DELIMS=" %%I IN ('DIR /S/B OFFTOOLS\2K3MENU\*.DLL') DO REGSVR32 /S "%%I")
IF EXIST ".\OFFTOOLS\2K3MENU\2K3MENU.SVR" REGEDIT /S ".\OFFTOOLS\2K3MENU\2K3MENU.SVR"
IF EXIST ".\OFFTOOLS\2K3MENU\2K3MENU.EXE" START /WAIT "" ".\OFFTOOLS\2K3MENU\2K3MENU.EXE"
:ACCR
CLS
IF EXIST ".\OFFICE\OPA12.BAK" SET OPAC=73A4C9C1-D68D-11d0-98BF-00A0C90DC8D9\12.0&&SET OPARU=rldvasjwmvjfrcatkskctmtjahdnkccdgjds&&SET OPARE=sbbcdcprktpjtapmmfdacmupasbhscddncgp
IF EXIST ".\OFFICE\OPA11.BAK" SET OPAC=73A4C9C1-D68D-11d0-98BF-00A0C90DC8D9\11.0&&SET OPARU=rldvasjwmvjfrcatkskctmtjahdnkccdgjds&&SET OPARE=sbbcdcprktpjtapmmfdacmupasbhscddncgp
IF EXIST ".\OFFICE\MSO9.DLL" SET OPAC=73A4C9C1-D68D-11d0-98BF-00A0C90DC8D9&&SET OPARU=okpvasjwmvjfrcatkskctmtjahdnkccdgjds&&SET OPARE=yubcdcprktpjtapmmfdacmupasbhscddncgp
IF EXIST ".\OFFICE\MSO97.DLL" SET OPAC=8CC49940-3146-11CF-97A1-00AA00424A9F&&SET OPARU=okpvasjwmvjfrcatkskctmtjahdnkccdgjds&&SET OPARE=yubcdcprktpjtapmmfdacmupasbhscddncgp
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("是否要把ACCESS设置为RUNTIME版?从而可以在客户端分发你的软件" , vbQuestion+vbYesNo+vbDefaultButton2, "鸿越软件温馨提示您!")
>>"%TEMP%\Temp.vbs" Echo IF intAnswer = vbYes THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "RUNTIME"
>>"%TEMP%\Temp.vbs" Echo ELSEIF intAnswer = vbNo THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "PRO"
>>"%TEMP%\Temp.vbs" Echo END If
IF EXIST ".\OFFICE\MSACCESS.EXE" (For /f "delims=" %%I In ('"cscript //nologo "%TEMP%\Temp.vbs""') do (GOTO:%%I))
SET ERR=设置完成,祝您工作愉快,如有任何问题请联系鸿越软件!
GOTO:ERROR
:RUNTIME
CLS
REG ADD "HKEY_CLASSES_ROOT\Licenses\%OPAC%\Runtime" /VE /T "REG_SZ" /D "%OPARU%" /F
REG DELETE "HKEY_CLASSES_ROOT\Licenses\%OPAC%\Retail" /F
SET ERR=设置完成,祝您工作愉快,如有任何问题请联系鸿越软件!
GOTO:ERROR
:PRO
CLS
REG ADD "HKEY_CLASSES_ROOT\Licenses\%OPAC%\Runtime" /VE /T "REG_SZ" /D "%OPARU%" /F
REG ADD "HKEY_CLASSES_ROOT\Licenses\%OPAC%\Retail" /VE /T "REG_SZ" /D "%OPARE%" /F
SET ERR=设置完成,祝您工作愉快,如有任何问题请联系鸿越软件!
GOTO:ERROR
:WIN9X
SET ERR=本工具暂时不能在WIN9X上安装运行
GOTO:ERROR
:ERROR
CMDOW @ /MIN
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("%ERR%" , vbYes, "鸿越软件温馨提示您!")
cscript //nologo "%TEMP%\Temp.vbs"
IF EXIST "%TEMP%\ERR.LOG" ECHO.>>"%TEMP%\ERR.LOG"&&ECHO 可能存在OFFICE程序进程,请结束进程后在运行设置程序>>"%TEMP%\ERR.LOG"&&START "" "%TEMP%\ERR.LOG"
GOTO:END
:END
CLS
IF EXIST "%TEMP%\LANS.INI" DEL /F/Q "%TEMP%\LANS.INI"
IF EXIST "%TEMP%\Temp.vbs" DEL "%TEMP%\Temp.vbs"
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /V "CheckedValue" /T "REG_DWORD" /D "1" /F>NUL
EXIT 三.通用卸载程序使用说明.
通用卸载程序很多功能和安装程序相同,如安装环境的检测等,这里不在赘述,只说不同的重点部分.
使用说明:
1.根据用户的设置进行注册表卸载.卸载程序工具GTOOLS下的REGDEL.LST文件中指定的要删除的注册表项进行删除注册表相关内容;安装程序还会提示是否完成卸载程序，如果选择是不仅会根据用户的设置卸载注册表项,还会完整删除OFFICE的两个主键,即HKEY_CURRENT_USER\Software\Microsoft\Office和HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Office,需要注意的完整删除可能造成其他版本的OFFICE无法使用,所以安装了其他版本OFFICE的建议不要使用完整卸载功能;卸载程序根据是否存在注册表备份并进行恢复,从而可以防止卸载程序造成其他程序不能正常使用的问题.
2.反注册控件.和安装程序一样,根据是否存在REGME.LST来反注册控件,如果不存在该文件,则会对当前目录和所有自目录进行反注册控件.
3.删除快捷键功能.可以完整删除根据安装程序创建的快捷键,所以不要更改快捷的名称.
程序代码:
@ECHO OFF
CLS
REM 本程序经过多层加密,如果你能看到源代码,恭喜你;但因编写本程序花费了作者不少心血,所以希望只供做学习研究之用,不得用于任何商业用途,否则本人将追加法律责任
REM 程序说明:本程序是OFFICE通用卸载程序,适合OFFICE97-2007程序安装,自动检测OFFICE版本并根据安装的组件自动删除对应的快捷方式等一系列操作,编写这个程序经历了至少10余次的修改和完善,现已相当完美了;本程序只能把系统时间调整到2007-08-08才能安装.
REM 参数说明:QHID安装时是否隐藏界面,默认为YES表示隐藏;QSTART安装后是否打开程序,默认NO不打开(这个变量已被VBS提示代替);QREADME是否显示版权信息,默认NO不显示.这三个变量主用于批量安装.
VER|FIND "4.1"
IF ERRORLEVEL 1 GOTO:WINXP
IF ERRORLEVEL 0 GOTO:WIN9X
:WINXP
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /V "CheckedValue" /T "REG_DWORD" /D "0" /F>NUL
SET PATH=%CD%;%CD%\GTOOLS\;%CD%\OFFICE\STARTUP\;%PATH%
TITLE OFFICE通用绿化卸载工具V2
mode con cols=20 lines=1
COLOR 02
CMDOW @ /DIS
SET QHID=YES
SET REGBAKDIR=REGBAK
IF /I "%QHID%"=="YES" (SET TIMEOUT=1) ELSE (SET TIMEOUT=5)
IF /I "%QHID%"=="YES" (CMDOW @ /HID)
FOR /F "TOKENS=1,2 DELIMS=: " %%I IN ('CHCP') DO SET LAN=%%J
IF "%LAN%" NEQ "950" GOTO :CHS
IF "%JUT%"=="1" GOTO CHS
:CHT
SET JUT=1
IF NOT EXIST ".\GTOOLS\CT.exe" SET ERR=缺少代码转换工具&&GOTO:ERROR
TYPE %0>"%TEMP%\UINSTALL.BAT"
START /WAIT CT.EXE /B /S "%TEMP%\UINSTALL.BAT" /D "%TEMP%\UINSTALLCHT.BAT"
START /B/WAIT "" "%TEMP%\UINSTALLCHT.BAT"
IF EXIST "%TEMP%\UINSTALL.BAT" DEL /F/Q "%TEMP%\UINSTALL.BAT"
IF EXIST "%TEMP%\UINSTALLCHT.BAT" DEL /F/Q "%TEMP%\UINSTALLCHT.BAT"
EXIT
:CHS
CLS
mode con cols=70 lines=20
ECHO.
ECHO ╔──────────────────────────────╗
ECHO │ │
ECHO │ OFFICE通用绿化卸载V2 │
ECHO │ 本程序由鸿越软件小布点编写制作 │
ECHO │ 本程序用于卸载已安装过的各版本OFFICE程序 │
ECHO │ 本程序可以自由复制,使用和发布,版权归作者本人所有 │
ECHO │ QQ:9399100 QQ群号:29946542 E-MAIL:xiaobudian528@sina.com │
ECHO │ │
ECHO ╚──────────────────────────2007─㊣╝
ECHO.
PING 127.0.0.1 -n %TIMEOUT% >NUL
FOR /F "TOKENS=1-3 DELIMS=/- " %%I IN ('DATE /T') DO (SET DY=%%I&&SET DM=%%J&&SET DD=%%K)
IF "%DY%-%DM%-%DD%" NEQ "2007-08-08" SET ERR=你所使用的软件已经过期,请联系鸿越软件QQ:9399100 TEL:076921033442&&GOTO:ERROR
net user "%username%"|FIND /I "Administrators"
IF "%ERRORLEVEL%"=="1" SET ERR=你没有权限安装和运行本程序,请联系你的管理员&&GOTO:ERROR
IF NOT EXIST OFFICE SET ERR=本工具只能放于与OFFICE同名的目录&&GOTO:ERROR
IF NOT EXIST ".\GTOOLS\BS.exe" SET ERR=缺少字符替换工具&&GOTO:ERROR
IF /I "%QHID%" NEQ "YES" (CMDOW @ /MIN)
CLS
REM 1.删除和恢复注册表,这里导入注册表不用REG IMPORT而使用REGEDIT,原因是前者使用导入不完整,也许是一个BUG吧
IF NOT EXIST ".\GTOOLS\REGDEL.LST" SET ERR=缺少注册表删除项列表文件GTOOLS\REGDEL.LST&&GOTO:ERROR
IF "%LAN%"=="950" SET REGBAKDIR=REGBAKF
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("是否要干净卸载OFFICE?建议已安装了OFFICE其他版本或组件的不要使用此功能!"+vbCrLf+vbCrLf+"注意:干净卸载会删除所有对应注册表项,可能造成已安装OFFICE或组件无法使用!", vbExclamation+vbYesNo+vbDefaultButton2, "鸿越软件温馨提示您!")
>>"%TEMP%\Temp.vbs" Echo IF intAnswer = vbYes THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "Y"
>>"%TEMP%\Temp.vbs" Echo ELSEIF intAnswer = vbNo THEN
>>"%TEMP%\Temp.vbs" Echo Wscript.Echo "N"
>>"%TEMP%\Temp.vbs" Echo END If
For /f "delims=" %%I In ('"cscript //nologo "%TEMP%\Temp.vbs""') do (CALL SET UINALL=%%I)
FOR /F "EOL=; DELIMS=" %%I In (.\GTOOLS\REGDEL.LST) Do (CALL REG DELETE "%%I" /F>NUL&CLS)
IF "%UINALL%"=="Y" REG DELETE "HKEY_CURRENT_USER\Software\Microsoft\Office" /F>NUL&CLS
IF "%UINALL%"=="Y" REG DELETE "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Office" /F>NUL&CLS
IF EXIST ".\GTOOLS\%REGBAKDIR%\*.SVR" (
FOR /F "DELIMS=" %%X IN ('DIR /B/S ".\GTOOLS\%REGBAKDIR%\*.SVR"') DO (REGEIT /S "%%X"))
)
IF EXIST ".\GTOOLS\REGME.LST" (
FOR /F "EOL=;DELIMS=" %%I IN (.\GTOOLS\REGME.LST) DO REGSVR32 /S /U "%%I"
IF EXIST PLUGINS (FOR /F "DELIMS=" %%I IN ('DIR /S/B PLUGINS\*.DLL PLUGINS\*.OCX') DO REGSVR32 /S /U "%%I")
GOTO:DSC
)
FOR /F "DELIMS=" %%I IN ('DIR /S/B *.DLL *.OCX') DO REGSVR32 /S /U "%%I"
:DSC
CLS
REM 2.删除快捷键
TYPE GTOOLS\GREEN.SVR|FINDSTR /I/V "%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a.*%%a">"%TEMP%\TGREEN.SVR"
IF "%LAN%"=="950" START /WAIT CT.EXE /B /S "%TEMP%\TGREEN.SVR" /D "%TEMP%\TGREEN.SVR"
IF EXIST "%TEMP%\TGREEN.SVR" (FOR /F "TOKENS=2 DELIMS=;:" %%I IN ('FINDSTR /I "GREENNAME" "%TEMP%\TGREEN.SVR"') DO SET GREENNAME=%%I)
IF EXIST ".\OFFICE\MSO97.DLL" SET OFFVN=97
IF EXIST ".\OFFICE\MSO9.DLL" SET OFFVN=2000
IF EXIST ".\OFFICE\OPA11.BAK" SET OFFVN=2003
IF EXIST ".\OFFICE\OPA12.BAK" SET OFFVN=2007
SET OFFV=%OFFVN%%GREENNAME%
IF "%LAN%"=="936" (SET DESKTOP=桌面&& SET PROGRAM=「开始」菜单\程序\【HYSOFT】\OFFICE%OFFV%&&GOTO:SC)
IF "%LAN%"=="950" (SET DESKTOP=桌面&& SET PROGRAM=「开始」功能表\程式集\【HYSOFT】\OFFICE%OFFV%) ELSE (SET DESKTOP=DESKTOP&& SET PROGRAM=Start Menu\Programs\【HYSOFT】\OFFICE%OFFV%)
:SC
IF EXIST "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\WORD%OFFV%.LNK" DEL /Q/F "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\WORD%OFFV%.LNK"
IF EXIST "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\EXCEL%OFFV%.LNK" DEL /Q/F "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\EXCEL%OFFV%.LNK"
IF EXIST "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\PPT%OFFV%.LNK" DEL /Q/F "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\PPT%OFFV%.LNK"
IF EXIST "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\ACCESS%OFFV%.LNK" DEL /Q/F "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch\ACCESS%OFFV%.LNK"
IF EXIST "%ALLUSERSPROFILE%\%PROGRAM%" RD /Q/S "%ALLUSERSPROFILE%\%PROGRAM%"
SET ERR=卸载完成,如果要完整删除本软件请删除整个目录即可!
GOTO:ERROR
:WIN9X
SET ERR=本工具暂时不能在WIN9X上安装运行
GOTO:ERROR
:ERROR
REM CMDOW @ /MIN
>"%TEMP%\Temp.vbs" Echo intAnswer = MsgBox("%ERR%" , vbYes, "鸿越软件温馨提示您!")
cscript //nologo "%TEMP%\Temp.vbs"
GOTO:END
:END
CLS
IF EXIST ".\GTOOLS\%REGBAKDIR%" RD /Q/S ".\GTOOLS\%REGBAKDIR%"
IF EXIST "%TEMP%\Temp.vbs" DEL "%TEMP%\Temp.vbs"
REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Folder\Hidden\SHOWALL" /V "CheckedValue" /T "REG_DWORD" /D "1" /F>NUL
IF EXIST ".\OFFTOOLS\2K3MENU\2K3MENU.EXE" CD .\OFFTOOLS\2K3MENU&&CALL UINSTALL.BAT
EXIT [ Last edited by HUNRYBECKY on 2007-8-10 at 11:10 AM ]
|
