中国DOS联盟

@echo off
title 备份基本设备驱动
::::::相关讨论：   http://www.cn-dos.net
::::::网上论坛：　 http://groups.google.com/group/fastslz
::::::个性空间：   http://space.cech.com.cn/fastslz
if not %OS%==Windows_NT (cls&echo.&color 4E&echo  此程序必须在Windows NT或2000以上操作系统上运行&ping/n 5 127.1>nul&exit)
devcon.exe>nul 2>nul
if %errorlevel%==9009 (cls&echo.&color 0E&echo 本脚本需要微软 DevCon.exe 命令行实用工具支持&ping/n 5 127.1>nul&exit)
set log="Drivers\%~n0.log"
set Tempfile="%Temp:"=%.\fast.slz"
set count=0&set error=0&set whql=0
if not exist Drivers\nul MD Drivers
del "Drivers\*.log" 2>nul
cls&color 0b
echo.
echo  正在收集设备信息，请稍等...
for %%a in (PCI PCIIDE USB IDE DISPLAY USBPRINT) do (
    for /f "tokens=1* delims=: " %%b in ('devcon find *%%a*^|find "\"') do echo "%%b"****"%%c">>"%Temp:"=%.\Devinfo.slz"
)
for /f "tokens=1* delims=****" %%b in ('type "%Temp:"=%.\Devinfo.slz"^|find /v ": "') do call :startcopy "@%%~b" "%%~c"
echo.
echo  已经备份了 %count% 项设备驱动
>>%log% echo.
echo  一共备份了 %count% 项设备驱动>>%log%
if %error% gtr 0 (
        echo.
if %error% equ 1 (
        echo  在复制过程中遇到错误
        ) else (
        echo  在复制过程中遇到 %error% 个错误
        )
        echo  请检查日志文件 %log%
        )
endlocal
echo.
echo  按任意键退出. . .&pause>nul

