标题: vbs 如何获取网络状态？ [打印本页]

---

作者: 25869     时间: 2009-8-1 21:50    标题: vbs 如何获取网络状态？

批处理可以通过ping 得知网络连接是开启还是被禁用
不知vbs 如何获取网络状态？

---

作者: slore     时间: 2009-8-2 03:25
vbs 有 WMI 的 ping

---

作者: 25869     时间: 2009-8-3 03:37
能不能给个示例，我在网上没查到，多谢！

---

作者: slore     时间: 2009-8-3 03:50
HOST = "."
TARGET = "www.google.com"

Set PingResults = GetObject("winmgmts:{impersonationLevel=impersonate}//" & _
        HOST & "/root/cimv2"). ExecQuery("SELECT * FROM Win32_PingStatus " & _
         "WHERE Address = '" + TARGET + "'")

For Each PingResult In PingResults
    If PingResult.StatusCode = 0 Then
        If LCase(TARGET) = PingResult.ProtocolAddress Then
            OUTPUT = "Pinging " & TARGET & vbCrLf
        Else
            OUTPUT = "Pinging " & TARGET & " (" & PingResult.ProtocolAddress & ")" & vbCrLf
        End If
        OUTPUT = OUTPUT & "字节: " & PingResult.BufferSize & vbCrLf
        OUTPUT = OUTPUT & "延时(毫秒): " & PingResult.ResponseTime & vbCrLf
        OUTPUT = OUTPUT & "TTL(秒): " & PingResult.ResponseTimeToLive & vbCrLf
    Else
        OUTPUT = OUTPUT & TARGET & " 没有回复" & vbCrLf
        OUTPUT = OUTPUT & "状态码: " & PingResult.StatusCode & vbCrLf
    End If
Next

WScript.Echo OUTPUT

---

作者: 25869     时间: 2009-8-3 07:31
多谢，继续学习！