rroo
初级用户
积分 24
发帖 14
注册 2007-9-6
状态 离线
|
『楼 主』:
制作WIN98/DOS622双启动的软盘
近日，有任务下来，需要制作一张WIN/DOS双启动的光盘。需要启动光盘则先有双
启动的软盘。下面我就教大家制作一张双启动的软盘。
1。把WIN98的三个系统文件IO.SYS,MSDOS.SYS,COMMAND.COM都COPY到软盘上，再
把DOS622的系统文件IO.SYS,MSDOS.SYS改名为IO.DOS,MSDOS.DOS后COPY到软盘上
，把DOS622的COMMAND.COM改名为COMMDOS.COM后COPY到软盘上。
2。COPY以下文件到软盘：
(1)一个你认为是万能的光驱驱动程序到软盘(我用的是精英100速的ECS_IDE.
SYS)
(2)WIN98的HIMEM.SYS
(3)WIN98的RAMDRIVE.SYS和CHOICE.COM(用“查找”命令在98的目录中找找看
)
(4)WIN98的SETRAMD.BAT和FINDRAMD.EXE(用“查找”命令在98的目录中找找看
)
(5)一个能在DOS环境下解压缩的文件(我用的是RAR.EXE)
(6)一个你自己制作的压缩包。压缩包解压后的大小不能超过虚拟盘的大小，
且包内应含有MSCDEX.EXE,DOSKEY.COM.包内的所有EXE和COM文件都不应对DOS版本
有限制。(如何解决DOS版本的限制请参阅我同时贴出的另一张贴子。)
(7)一个能在DOS下进行文本编辑的字处理程序。(我用的是QEDIT.EXE)
3。编辑一个CONFIG.SYS和AUTOEXEC.BAT和MSDOS.SYS文件。(我的文件下附)
4。用16进制编辑文件编辑IO.DOS文件，查找字符串“COMMAND.COM”,把找到的全
部改为“COMMDOS.COM”
5。如果这样做以后还不能引导系统，在98环境下执行“SYS C: A:”命令后再把
98中的MSDOS.SYS文件COPY到软盘，从新编辑MSDOS.SYS文件。
6。如果跟着做完第5步以后还是不能引导系统，请寄信给我，让我帮你分析一下
原因吧。
附录：
1。软盘的文件列表：
IO SYS 224,150 06-19-98 20:01 IO.SYS
MSDOS SYS 1,175 09-05-99 22:52 MSDOS.SYS
CHOICE COM 1,754 04-25-98 18:35 CHOICE.COM
AUTOEXEC BAT 1,808 09-06-99 23:36 AUTOEXEC.BAT
FINDRAMD EXE 6,855 06-18-98 20:01 FINDRAMD.EXE
COMMDOS COM 54,645 05-31-94 6:22 COMMDOS.COM
EBD RAR 621,686 08-05-99 16:45 EBD.RAR
HIMEM SYS 33,191 07-17-98 13:52 HIMEM.SYS
IO DOS 40,774 09-04-99 20:00 IO.DOS
COMMAND COM 94,282 06-19-98 20:01 COMMAND.COM
MSDOS DOS 38,138 09-04-99 19:34 MSDOS.DOS
Q EXE 52,876 11-30-96 18:45 Q.EXE
RAM SYS 12,663 06-19-98 20:01 RAM.SYS
RAR EXE 104,546 01-02-99 0:27 RAR.EXE
SETRAMD BAT 352 09-05-99 21:05 SETRAMD.BAT
ECS_IDE SYS 22,320 08-09-96 13:28 ECS_IDE.SYS
CONFIG SYS 140 09-05-99 23:16 CONFIG.SYS
2。我的CONFIG.SYS文件内容：
DEVICE=A:\HIMEM.SYS /TESTMEM:OFF
FILES=50
DOS=HIGH,UMB
DEVICEHIGH=A:\ECS_IDE.SYS /D:MYCDROM
DEVICEHIGH=A:\RAM.SYS /E 4096
LASTDRIVE=Z
3。我的AUTOEXEC.BAT文件内容：
@ECHO OFF
SET DIRCMD=/O:N
SET LGLDRV=22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15 O 14 N 13
SET LGLDRV=%LGLDRV% M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
CALL SETRAMD.BAT %LGLDRV%
:START
CLS
VER
ECHO ******************************************
ECHO 1. Start MS-Windows 98 Batch File
ECHO 2. Start MS-DOS 6.22 Batch File
ECHO 3. Run GHOST for setup Windows 98
ECHO ******************************************
CHOICE /C:123 /N Which one(1,2,3)?
IF ERRORLEVEL 3 GOTO GHOST
IF ERRORLEVEL 2 GOTO DOS
IF ERRORLEVEL 1 GOTO WIN
GOTO START
:GHOST
%CDROM%:
CD\GHOST
GHOST.EXE
GOTO START
:DOS
SET VERSION=DOS
COPY A:\COMMDOS.COM %RAMD%:\COMMAND.COM >NUL
COPY A:\*.DOS %RAMD%:\*.SYS >NUL
SET COMSPEC=%RAMD%:\COMMAND.COM
IF NOT %RAMD%==* GOTO CONU
SET COMSPEC=A:\COMMDOS.COM
GOTO CONU
:WIN
SET VERSION=WIN98
COPY A:\COMMAND.COM %RAMD%: >NUL
COPY A:\IO.SYS %RAMD%: >NUL
COPY A:\MSDOS.SYS %RAMD%: >NUL
SET COMSPEC=%RAMD%:\COMMAND.COM
IF NOT %RAMD%==* GOTO CONU
SET COMSPEC=A:\COMMAND.COM
:CONU
PATH=%RAMD%:\;A:\;%CDROM%:\WARE
SET LGLDRV=
COPY Q.EXE %RAMD%: >NUL
COPY RAR.EXE %RAMD%: >NUL
COPY EBD.RAR %RAMD%: >NUL
%RAMD%:
RAR.EXE E -Y EBD.RAR
LH UCMOUSE.COM >NUL
LH DOSKEY.COM /INSERT
LH MSCDEX.EXE /D:MYCDROM /L:%CDROM%
CLS
ECHO Found RAMDRIVE = %RAMD%
ECHO Found CDROM = %CDROM%
GOTO AUTO
:NORAMD
PATH=A:\;%CDROM%:\WARE
SET LGLDRV=
CLS
ECHO Found RAMDRIVE = NONE
ECHO Found CDROM = ?, Name = MYCDROM
ECHO Not load "DOSKEY.COM" & "MSCDEX.EXE"
:AUTO
IF NOT %RAMD%==C GOTO END
%CDROM%:
CD\DM
COPY *.* %RAMD%:\ >NUL
%RAMD%:
ECHO Not found HardDisk !! Run The DM !!
:END
ECHO.
IF %VERSION%==WIN98 ECHO MS-Windows 98 Start......successfully.
IF %VERSION%==DOS ECHO MS-DOS 6.22 Start......successfully.
VER
4。我的MSDOS.SYS文件头部：
[Paths]
WinDir=
WinBootDir=
HostWinBootDrv=C
[Options]
BootDelay=3
BootMenuDefault=5
BootMenuDelay=10
BootWarn=0
BootKeys=1
BootMulti=1
BootMenu=1
BootWin=1
BootGUI=0
LoadTop=1
Logo=1
AutoScan=1
BootFailSafe=0
DoubleBuffer=1
DblSpace=0
DrvSpace=0
NetWork=0
WinVer=4.10.1998
5.我的SETRAMD.BAT文件内容:
@echo off
set RAMD=
set CDROM=
echo Cheaking your RAM-DRIVE. Please wait...
findramd.exe
if errorlevel 255 goto no_ramdrive
goto do_shift
:loop
if errorlevel %1 goto no_shift
:do_shift
set cdrom=%2
shift
shift
if not %1*==* goto loop
goto no_ramdrive
:no_shift
set ramd=%2
goto success
:no_ramdrive
set RAMD=*
:success
--
或许该改名叫做潮汐了，没钱没时间，也就只能限制在一个月上网一次了。
欢迎你给我写信，但若想收信则只能请你耐心等候了。
"路漫漫其修远兮，吾将上下而求索！"
|
|
