中国DOS联盟

[/size]
@echo off&setlocal enabledelayedexpansion
title 批处理版音视频播放器 V4.3 改进版
::by cjiabing;from http://hi.baidu.com/cjiabing
::date:2010.10.10;cmd@xp
COLOR 2E
call :beforehand_default
:drag
rem 拖拉输入
set input=%*
if not exist !mpp!  (call  :beforehand_findmplayer) else  (
    if defined input (
        if exist "%~dp0_playlists.txt" del "%~dp0_playlists.txt"
        for /f "tokens=*" %%a in ("!input!") do  (
     for  %%i in (%%a) do (
                if exist %%i set input=%%~i
                if /i "!input:~-4,4!"==".txt" (
                    type "!input!">>"%~dp0_playlists.txt"
                    goto play_txt
                )
                if exist "!input!\." dir /a:d "!input!"&&set input="!input!"&&goto inport_folder
                echo !input!>>"%~dp0_playlists.txt"
            )
        )
        goto play_txt
    )
)

:start
rem 主界面
set "a=a"
call :main_face
call :backgroundmusic
:main
set "a=b"
call :main_face
call :input
:main_face
cls
echo.
if /i "%a%"=="a" (
    call :colour "27"  "∷∷∷∷I'M LOOKING OUT,I'M LOOKING IN.  WAY DOWN,THE LIGHTS ARE DIMMER∷∷∷∷"
) else (
    call :colour "27"  "∷∷∷∷批处理，她就像中国围棋，小棋盘大世界，虽然简单但同样能带给你精彩∷∷∷∷"
)
call :colour "27"  "∷∷∷∷"&call :colour "2f"  " 设置【S】搜索【F】帮助【H】热键【HK】退出【Q】CMD【C】BAT【B】"&call :colour "27"  "∷∷∷∷"
echo.
echo.
echo.
call :colour "2b"  "   ◥██▃▁                                 _ _..-‐‐-."
echo.
call :colour "2b"  "   ...◥████▅▄▃▁▁▁▁▁▃▄▅▅▆▇▇▅▄▃▃▃▃▃▅▄▁"
echo.^
&call :colour "2b"  "   ≡¤███"&call :colour "0c"  "━批处理版音★视频播放器━"&call :colour "2b"  "██████████████▅▄▃▁▁"
echo.
call :colour "2b"  "   ≡¤███████████████████◤"
echo.
echo.
echo.
goto :eof
:input
rem 输入汇总
call :keyin
goto main
:keyin
set /p "input=     %~pds0"
if /i !input!=="" goto start
if not defined input if exist "%~dp0_playlists.txt" (goto play_txt) else (goto start)
call :inport
call :input_sets
call :input_end
goto :eof
:inport
if exist "!input!" (
    if /I "!input:~-4,4!"==".txt" call :inport_txt
    if /I "!input:~-5,4!"==".txt" call :inport_txt
    dir /a:d !input!||call :play_file
    :inport_folder
    if /i not "!input:~-1,1!"=="\" (set input="!input!\") else (set input="!input!")
    cd.>"%~dp0_playlists.txt"
    dir /a-d /b /s "!input!*.wma" "!input!*.mp3">>"%~dp0_playlists.txt"
    call :play_txt
)
for %%a in (http rtsp vcd dvd) do if /i "!input:~0,4!"=="%%a" (
    echo !input!>"%~dp0_playlists.txt"
    type "%USERPROFILE%\My Documents\My Music\_urlplaylists.txt">>"%~dp0_playlists.txt"
del /q "%USERPROFILE%\My Documents\My Music\_urlplaylists.txt">nul
    copy "%~dp0_playlists.txt" "%USERPROFILE%\My Documents\My Music\_urlplaylists.txt">nul 2>nul
    echo !input!>"%~dp0_playlists.txt"
    call :play_txt
)
goto :eof
:input_end
call :input_sets
echo.
CMD /C !input!&echo.&pause&cls
goto main
:input_sets
rem 全局快捷键
if /i "!input!"=="S" goto setting
if /i "!input!"=="F" call :search&goto main
if /i "!input!"=="C" call :cl&goto main
if /i "!input!"=="B" call :bc&goto main
if /i "!input!"=="H" goto help
IF /I "!input!"=="RS" goto play_general
if /i "!input!"=="HK" call :entry&goto main
if /i "!input!"=="OP" goto play_sets
if /i "!input!"=="BM" goto start
IF /I "!input!"=="CB" START "" IEXPLORE.EXE http://hi.baidu.com/cjiabing&GOTO MAIN
IF /I "!input!"=="BH" START "" IEXPLORE.EXE http://www.bathome.net&GOTO MAIN
IF /I "!input!"=="CD" START "" http://www.cn-dos.net/forum/index.php&GOTO MAIN
IF /I "!input!"=="MP" START "" IEXPLORE.EXE HTTP://WWW.MPLAYERHQ.HU&GOTO MAIN
if /i "!input!"=="LRC" goto lyrics
if /i "!input:~0,2!"=="WB" call :websearch &goto main
if /i "!input!"=="Q" goto exit
goto :eof
:inport_txt
if exist "%~dp0_playlists.txt" (
    if "!input!"=="%~dp0_playlists.txt" (
goto play_txt
    ) else (
cd.>"%~dp0_playlists.txt"
type !input!>>"%~dp0_playlists.txt"
goto play_txt
    )
) else (
    cd.>"%~dp0_playlists.txt"
    type !input!>>"%~dp0_playlists.txt"
    goto play_txt
)
goto :eof
:websearch
for /f "tokens=1,2,* delims= " %%i in ("!input!") do  (
    if /i "%%i"=="wb" (
        if /i "%%j"=="bd" start "" IEXPLORE.EXE "http://www.baidu.com/s?wd=%%k"&goto search
        if /i "%%j"=="gg" start "" IEXPLORE.EXE "http://www.google.cn/music/search?q=%%k"&goto search
        if /i "%%j"=="sg" start "" IEXPLORE.EXE "http://mp3.sogou.com/music.so?query=%%k"&goto search
        if /i "%%j"=="kg" start "" IEXPLORE.EXE "http://www.kugou.com/ting/Search.aspx?keywords=%%k"&goto search
        if /i "%%j"=="gou" start "" IEXPLORE.EXE "http://mp3.gougou.com/search?search=%%k"&goto search
        if /i "%%j"=="ss" start "" IEXPLORE.EXE "http://cgi.music.soso.com/fcgi-bin/m.q?w=%%k"&goto search
        start "" IEXPLORE.EXE "http://www.baidu.com/s?wd=%%j %%k"&goto search
)
)
goto :eof
:play
rem 播放程序
COLOR 2E
if not defined mpp goto beforehand_default
cls
echo.===========================================================================
call :colour "0c" "★★★正在播放！下一首【PageUp】快进【Up】静音【M】暂停【P】退出【Q】★★★"&echo.
echo.===========================================================================
goto :eof
:play_txt
call :play
!mpp!  -playlist  "%~dp0_playlists.txt"
goto main
:play_file
call :play
!mpp! !input!
goto main
:play_general
if exist "%~dp0_playlists.txt" (
    IF /I "!input!"=="r"   set "pp=-loop 0 -playlist"&set input="%~dp0_playlists.txt"
    IF /I "!input!"=="s"   set "pp=-shuffle -playlist"&set input="%~dp0_playlists.txt"
    IF /I "!input!"=="rs"  set "pp=-shuffle -loop 3  -playlist"&set input="%~dp0_playlists.txt"
    call :play
    !mpp! !pp! "%~dp0_playlists.txt"
)
::IF defined pp ("!mpp!" !pp! !input!) else ("!mpp!" !input!)
goto main
goto :eof
:beforehand_default
rem 默认播放器路径
if exist "%ProgramFiles%\StormII\codec\MPlayer.exe" (
   set mpp="%ProgramFiles%\StormII\codec\MPlayer.exe"
   if not exist %SYSTEMDRIVE%\_mplayerpath.txt echo !mpp!>%SYSTEMDRIVE%\_mplayerpath.txt
) else (
     if exist %SYSTEMDRIVE%\_mplayerpath.txt (goto beforehand_mplayerpath) else (call  :beforehand_findmplayer)
)
goto :eof
:beforehand_mplayerpath
if exist %SYSTEMDRIVE%\_mplayerpath.txt (
    set "var_bmp="
    for /f "tokens=* delims=　 " %%i in (%SYSTEMDRIVE%\_mplayerpath.txt) do (
        if /i not "%%i"=="" set var_bmp=a&set "mpp=%%~i"
        )
    if not defined var_bmp (call  :beforehand_findmplayer&goto beforehand_mplayerpath) else (
        if exist !mpp! (goto beforehand_drag) else (call  :beforehand_findmplayer&goto beforehand_mplayerpath)
    )
)
goto :eof
:backgroundmusic
rem 背景音乐
if not defined mpp (
    set var_start=                     对不起！播放器不存在！请安装设置！
    goto  :beforehand_findmplayer
) else (
    if exist  !mpp! (
        call :colour "27"  "                 背景音乐播放中，停止播放请按【Q】或【EnTer】"
        if exist "%USERPROFILE%\My Documents\My Music\_urlplaylists.txt" (
     !mpp! -playlist  "%USERPROFILE%\My Documents\My Music\_urlplaylists.txt">nul 2>nul||!mpp!  -cache 2048  nul">http://cd05.128.music.static.jango.com/music/06/00/48/0600487986.mp3>nul 2>nul&goto main
        ) else (
            !mpp! -cache 2048 nul">http://cd05.128.music.static.jango.com/music/06/00/48/0600487986.mp3>nul 2>nul
        )
    ) else (
     set var_start=                     对不起！播放器不存在！请安装设置！)
  call  :beforehand_findmplayer
)
goto :eof
:setting
cls
COLOR 27
echo.
call :colour "2E" "                                设置选项"&echo.
echo. __________________________________________________________________________
echo.                    
call :colour "2F"  "       ★ 播放列表" &echo →搜索与创建【F】；
echo                   →将媒体文件拖至“程序图标”上自动生成播放列表；
echo.
call :colour "2F"  "       ★ 循环模式" &echo →随机【S】\重复【R】\随机并重复【RS】；
echo                   →需先设置播放列表；只对当前播放有效；全局通用键【RS】；
echo.
call :colour "2F"  "       ★ 播放器参数设置" &echo →使用介绍【OP】；
echo.
call :colour "2F"  "       ★ 歌词设置" &echo →显示歌词【LRC】；
echo                   →目前只支持播放单曲，而且只在通用键下有效；
echo.
call :colour "2F"  "       ★ MPlayer程序路径" &echo →设置【P】；
echo.
call :colour "2F"  "       ★ 命令行界面" &echo →进入【C】；
echo.
call :colour "2F"  "       ★ 编写批处理" &echo →进入【B】；
echo.
echo. __________________________________________________________________________
echo.
call :colour "2E" "     请选择（返回【Q】）："
set /p input=
IF /I "!input!"=="" goto setting
IF /I "!input!"=="rs" goto play_general
IF /I "!input!"=="r" goto play_general
IF /I "!input!"=="s" goto play_general
IF /I "!input!"=="p" goto way
IF /I "!input!"=="OP" goto play_sets
IF /I "!input!"=="q" goto main
call :input_sets
echo.
pause
goto main
:way
cls
COLOR 27
echo.
call :colour "2E" "                                设置选项"&echo.
echo. __________________________________________________________________________
echo.                 
echo.
echo      当前 MPlayer.exe 的路径是：
echo.  
echo      !mpp!
echo.      
call :colour "2E" "     请输入 MPlayer.exe 的路径(搜索【F】默认【MR】返回【Q】)："
set /p input=
IF /I "!input!"=="" goto way
if /i "%input%"=="q" goto setting
if /i "%input%"=="mr" goto way_default
call :input_sets
echo %input%>%SYSTEMDRIVE%\_mplayerpath.txt
set "mpp=!input!"
:way_default
if /i "%input%"=="mr" (
    echo %ProgramFiles%\StormII\codec\MPlayer.exe>%SYSTEMDRIVE%\_mplayerpath.txt
    set mpp="%ProgramFiles%\StormII\codec\MPlayer.exe"
    echo.
    echo     ★ 设置完成！MPlayer的路径为：!mpp!
    ) else (
    echo.
    echo     ★ 设置完成！MPlayer的路径为：!input!
    )
    echo.
