中国DOS联盟

@echo off
color 2e
title 查杀U盘病毒
mode con lines=23 cols=60

cls
color 1f
echo.&echo          U盘病毒查杀程序 clamber制作 20070717 @XP
setlocal enabledelayedexpansion
for /f "skip=1 tokens=1,2 delims=\" %%a in ('fsutil fsinfo drives^|find /v ""') do (
    set aa=%%a
    set aa=!aa:~-2!
    for %%j in (!aa!) do (
    if not exist %%j\autorun.inf (echo  ─────────────────────────────&echo [%%j]盘安全^^!) else (echo  ─────────────────────────────&echo [%%j]盘有威胁  清除中 ...&set pau=pause&set panf=%%j&call :kill)
    )
     )
echo  ─────────────────────────────
echo  如双击磁盘无法打开请重启电脑            按任意键退出 ...
%pau%>nul&exit
:kill
fsutil fsinfo drivetype %panf%|find /i "ROM">nul 2>nul
if %ERRORLEVEL%==0 echo     CD-ROM 驱动器 禁止清除^^! &goto :eof
if exist %panf%\*.exe md %panf%\exe备份>nul 2>nul&attrib %panf%\*.exe -h -r>nul 2>nul&move /y %panf%\*.exe %panf%\exe备份>nul 2>nul
attrib %panf%\autorun.inf -s -h -r>nul&attrib %panf%\*.exe -s -h -r>nul 2>nul
del %panf%\autorun.inf /q>nul 2>nul&del/q %panf%\*.exe>nul 2>nul
if not exist %panf%\autorun.inf (echo     已成功清除^^!) else echo     清除失败^^!
if exist %panf%\*.exe echo 仍有威胁程序在运行:&echo ------------------&dir %panf%\*.exe /b&echo ------------------&goto taskk
goto :eof

:taskk
set /p ask=要强制删除威胁程序吗? [y]结束 [D]删除 [N]跳过 :
if /i "%ask%"=="d" (for /f %%k in ('dir %panf%\*.exe /b') do taskkill /f /t /im %%k) & del /q %panf%\*.exe
if /i "%ask%"=="y" for /f %%k in ('dir %panf%\*.exe /b') do (
   taskkill /f /t /im %%k
   set nam=%%k
   ren %panf%\%%k "!nam:~0,-4!.exe疑为病毒"
   )
goto :eof