|
26933062
银牌会员
积分 2268
发帖 879
注册 2006-12-19
状态 离线
|
『楼 主』:
依次横向显示文档中的字符
a.txt内容如下
abcefg
1234567
yuhgrte
问题:我运行以下批处理后,显示完第一排字符后就停了,有什么办法能继续显示后面的字符?
@echo off
set s=0
for /f "delims=" %%i in (a.txt) do call :xs %%i
goto :eof
:xs
set a=%1
:top
echo.|call set /p b=%%a:~%s%,1%%
set /a s+=1
goto top
|
|
 2007-2-2 14:41 |
|
|
PPdos
高级用户
积分 783
发帖 268
注册 2006-12-26
状态 离线
|
『第
2 楼』:
学习楼主程序
在下愚见 认为:xs没有定义退出循环的条件 从而不能进入第二行的显示
|
菩提本无树,明镜亦非台,本来无一物,何处惹尘埃. |
|
|
2007-2-2 17:38 |
|
|
anqing
高级用户
积分 859
发帖 413
注册 2006-8-14
状态 离线
|
『第
3 楼』:
xs
set a=%1
:top
echo.|call set /p b=%%a:~%s%,1%%
set /a s+=1
goto top
这些地方看不懂？
|
|
|
2007-2-2 22:08 |
|
|
namejm
荣誉版主
batch fan
积分 5226
发帖 1737
注册 2006-3-10
来自 成都
状态 离线
|
『第
4 楼』:
试试下面的代码：
版本一：
@echo off
:: 如果有半角双引号，将不能继续处理下去，但是可以兼容除等号外的其他特殊字符
:: 如果有等号，将在等号出现的地方报错，但可以继续处理下一个字符
:: 忽略以引号打头的行，忽略空行
:: 不能处理unicode格式文本
for /f "delims=" %%i in (test.txt) do (
set "str=%%i"
call :pickup
)
pause
goto :eof
:pickup
ping -n 1 127.1>nul
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if not "%str%"=="" goto pickup
echo.
goto :eof 版本二：
@echo off
:: 把半角双引号换成空格，把等号换成〓，兼容其他特殊字符
:: 能处理以分号打头的行，但是会忽略空行；
:: 能兼容unicode格式的文本
:: 每行之间空一行显示
for /f "delims= eol=" %%i in ('type test.txt') do (
set "str=%%i"
call set "str=%%str:"= %%"
call :pickup
)
pause
goto :eof
:pickup
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.&echo.
goto :eof 版本三：
@echo off
:: 与版本二的几点区别：
:: 1、不能处理unicode文本
:: 2、每行之间不再强行加上空行，并且能原样显示空行
for /f "delims= eol=" %%i in ('findstr /n .* test.txt') do (
set "str=%%i"
call set "str=%%str:"= %%"
call set "str=%%str:*:=%%"
call :pickup
)
pause
goto :eof
:pickup
if not defined str echo.&goto :eof
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.
goto :eof [ Last edited by namejm on 2007-2-2 at 01:42 PM ]
|
尺有所短，寸有所长，学好CMD没商量。
考虑问题复杂化，解决问题简洁化。 |
|
|
2007-2-2 22:32 |
|
|
anqing
高级用户
积分 859
发帖 413
注册 2006-8-14
状态 离线
|
『第
5 楼』:
版主的可行，这么显示，挺有意思的
|
|
|
2007-2-2 23:10 |
|
|
26933062
银牌会员
积分 2268
发帖 879
注册 2006-12-19
状态 离线
|
『第
6 楼』:
学习了 谢谢版主!!!!!!!!
不过我还是没搞明白,我的为什么会停住,set /p 以后只要没了字符就停了,
还有你的 <nul 是什么意识?
|
|
|
2007-2-3 02:07 |
|
|
namejm
荣誉版主
batch fan
积分 5226
发帖 1737
注册 2006-3-10
来自 成都
状态 离线
|
『第
7 楼』:
你的代码因为在goto top的时候，没有判断某一行的字符是否取尽，从而造成了死循环，所以会一直在处理第一行而不能处理下一行。
<nul 在set/p中的作用是：在同一行上显示每次获取到的内容。
|
尺有所短，寸有所长，学好CMD没商量。
考虑问题复杂化，解决问题简洁化。 |
|
|
2007-2-3 02:53 |
|
|
minmin888
初级用户
积分 127
发帖 62
注册 2007-4-19
状态 离线
|
|
|
2007-5-8 10:22 |
|