pause
goto setting
:beforehand_findmplayer
cls
COLOR 27
echo.
call :colour "2E" "                缺少MPlayer.exe文件，无法播放，正在搜索……"&echo.
echo. __________________________________________________________________________
echo.
echo      ★ 尝试搜索常用安装目录，请稍候……
echo.
for %%a in ("%ProgramFiles%\StormII\codec\MPlayer.exe" "D:\Program Files\StormII\codec\mplayer.exe" "D:\mplayer\mplayer.exe" "C:\mplayer\mplayer.exe" "C:\MPlayer_Windows\mplayer.exe" "D:\Program Files\Super Player\codecs\MPlayer.exe"  "%ProgramFiles%\Super Player\codecs\MPlayer.exe") do if exist %%a set mpp=%%a&&echo !mpp!>%SYSTEMDRIVE%\_mplayerpath.txt&&goto start
echo.
echo      ★ 尝试搜索C、D盘，请稍候……
echo.
cd.>%SYSTEMDRIVE%\_mplayerpath.txt
for %%a in (C D) do  if exist %%a:\  cd /d %%a:\ && for /r %%i in (MPlayer.exe) do if exist %%i (
    echo %%i>>%SYSTEMDRIVE%\_mplayerpath.txt
    set "mpp=%%i"
    goto start
)
echo.
call :colour "2C" "     ★ 无法找到MPlayer.exe文件！您将无法正常使用本程序！"&echo.
call :colour "2C" "     ★ 请确认您的系统安装有MPlayer并手动设置MPlayer.exe的路径。"&echo.
call :colour "2C" "     ★ 建议从MPlayer官方网站下载安装MPlayer播放器程序！"&echo.
echo.
call :colour "2C" "     ★ 正在自动返回！……"&echo.
echo.
ping /n 15 127.0.1>nul
start "" IEXPLORE.EXE  http://www.mplayerhq.hu
goto main
:search
cls
COLOR 27
echo.
call :colour "2E" "                       查找音视频文件并生成播放列表"&echo.
echo. __________________________________________________________________________
echo.
call :colour "2F"  "    ★ 路径名(全盘【A】)：" &echo 有空格需引号。如：
echo           F:\         "D:\Program Files\easy"     
call :colour "2F"  "    ★ 搜索词：" &echo 多个搜索词之间用空格隔开，如：
echo           雅尼  陈慧娴 边走边爱
call :colour "2F"  "    ★ 网页搜索：" &echo 格式：WB + 网站名缩写 + 搜索词，如：
echo           百度搜索“刘德华”：WB  bd  刘德华；
echo           搜狗搜索“情难自禁”：WB sg  情难自禁
echo           百度【BD】谷歌【GG】狗狗【Gou】酷狗【KG】搜狗【SG】搜搜【SS】；
call :colour "2F"  "    ★ 常见音频格式【Y】：" &echo *.mp3 *.wma *.wav。
call :colour "2F"  "    ★ 常见视频格式【S】：" &echo *.mp4 *.flv *.3gp *.mpg *.avi *.wmv *.rm *.rmvb
call :colour "2F"  "    ★ 技巧：" &echo 可直接将媒体文件拖拉至程序图标上，程序自动生成播放列表。
call :colour "2F"  "    ★ 返回【Q】"  &echo.
echo. __________________________________________________________________________
echo.
call :colour "2E" "       输入路径名："
set /p "input="
IF /I "!input!"=="" goto search
if not defined input set "input=%~d0"
if /i "!input!"=="w" echo.&set /p "inport=关键词："&&start "" "http://www.baidu.com/s?wd=!inport!"&goto search
if /i "!input:~-1,1!"=="\" (set input="!input:~0,-1!") else (set input=!input!)
IF /I "!input!"=="q" goto :eof
call :input_sets
call :colour "2E" "       输入搜索词："
set /p "inport="
IF /I "!input!"=="" goto search
if not defined inport set "inport=*.mp3"
if /i "!inport!"=="q" goto main
if exist "%~dp0_playlists.txt" del /q "%~dp0_playlists.txt">nul 2>nul
if /i "!inport!"=="y" dir /a-d /b /s !input!\*.wma !input!\*.mp3>>"%~dp0_playlists.txt"&goto search_end
if /i "!inport!"=="s" dir /a-d /b /s !input!\*.avi !input!\*.wm !input!\*.rm !input!\*.rmvb !input!\*.wmv !input!\*.mpg !input!\*.flv !input!\*.3gp  !input!\*.mp4>>"%~dp0_playlists.txt"&goto search_end
for  %%i in (%inport%) do  (
    set "var_ser=%%i"
    if /i "!var_ser:~-3,1!"=="." dir /a-d /b /s %input%\!var_ser!
    if /i "!var_ser:~-4,1!"=="." dir /a-d /b /s %input%\!var_ser!
    if /i "!var_ser:~-5,1!"=="." (dir /a-d /b /s %input%\!var_ser!) else (dir /a-d /b /s %input%\*%%i*.*)
    )>>"%~dp0_playlists.txt"