:startcopy
color 0e
if "%~2"=="%forestall%" goto:eof
set "forestall=%~2"
setlocal enabledelayedexpansion
if "%~2"=="" goto:eof
del %Tempfile% 2>nul
set ID=%1
devcon driverfiles %1>%Tempfile% 2>nul
find ":\" %Tempfile%>nul
if errorlevel 1 goto:eof
if %count% equ 0 cls
set name="%~2"
>>%log% echo "%~2"
set ename=%name:&=_%
<nul set/p=正在备份--^> %ename:~0,54%
for %%k in (/ ; ,) do set name=!name:%%k=_!
rem set name=%name:(=[%
rem set name=%name:)=]%
set name=%name:&=_and_%
set name=%name:"=%
for /f "tokens=1 delims=\" %%i in ('type %Tempfile%^|find "\"^|find /v ":"') do set class=%%i
for /f "tokens=1 delims=[" %%i in ('type %Tempfile%^|find /i ".inf"') do set inf=%%~i
for /f "tokens=1* delims=:" %%i in ("%inf:~0,-1%") do for %%a in (%%i) do set "inf=%%a:%%j"&set "infname=%%~nj"
if defined inf (
        xcopy /h /r /y "%inf%" "drivers\%class%\%name%\*.*">nul 2>>%log%
        if errorlevel 1 set /a "error=%error%+1"
)
for /f "tokens=* delims= " %%i in ('type %Tempfile%^|find ":\"^|find /i /v "Driver installed from"') do (
        xcopy /h /r /y "%%~i" "drivers\%class%\%name%\*.*">nul 2>>%log%
        if errorlevel 1 set /a "error=%error%+1"
)
for /f "tokens=1* delims== " %%k in ('type "%inf%"^|find /i ".cat"^|find /v "64"') do set oemname=%%~nl
if defined oemname for /f "delims=*" %%k in ('dir /s /b /a-d "%SystemRoot%\system32\CatRoot\%infname%.cat" 2^>nul') do set catfile=%%~k
if not defined catfile for /f "delims=*" %%k in ('dir /s /b /a-d "%SystemRoot%\%oemname%.cat" 2^>nul') do set catfile=%%k
if defined catfile (
           set infname=%oemname%
           xcopy /h /r /y "%catfile%" "drivers\%class%\%name%\*.*">nul 2>>%log%
           if errorlevel 0 color 0e&echo  含WHQL数字签名
           attrib -s -h -r "drivers\%class%\%name%\%infname%.*">nul
           move /y "drivers\%class%\%name%\%infname%.inf" "drivers\%class%\%name%\%oemname%.inf">nul 2>nul
           move /y "drivers\%class%\%name%\%infname%.cat" "drivers\%class%\%name%\%oemname%.cat">nul 2>nul
)
for /f "tokens=1,2 delims=\ " %%i in ('devcon hwids %ID%^|sed -n "/Hardware ID's:/{n;p;}"') do echo "%infname%.inf"****"%%~i\%%~j">>"Drivers\HardwareID.log"
del "%Temp:"=%\Devinfo.slz" 2>nul
set /a "count=%count%+1"
if not defined catfile echo.
endlocal&(set count=%count%)&(set error=%error%)
goto:eof

@echo off
setlocal enabledelayedexpansion
echo 硬盘型号                接口类型    修订版本
echo ========                ========    ========
for /f "tokens=1,2* delims=\" %%a in ('devcon.exe find gendisk^|find /v /i "USBSTOR\"^|find ":"') do call :fastslz "%%a" "%%b" "%%c"
echo.&pause
:fastslz
set "填充空格=          "
set 类型=%~1%填充空格%
set 修订=%~2
set 修订=%修订:_= %
for %%i in (%修订%) do set 修订=%%i
for /f "tokens=1* delims=:" %%a in ('echo %3') do set 型号="%%~b"
set 型号=%型号:~0,30%
set 型号=%型号:"=%%填充空格%
set 型号=%型号:~1,30%
echo %型号%%类型:~0,12%%修订%
goto:eof

PCI\VEN_1002&DEV_4153&SUBSYS_41531FD3&REV_00\4&1AD7642&0&0058
    Name: RADEON 9550
    Hardware ID's:
        PCI\VEN_1002&DEV_4153&SUBSYS_41531FD3&REV_00
        PCI\VEN_1002&DEV_4153&SUBSYS_41531FD3
        PCI\VEN_1002&DEV_4153&CC_030000
        PCI\VEN_1002&DEV_4153&CC_0300
    Compatible ID's:
        PCI\VEN_1002&DEV_4153&REV_00
        PCI\VEN_1002&DEV_4153
        PCI\VEN_1002&CC_030000
        PCI\VEN_1002&CC_0300
        PCI\VEN_1002
        PCI\CC_030000
        PCI\CC_0300

C:\>cd "C:\Downloads\Drivers\PCI\RADEON 9550\"

C:\Downloads\Drivers\PCI\RADEON 9550>devcon update oem4.inf "PCI\VEN_1002&DEV_41
53&SUBSYS_41531FD3&REV_00"
Updating drivers for PCI\VEN_1002&DEV_4153&SUBSYS_41531FD3&REV_00 from C:\Downlo
ads\Drivers\PCI\RADEON 9550\oem4.inf.
Drivers updated successfully.

PCI\VEN_1002&DEV_4153&SUBSYS_41531FD3&REV_00
        PCI\VEN_1002&DEV_4153&SUBSYS_41531FD3
        PCI\VEN_1002&DEV_4153&CC_030000
        PCI\VEN_1002&DEV_4153&CC_0300
    Compatible ID's:
        PCI\VEN_1002&DEV_4153&REV_00
        PCI\VEN_1002&DEV_4153
        PCI\VEN_1002&CC_030000
        PCI\VEN_1002&CC_0300
        PCI\VEN_1002
        PCI\CC_030000
        PCI\CC_0300

@echo OFF
title 还原更新（驱动精灵）备份项目
::::::相关讨论：   http://www.cn-dos.net
::::::网上论坛：　 http://groups.google.com/group/fastslz
::::::个性空间：   http://space.cech.com.cn/fastslz
if not %OS%==Windows_NT (cls&echo.&color 4E&echo  此程序必须在Windows NT或2000以上操作系统上运行&ping/n 5 127.1>nul&EXIT)
devcon.exe>nul 2>nul
if %errorlevel%==9009 (cls&echo.&color 0E&echo 本脚本需要微软 DevCon.exe 命令行实用工具支持&ping/n 5 127.1>nul&EXIT)
set log="Drivers\%~n0.log"
set Tempfile="%Temp:"=%.\fast.slz"
set count=0
del "Drivers\*.log" 2>nul
del %Tempfile% 2>nul
cls&color 0b
echo.
echo  正在全盘搜索（驱动精灵）备份项目信息，这个可能持续较长时间，请稍等...
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v "a"') do (
    set var=%%i
    set drive=!var:~-2!
    fsutil fsinfo drivetype !drive!\|find /v "-ROM">nul &dir /s /b /a-d !drive!\Driver.nfo>>%Tempfile% 2>nul
    )
