中国DOS联盟

@rem 关闭命令行回显并打开延迟扩展
@echo %bg% off & SetLocal EnableDelayedExpansion

rem 对当前目录及其子目录中的每个文件大小进行索引
set tnum=1
for /r .\ %%a in (*) do (
        set "file!tnum!_%%~nxa=%%~za"
        set /a tnum+=1
)

rem 处理TREE的输入并显示结果
set tnum=1

echo %cd%
echo ************************************************
for /F "delims=" %%a in ('tree /F^|more +3') do (
        echo %%a|findstr /R "├ └" >nul && (
                echo\%%a
        ) || (
                echo %%a|findstr /R /C:"^│[ ]*$" >nul 2>nul && (
                        echo\%%a
                ) || (
                for /f "delims=" %%c in ("%%a") do (
                        set string=%%c
                        set string=!string:│=!
                        for /f "tokens=* delims= " %%d in ("!string!") do set fname=%%d
                        if not "!fname!"=="" (
                                call echo\%%a [%%file!tnum!_!fname!%%]
                                set /a tnum+=1
                        ) else (echo\%%a)
                )
                )
        )
)