if exist "%~dp0_playlists.txt" type "%~dp0_playlists.txt"
:search_end
echo.
if exist "%~dp0_playlists.txt"  (call :colour "2E" "       ★ 搜索完毕！已在当前目录生成文件列表_playlists.txt。"&echo.) else (call :colour "2E" "       ★ 搜索失败，请重试！"&echo.&echo.&pause&goto search)
echo.
pause
goto :eof
:colour
pushd "%temp%"
>"%~2",set/p=   <nul
findstr /a:%~1 .* "%~2*"
del "%~2"
popd
goto :eof
:CL
cls
COLOR 27
echo.
call :colour "2E" "         ★ 你已进入命令行提示符！退出【EXIT】；批处理编辑器【B】。 ★"&echo.
echo. __________________________________________________________________________
echo.&set /p input=%~pds0
if /I "!input!"=="B" goto bc
if /I "!input!"=="exit" goto main
call :input_sets
CMD /k !input!
goto :eof
:Bc
cls
COLOR 2F
echo.
call :colour "2E" "                                  批处理编辑器"
echo.&echo.
call :colour "2E" "      ★ 可编写一般的批处理代码，可以复制粘贴和拖入BAT文件查看代码。★"&echo.
call :colour "2E" "      ★ 结果mpb.bat在临时文件夹Temp下。变量延迟【SETL】for【FOR】。★"&echo.
call :colour "2E" "      ★ 新建【XJ】另存【LC】执行【ZX】打开【DK】C【CMD】退出【Q】。★"&echo.
echo. __________________________________________________________________________
echo.
echo @echo off>"%temp%\mpb.bat"
set var_num=0
:bc_sets
set /a var_num+=1
if !var_num! lss 10 (
    call :colour "2C" "BEdit0!var_num!﹥"
    set /p "input="
    ) else (
    call :colour "2C" "BEdit!var_num!﹥"
    set /p "input="
    )