for /f "delims=*" %%i in ('type %Tempfile%^|find /i /v "RECYCLE"') do type "%%i"|find /i "InfFile">nul 2>nul
if %errorlevel%==1 cls&echo.&color 0e&echo  在所有本地磁盘、及移动磁盘上未发现（驱动精灵）备份项目信息&echo  如果驱动文件已压缩请解压文件到任意位置，再运行本脚本&ping/n 10 127.1>nul&exit/b

:::::goto Driver_start
Wprompt "提示信息" "按下确定开始还原驱动精灵已备份的项目，需要单个恢复模式脚本请联系本人   " OkCancel 2 ?
if %errorlevel%==2 color 0e&echo  用户取消操作 . . .&ping/n 3 127.1>nul&exit/b

:Driver_start
cls
for /f "delims=*" %%i in ('type %Tempfile%^|find /i /v "RECYCLE"') do (
    for /f "tokens=1* delims==" %%a in ('type "%%~i"^|find /i "DriverName"') do (
        for /f "tokens=1* delims==" %%e in ('type "%%~i"^|find /i "InfFile"') do (
            for /f "tokens=1* delims==&" %%k in ('type "%%~i"^|find /i "HardwareID"') do (call :startdriver "%%b" "%%~dpi%%f" "%%l")
        )
    )
)
del %Tempfile% 2>nul
echo.
echo  一共更新了 %count% 项设备驱动
echo.
echo  按任意键退出. . .&pause>nul

:startdriver
set "ID=%~3"
set "typename=%~1"
if not defined typename goto:eof
set/p=正在更新--^> "%typename:~0,47%"<nul
if not exist "%~2"  echo 没有对应项，执行下一项目 . . .&ping/n 2 127.1>nul&goto:eof
rem 如果不能成功更新，尝试下一for语句delims=上加符号&
for /f "delims=" %%m in ('echo."%ID%"') do devcon updateNI "%~2" "%%~m">nul
if %errorlevel%==0 color 0e&echo  ^<--设备驱动已更新&ping/n 1 127.1>nul&color 0b
if %errorlevel%==1 color 0e&echo  ^<--已更新提示重启&ping/n 1 127.1>nul&color 0b
if %errorlevel%==2 color 0e&echo  ^<--提示更新失败！&echo 原因未正确判断出硬件ID，或驱动源不正确。&ping/n 1 127.1>nul
if %errorlevel%==3 color 0e&echo  DevCon语法错误。&ping/n 1 127.1>nul
set /a "count=%count%+1"
del %Tempfile% 2>nul
endlocal&(set count=%count%)
goto:eof