Board logo

标题: [已结]for循环中的set语句不能正常赋值 [打印本页]
作者: easterling     时间: 2008-11-14 15:46    标题: [已结]for循环中的set语句不能正常赋值

我想得到我的所有驱动器盘符,如"D:\" 我想得到"D" 测试代码如下：
set p=D:\
echo %p%
echo %p:~0,1%
以上代码执行完全正常，但放在for循环中就不行了，代码如下：
for /f "skip=2" %%i  in ('fsutil fsinfo drives^|more') do (
echo %%i
set p=%%i
echo %p%
echo %p:~0,1%
)
第二行还正常,第四行就显示不出来了，等于变量p的值没有赋上，为什么？

[ Last edited by HAT on 2008-11-14 at 20:05 ]
作者: iyou     时间: 2008-11-14 15:54
试试前面在for 前面+上setlocal enabledelayedexpansion
作者: tireless     时间: 2008-11-14 16:13
修改方案：

1. 用 call 延迟变量扩展

  Quote:
for /f "skip=2" %%i  in ('fsutil fsinfo drives^|more') do (
echo %%i
set p=%%i
call echo %%p%%
call echo %%p:~0,1%%
)

2. 开启变量延迟扩展

  Quote:
setlocal EnableDelayedExpansion
for /f "skip=2" %%i  in ('fsutil fsinfo drives^|more') do (
echo %%i
set p=%%i
echo !p!
echo !p:~0,1!
)

3. 增加分隔符

  Quote:
for /f "skip=2 delims=:\" %%i in ('fsutil fsinfo drives^|more') do echo %%i

1. 本版搜索变量延迟
2. set /?

[ Last edited by tireless on 2008-11-14 at 16:32 ]
作者: hqso     时间: 2008-11-14 16:30
setlocal EnableDelayedExpansion
变量延迟扩展，不错的命令，无意中长了见识
作者: easterling     时间: 2008-11-14 17:49    标题: 太佩服3楼了



  Quote:
Originally posted by tireless at 2008-11-14 16:13:
修改方案：

1. 用 call 延迟变量扩展



2. 开启变量延迟扩展



3. 增加分隔符


1. 本版搜索变量延迟
2. [color=re ...

太佩服3楼了 发帖不到30分钟 竟然一口气给出了3种解决方案，并且都完全正确，太了不起了。我会记住你的名字的。