:bc_cl
if /i  "!input!"=="c" (
    echo.
    call :colour "0C" "您已经入命令行提示符界面！返回编辑器请使用【EXIT】命令"
    echo.&echo.
    set /p input=%~pds0&call :input_sets&CMD /k !input!
    echo.
    call :colour "0C" "按任意键返回编辑器……"
    echo.
    pause>nul
    echo.
    goto bc_sets
)
:bc_hotkey
if /i  "!input!"=="setl" (
    set input=setlocal enabledelayedexpansion
    echo !input!>>"%temp%\mpb.bat"&echo !input!
    goto bc_sets
    )
if /i  "!input!"=="for"  (
    set "input=for /f "tokens=* delims=" %%%%a in (".") do echo %%%%a"
    echo !input!>>"%temp%\mpb.bat"&&echo !input!
    goto bc_sets
    )
if /i not "!input!"=="q" (
    if exist "!input!" (
    type "!input!"
    echo.
    call :colour "0C" "按任意键返回编辑器……"
    echo.
    pause>nul
    echo.
    goto bc_sets
    )
    :xj
    if /i  "!input!"=="xj" (
        del /q /f /s /a "%temp%\_mpb.bat">nul 2>nul
        echo @echo off>"%temp%\mpb.bat"
        echo echo.>>"%temp%\mpb.bat"
        echo echo.>>"%temp%\mpb.bat"
        echo echo.>>"%temp%\mpb.bat"
        echo ::pause>>"%temp%\mpb.bat"
        echo ::exit>>"%temp%\mpb.bat"
        goto bc
    )
    :zx
    if /i  "!input!"=="zx" (
        del /q "%temp%\_mpb.bat">nul 2>nul
        echo echo.>>"%temp%\mpb.bat"
        echo pause>>"%temp%\mpb.bat"
        echo exit>>"%temp%\mpb.bat"
        copy "%temp%\mpb.bat" "%temp%\_mpb.bat">nul 2>nul
        start "mpb" "%temp%\_mpb.bat"
        goto bc_sets
    )
    :dk
    if /i  "!input!"=="dk" (
        echo pause>>"%temp%\mpb.bat"
        echo exit>>"%temp%\mpb.bat"
        start "" notepad.exe "%temp%\mpb.bat"
        goto bc_sets
    )
    :lc
    if /i  "!input!"=="lc" (
        set /p mbp=另存为（桌面【ZM】当前【DQ】返回【Q】）：
        if /i  "!mbp!"=="" goto bc_sets
        if /i  "!mbp!"=="Q" goto bc_sets
        if /i  "!mbp!"=="zm" (
            echo pause>>"%temp%\mpb.bat"
            echo exit>>"%temp%\mpb.bat"
            copy "%temp%\mpb.bat" "%USERPROFILE%\桌面"
            goto bc_sets
        )
        if /i  "!mbp!"=="dq" (
            echo pause>>"%temp%\mpb.bat"
            echo exit>>"%temp%\mpb.bat"
            copy "%temp%\mpb.bat" "%~pd0"
            goto bc_sets
            )
        echo pause>>"%temp%\mpb.bat"
        echo exit>>"%temp%\mpb.bat"
        copy "%temp%\mpb.bat" "!mbp!"&goto bc_sets
    )
    call :input_sets
    echo !input!>>"%temp%\mpb.bat"
    goto bc_sets
)
goto :eof
:help
cls
COLOR 27
echo.
call :colour "2E" "                                使用说明"&echo.
echo. __________________________________________________________________________
echo.
echo      ★ 按提示输入后需回车才执行，但播放中使用控制键时不需回车；
echo      ★ 将（单个）音频、视频文件或文件列表（TXT格式）拖入窗口并回车开始播放；
echo      ★ 将（多个）媒体文件拖至程序图标（非窗口）可自动生成播放列表并自动播放；
echo      ★ 可直接输入地址开始播放（包括盘符、文件夹和文件）；
echo      ★ 可使用URL（http、rtsp、vcd、dvd类）播放网络音乐和设备媒体；
echo      ★ 可使用网址播放背景音乐并自动存至My Documents\_urlplaylists.txt；
echo      ★ 背景音乐需保证URL正确和网络流畅，否则会卡住；
echo      ★ 可使用TAB键；可直接回车播放_playlists.txt中的歌曲，但不是每次有效；
echo      ★ 使用循环模式需先设置播放列表，且只对当前播放有效；
echo      ★ 可在主界面输入DOS命令，可打开CMD和BAT编辑器，可用【%%mmp%%】调取播放器；
echo      ★ 本程序默认使用暴风影音自带的MPlayer.exe，须先安装MPlayer(或暴风影音)；
echo      ★ 无法播放请手动设置其路径，或%SYSTEMDRIVE%\_mplayerpath.txt中的路径；
echo      ★ 可通过MPlayer的官方网站下载原版MPlayer程序：  http://www.mplayerhq.hu
echo      ★ MPlayer偶尔会出现一些小故障，与MPlayer有关的更多内容请参考其官方说明。
echo.
echo. __________________________________________________________________________
echo.
pause
call :entry
call :about
goto :eof
:entry
COLOR 27
cls
echo.
call :colour "2E" "                               通用输入键"&echo.
echo. __________________________________________________________________________
echo.
call :colour "2F" "                    名词    热键    说明"
echo.
echo                     quit     Q      退出\返回上一层；
echo                  setting     S      设置选项；
echo                     find     F      搜索与创建文件列表；
echo                      cmd     C      进入命令行提示符；
echo                      bat     B      进入批处理编辑器；
echo                     path     P      路径设置；
echo                     help     H      帮助说明；
echo                   hotkey     HK     播放器快捷键说明；
echo          option and help     OP     播放器命令参数设置说明；
echo    repeat and stochastic     RS     循环与随机播放；
echo         background music     BM     播放背景音乐；
echo               web search     WS     搜索网络音乐；
echo                 cjiabing     CB     打开本程序作者空间；
echo                  bathome     BH     打开批处理之家论坛；
echo                   cn-dos     CD     打开中国DOS联盟论坛；
echo                mplayerhq     MP     打开MPlayer官网主页；
echo                   lyrics     LRC    显示歌词；
echo. __________________________________________________________________________
call :colour "2E" "                           [★ 快捷键全局有效，注意看提示。]"&echo.
echo.
pause
goto hotkey
:hotkey
cls
COLOR 27
echo.
call :colour "2E" "                               基本控制键"&echo.
echo. __________________________________________________________________________
echo.
echo          p 或 SPACE 或 ^>   暂停播放(按任意键继续)；
echo                 q 或 ESC   停止播放并退出；
echo           pgdown 或 pgup   上一首 / 下一首；
echo               down 或 up   快进 / 后退 1 分钟；
echo                  ]  或 [   快速播放 / 慢速播放；
echo                   ) 或 (   增加或减少音量，每次+/-3%%；
echo                   * 或 /   增加或减少pcm音量；
echo                        m   静音；
echo                        f   全屏；
echo                        o   循环切换 OSD 模式：无/定位条/定位条+计时器；
echo                   z 或 x   调整字幕延迟+/-0.1秒；
echo                   r 或 t   上/下调整字幕位置；
echo                   1 或 2   调整对比度；
echo                   3 或 4   调整亮度；
echo                   5 或 6   调整色调
echo                   7 或 8   调整饱和度。
echo. __________________________________________________________________________
call :colour "2E" "                           [★ 部分控制键可能在特定条件下才有效]"&echo.
echo.
pause
goto :eof
:about
cls
COLOR 27
echo.
call :colour "2E" "                              关         于"&echo.
echo. __________________________________________________________________________
echo.
echo      ★ 当前版本：批处理版MPlayer音视频播放器 V4.3 改进版。
echo      ★ 本程序基于命令行版MPlayer播放器，以批处理的方式运行。
echo      ★ MPlayer是一款优秀的开源软件，任何人都可以永久免费安装使用。
echo      ★ MPlayer支持各种常见的音频、视频媒体格式，支持网络播放。
echo      ★ 本程序为MPlayer添加了一个类似GUI的批处理交互界面。
echo      ★ 极大地支持多种输入播放，可以使用快捷键控制播放。
echo      ★ 本程序版权归cjiabing所有。免费共享，但不可用于商业与非法目的。
echo      ★ 难免存在缺陷，使用须自担风险，欢迎反馈交流。
echo      ★ 献给喜欢简单和怀旧的年轻朋友，祝大家生活愉快！
call :colour "2E" "                                                            甲兵时代"&echo.
echo                                                           2010.10.10
echo                                         http://hi.baidu.com/cjiabing
echo. __________________________________________________________________________
echo.
pause
goto start
:play_sets
cls
COLOR 27
echo.
call :colour "2E" "                             播放器参数设置说明"&echo.
echo. __________________________________________________________________________
echo.
echo      ★ 因MPlayer的设置较复杂，这里只做介绍，具体使用请参照官方说明。
echo      ★ 使用说明man_page.html位于MPlayer目录下，是英文的。
echo      ★ MPlayer的用户配置位于~/.mplayer/config，可自行配置。
echo      ★ 本程序也支持使用自定义的MPlayer命令配置，使用方法如下：
echo      ★ 在主界面使用【%%mpp%%】代替MPlayer，遵循MPlayer命令格式。
echo      ★ 如指定字幕文件：%%mpp%% -sub ^<somesubtitlefile^> ^<somefile^>
echo      ★ 如设置缓存：%%mpp%% -cache 8192 -cache-min 50 -playlist ^<file or url^>
echo.
echo.
echo. __________________________________________________________________________
call :colour "2E" "                                         [★ 更多内容请阅读官方说明]"&echo.
echo.
pause
cls
COLOR 27
echo.
call :colour "2E" "                             播放器参数设置说明"&echo.
echo. __________________________________________________________________________
echo.
echo    -playlist ^<文件^> 指定播放列表文件
echo    -ss ^<位置^>       定位至给定（秒数或时:分:秒 - hh:mm:ss）位置
echo    -nosound         不播放声音
echo    -fs -vm -zoom    全屏播放选项(fullscr,vidmode chg,softw.scale)
echo    -x ^<x^> -y ^<y^>    设置显示的分辨率（用以与 -vm 或 -zoom 一起使用）
echo    -vid x -aid y    选择播放视频流（x）和音频流（y）
echo    -fps x -srate y  改变视频帧率为 x（fps），音频采样率为 y（Hz）
echo    -pp ^<质量^>       启用后期处理过滤器（详见于手册相关页面manpage/docs）
echo    -framedrop       启用丢帧（用于运行慢的机器）
echo    -vo ^<drv^>        选择视频输出驱动程序（查看驱动程序列表用“-vo help”）
echo    -ao ^<drv^>        选择音频输出驱动程序（查看驱动程序列表用“-ao help”）
echo    vcd://^<曲目号^>   播放 (S)VCD（超级VCD）曲目（无格式设备，无需装载）
echo    dvd://^<标题号^>   从设备而不是从普通文件上播放 DVD 标题
echo    -sub ^<文件^>      指定所使用的字幕文件（另见 -subfps、-subdelay）
echo    -alang/-slang    选择DVD音轨/字幕的语言(使用两位的国家代码)
echo.
echo. __________________________________________________________________________
call :colour "2E" "                                         [★ 更多内容请阅读官方说明]"&echo.
echo.
pause
cls
COLOR 27
echo. __________________________________________________________________________
echo    %%mpp%% ^[options^] ^[ file ^| URL ^| playlist ^| - ^]
echo    %%mpp%% ^[global options^] file1 ^[specific options^] ^[file2^] ^[specific options^]
echo    %%mpp%% ^[global options^] {group of files and options} ^[group specific options^]
echo    %%mpp%% dvd^:^/^/^[title ^| ^[start_title^]-end_title ^] ^[options^]
echo    %%mpp%% vcd^:^/^/track^[^/device^]
echo    %%mpp%% tv^:^/^/^[channel^] ^[options^]
echo    %%mpp%% dvb^:^/^/^[card_number@^]channel ^[options^]
echo    %%mpp%% mf^:^/^/filemask ^[-mf options^] ^[options^]
echo    %%mpp%% ^[cdda^|cddb^]^:^/^/track^[^:speed^]^[^/device^] ^[options^]
echo    %%mpp%% cue^:^/^/file^[^:track^] ^[options^]
echo    %%mpp%% ^[file^|mms^[t^]^|http^|http_proxy^|rt^[s^]p^|ftp^|udp^|unsv^]^:^/^/ ^[user^:passwd^@^]URL^[^:port^] ^[options^]
echo    %%mpp%% sdp^:^/^/file ^[options^]
echo    %%mpp%% mpst^:^/^/host^[^:port^]^/URL ^[options^]
echo    %%mpp%% tivo^:^/^/host^/list ^[options^]
echo    %%mpp%% tivo^:^/^/host^/llist ^[options^]
echo    %%mpp%% tivo^:^/^/host^/fsid ^[options^]
echo    gmplayer ^[options^] ^[-skin skin^]
echo    mencoder ^[options^] ^[ file ^| URL ^| - ^] ^[-o file^]
echo    mencoder ^[global options^] file1 ^[specific options^] ^[file2^] ^[specific options^]
echo. __________________________________________________________________________
call :colour "2E" "           [★ 更多内容请阅读官方说明]"&pause
goto main

:LYRICS
cls
echo.
echo 暂时占位，未解决！~
echo.
pause
goto main