中国DOS联盟

『第 16 楼』:

@echo off&goto start&rem 数字排序

a.txt 中为一行一个数字

可以对任何 200 位以内的整数进行排序。（包括负数、正数、0、及重复的数字）

缺点： 对于0开头的数字，结果会忽略首位的0

::by 26933062 2007-11-25

:start

setlocal EnableDelayedExpansion

for /l %%a in (1 1 200) do set lin=0!lin!

for /f %%a in (a.txt) do (

   set "str=%%a"

   if "!str:~0,1!"=="-" (set fus=a&set str=!str:~1!&set zf=_) else set zf=+

   set str=!lin!!str!

   set !zf!!str:~-200! !random!!random!!random!!random!!random!!random!!random!=a

)

if defined fus call :sort _ /r

call :sort +

pause&exit

:sort

for /f "tokens=1,2 delims=_+= " %%a in ('set %1^|sort %2') do (

   for /f "tokens=* delims=0" %%i in ("%%a") do (

      if "%1"=="_" (set fuhao=-) else set "fuhao="

      if "%%i"=="" (echo !fuhao!0) else echo !fuhao!%%i

   )

)

goto :eof

此帖被 +7 点积分      点击查看详情    评分人：【 plp626 】 分数： +7  时间：2008-5-4 22:01

@echo off

setlocal enabledelayedexpansion

set str= %random% %random% -%random% %random% %random% -%random% %random% -%random% %random% %random%

::对于 a.txt 中为一行一个数字采用下一行方式读取，上一行不要

::上一行set str= %random%...的数前面必需要有一个空格

::for /f %%i in (a.txt) do set str=!str! %%i

echo 排序前数组为: %str:~1%



:sort

    set num=m

    for %%i in (%str%) do if %%i lss !num! set num=%%i

    set ret=%ret% %num%

    set str=!str: %num%=!

    if not "%str%" == "" goto sort



echo 排序后数组为: %ret:~1%

pause

exit

『第 18 楼』:

@echo off&setlocal enabledelayedexpansion

set/p str=输入数字(用空格隔开)

for %%i in (%str%) do (

    set str=0000000000%%i

    set .!str:~-10! !random!=%%i

)

for /f "tokens=2 delims==" %%i in ('set .') do set/p=%%i <nul

pause>nul

此帖被 +5 点积分      点击查看详情    评分人：【 plp626 】 分数： +5  时间：2008-4-30 16:27

『第 19 楼』:

@echo off & Setlocal EnableDelayedExpansion



for /L %%i in (1,1,5) do (

	set skip=.!skip!

	findstr /rc:"^^!skip!$" file.txt|sort

)

此帖被 +15 点积分         点击查看详情    评分人：【 plp626 】 分数： +15  时间：2008-4-30 17:28

Originally posted by lxmxn at 2008-4-30 05:25 PM:
这么热闹，我也来一段了，缺点是效率有点低……

@echo off & Setlocal EnableDelayedExpansion



for /L %%i in (1,1,5) do (

	set skip=.!skip!

	findstr /rc:"^^!ski ... 

Originally posted by huahua0919 at 2008-4-30 18:02:

版主的代码没看懂,能否解释一下?
好象不支持负数排序

Originally posted by MLQX at 2008-5-2 11:26 AM:
谢谢了.quote]

Last edited by MLQX on 2008-5-2 at 12:34 PM ]

Originally posted by zh159 at 2008-4-30 01:51 AM:
以前用过的，忘了出自哪里了

@echo off

setlocal enabledelayedexpansion

    set numbers=%random% %random% %random% %random% %random% %random% %random% %random%

    echo 排序前 ... 

Originally posted by plp626 at 2008-4-29 11:59 PM:

if not %1.==. 

@echo off&setlocal enabledelayedexpansion

set "str=101 20 14 13 19 18 16 11 5 -7"

for %%i in (%str%) do call,set var=!var! n%%i

for %%i in (%var%) do set a=%%i&call :lp

echo !var:n=!

pause>nul&goto :eof

:lp

for %%i in (!var!) do (

    set b=%%i

    if !b:~1! lss %a:~1% (

       set var=!var:%a% =!

       set var=!var:%%i=%%i %a%!

    )

)

Originally posted by zw19750516 at 2008-5-3 22:19:
&&想不到一石激起千重浪，几天未来论坛此贴已经变成了精华贴，而且如此之火，真是非我始之所料，今天将我原来的代码又研究了下，有了如下 ...